Серый форум — AHK: Прозрачность отдельного элемента

Re: AHK: Прозрачность отдельного элемента

2014-10-23T09:05:28Z

*шмырг* Читаю такие темы, и прям ностальгия наваливается *шмырг-шмырг*

Re: AHK: Прозрачность отдельного элемента

2014-10-23T00:40:23Z

Спасибо teadrinker, скрипт в посте 29 идеален для меня .

Re: AHK: Прозрачность отдельного элемента

2014-10-22T19:19:51Z

Скорее всего, по-другому и не получится. Окно с ActiveX хотя бы на мгновение должно получить клавиатурный фокус (а значит и активность), т. к. в ином случае невозможно будет взаимодействовать с его элементами управления (если таковые есть).

+ Вариант без получения активности

SetWinDelay, 0
global hMainGui, hChildGui, hWorkGui

Gui, Main: +hwndhMainGui +LastFound
Gui, Child: +hwndhChildGui -Caption +ParentMain
Gui, Child: Color, 123456
WinSet, TransColor, 123456
Gui, Main: Add, Button, x227 y167 w65 h23 gPlay, Play
Gui, Main: Show, w300 h200
Gui, Child: Show, x10 y10 w280 h150

Gui, Work: +hwndhWorkGui -Caption +ToolWindow +LastFound
Gui, Work: Add, ActiveX, x0 y0 w280 h150 vWMP, WMPlayer.OCX.7
WMP.url := A_WinDir "\Media\tada.wav"
WMP.controls.stop

WinSet, Transparent, 180
WinGetPos, X, Y,,, ahk_id %hChildGui%
Gui, Work: Show, x%X% y%Y% w280 h150 NA

OnMessage(0x6, "WM_ACTIVATE")
OnMessage(0x3, "WM_MOVE")
OnExit, Exit
Return

Play:
   WMP.controls.play
   Return

Exit:
   DllCall("DeregisterShellHookWindow", "UInt", A_ScriptHwnd)
   ExitApp

MainGuiClose:
   Gui, Main: Cancel
   ExitApp
   
WM_MOVE(wp, lp, msg, hwnd)
{
   if (hwnd != hMainGui)
      Return
   
   WinGetPos, X, Y,,, ahk_id %hChildGui%
   Gui, Work: Show, x%X% y%Y% NA
}

WM_ACTIVATE(wp, lp, msg, hwnd)
{
   if (hwnd != hWorkGui)
      Return
   
   if (wp & 0xFFFF != 0)
      WinActivate, ahk_id %hMainGui%
}

В нём не получается взаимодействовать с кнопками плеера.

Re: AHK: Прозрачность отдельного элемента

2014-10-22T18:32:09Z

ypppu пишет:

Очередной экспонат для Коллекции!

Доработать для Коллекции надо, чтобы не мелькало. Может, кто предложит чего.

Re: AHK: Прозрачность отдельного элемента

2014-10-22T18:15:34Z

sergeiplugatyr, беги за поллитрой!

Re: AHK: Прозрачность отдельного элемента

2014-10-22T17:33:36Z

Получилось, но не айс. С подпорками, и всё же окно с ActiveX иногда на мгновение становится активным, возникает мелькание.

SetWinDelay, 0
global hMainGui, hChildGui, hWorkGui

Gui, Main: +hwndhMainGui +LastFound
Gui, Child: +hwndhChildGui -Caption +ParentMain
Gui, Child: Color, 123456
WinSet, TransColor, 123456
Gui, Main: Add, Button, x227 y167 w65 h23 gPlay, Play
Gui, Main: Show, w300 h200
Gui, Child: Show, x10 y10 w280 h150

Gui, Work: +hwndhWorkGui -Caption +ToolWindow +LastFound +OwnerMain
Gui, Work: Add, ActiveX, x0 y0 w280 h150 vWMP, WMPlayer.OCX.7
WMP.url := A_WinDir "\Media\tada.wav"
WMP.controls.stop

WinSet, ExStyle, +0x8000000   ; WS_EX_NOACTIVATE
WinSet, Transparent, 150
WinGetPos, X, Y,,, ahk_id %hChildGui%
Gui, Work: Show, x%X% y%Y% w280 h150 NA

DllCall("RegisterShellHookWindow", "UInt", A_ScriptHwnd) 
OnMessage(DllCall("RegisterWindowMessage", "str", "SHELLHOOK"), "ShellProc")
OnMessage(0x3, "WM_MOVE")
OnExit, Exit
Return

Play:
   WMP.controls.play
   Return

Exit:
   DllCall("DeregisterShellHookWindow", "UInt", A_ScriptHwnd)
   ExitApp

MainGuiClose:
   Gui, Main: Cancel
   ExitApp
   
WM_MOVE(wp, lp, msg, hwnd)
{
   if (hwnd != hMainGui)
      Return
   
   WinGetPos, X, Y,,, ahk_id %hChildGui%
   Gui, Work: Show, x%X% y%Y% NA
}

ShellProc(nCode, wParam)
{ 
   if (nCode = 4 && WinActive("ahk_id" hWorkGui))   ; HSHELL_WINDOWACTIVATED := 4
      WinActivate, ahk_id %hMainGui%
}

Re: AHK: Прозрачность отдельного элемента

2014-10-22T14:26:09Z

Тут уже написано:
http://www.autohotkey.com/board/topic/1 … ay-in-gui/

Re: AHK: Прозрачность отдельного элемента

2014-10-22T13:58:42Z

Напишу попозже.

Re: AHK: Прозрачность отдельного элемента

2014-10-22T13:57:15Z

teadrinker пишет:

serzh82saratov пишет:
Если совсем извратится, то через WinSet Region вырезать кусок окна, поместить туда другое прозрачное окно, применить к нему WS_EX_NOACTIVATE, ну и следить за перемещением основного окна.
Так можно. Тоже думал об этом, но не знал, что есть такой стиль.

Пробовал. Не придумал, как организовать быстро перемещение. Всё рывками, на нервы действует.

Re: AHK: Прозрачность отдельного элемента

2014-10-22T11:34:02Z

Да, не подходит мой вариант.

Re: AHK: Прозрачность отдельного элемента

2014-10-22T11:22:01Z

И что в таком одноцветном контроле будет отображаться (учитывая, что это ActiveX) ?

Re: AHK: Прозрачность отдельного элемента

2014-10-22T11:20:02Z

Сделать контрол определенного цвета и применить к нему WinSet, Transcolor с нужной прозрачностью.

Re: AHK: Прозрачность отдельного элемента

2014-10-22T11:04:23Z

Ну, а дальше что?

Re: AHK: Прозрачность отдельного элемента

2014-10-22T11:02:50Z

Все-таки не понял, почему так нельзя?

#Persistent
#SingleInstance, Force
Gui, Add, Progress, x0 y0 w300 h20 100
Gui, Color, 000111
Gui, Show, W400 H300, Test
WinSet, Transcolor, 000111, Test
Return

Re: AHK: Прозрачность отдельного элемента

2014-10-22T10:58:28Z

serzh82saratov пишет:

Если совсем извратится, то через WinSet Region вырезать кусок окна, поместить туда другое прозрачное окно, применить к нему WS_EX_NOACTIVATE, ну и следить за перемещением основного окна.

Так можно. Тоже думал об этом, но не знал, что есть такой стиль.