Серый форум — AHK: Клик по иконке другой программы в трее или вызов ее меню

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Tue, 01 Sep 2015 15:35:06 +0000

Тогда не знаю, видимо, какие-то проблемы чтения памяти другого процесса в Windows 10. Не могу проэкспериментировать, у меня 7.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (becauseim) — Tue, 01 Sep 2015 15:31:28 +0000

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Tue, 01 Sep 2015 15:29:35 +0000

А, понял, в справке этого не может быть написано, она общая. Откройте папку, куда установлен AHK, найдите файл AutoHotkey.exe, наведите на него курсор. Должно появиться всплывающее окно типа такого:

Там будет описание файла.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (becauseim) — Tue, 01 Sep 2015 15:19:31 +0000

teadrinker пишет:

как там указано?

Так как я указал. Где указывается битность, я не знаю, к сожалению.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Tue, 01 Sep 2015 15:16:49 +0000

Что за окно Help и именно как там указано?

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (becauseim) — Tue, 01 Sep 2015 15:14:45 +0000

Не знаю, как это можно узнать. В окне Help указано именно так.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Tue, 01 Sep 2015 15:02:26 +0000

Битность AHK тоже имеет значение.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (becauseim) — Tue, 01 Sep 2015 15:00:11 +0000

Win10 x64
v1.1.22.02

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Tue, 01 Sep 2015 12:53:21 +0000

Чем поделиться? У меня последний скрипт работает, у остальных, вроде, тоже работал. Какая ОС у вас, какая версия AHK?

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (becauseim) — Tue, 01 Sep 2015 12:44:46 +0000

teadrinker пишет:

отправляем сообщения иконке Skype.exe

Была бы кстати рабочая версия. Поделитесь, пожалуйста.
Имеется в виду пкм по заданной программе в трее.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Thu, 13 Nov 2014 14:33:32 +0000

Ключевое слово "this" используется при работе с классами, но изучить следует всю статью Объекты.
Справочная информация о winapi-функциях (и иногда примеры использования) находится поиском в MSDN, например OpenProcess.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (stealzy) — Thu, 13 Nov 2014 12:34:00 +0000

И то, и другое наверно. Если кинете пару ссылок как с этим обращатся с примерами, буду балгодарен.

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Thu, 13 Nov 2014 11:56:56 +0000

Не совсем понял, вопрос про конструкцию this.hProc, или про winapi-функцию?

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (stealzy) — Thu, 13 Nov 2014 11:44:06 +0000

Спасибо большое, вариант по имени процесса отлично работает.
Я только не понял как он это делает.
В частности указатели или такие вызовы:

(this.hProc := DllCall("OpenProcess", UInt, PROCESS_VM_OPERATION|PROCESS_VM_READ|PROCESS_VM_WRITE, Int, 0, UInt, PID, Ptr))

Я в основном учился по справке.
Вы не подскажете что проштудировать, чтобы самому составлять такие выражения?

Re: AHK: Клик по иконке другой программы в трее или вызов ее меню

null@example.com (teadrinker) — Wed, 12 Nov 2014 17:27:36 +0000

Где-то уже писал, но вот подправленные варианты. По порядковому индексу иконки, отправляем сообщения первой иконке в трее:

#NoTrayIcon
idx := 1
PostMessage2TrayIconIndex(idx
   , "Tray"   ; если иконка в Shell_TrayWnd, пишем "Tray", если в NotifyIconOverflowWindow — ""
   , WM_RBUTTONDOWN := 0x204
   , WM_RBUTTONUP := 0x205)  ; последние параметры — сообщения которые нужно отправить
Return

PostMessage2TrayIconIndex(idx, TrayOrOverflow, messages*)
{
/*
Структура TRAYDATA
typedef TRAYDATA
{
IntPtr hwnd;
uint uID;
uint uCallbackMessage;
uint Reserved;
uint Reserved2;
IntPtr hIcon;
}
*/
   static WM_USER := 0x400, TB_BUTTONCOUNT := WM_USER + 24, TB_GETBUTTON := WM_USER + 23
      , PtrSize := A_Is64bitOS ? 8 : 4, SizeOfTBBUTTON := 8 + PtrSize*3, SizeOfTRAYDATA := 16 + PtrSize*2

   DHW_Prev := A_DetectHiddenWindows
   DetectHiddenWindows, On
   ControlGet, hWnd, hwnd,, ToolbarWindow321, % "ahk_class " . (TrayOrOverflow = "Tray" ? "Shell_TrayWnd" : "NotifyIconOverflowWindow")
   WinExist("ahk_id" hWnd)
   WinGet, PID, PID

   if !IsObject(RemoteBuff := New RemoteBuffer(PID, SizeOfTRAYDATA)) {
      DetectHiddenWindows, %DHW_Prev%
      Return, 0, DllCall("MessageBox", Ptr, 0, Str, "Не удалось создать удалённый буфер`nОшибка " A_LastError, Str, "", UInt, 0)
   }
 
   SendMessage, TB_GETBUTTON, idx - 1, RemoteBuff.ptr
   if ! ( pTBBUTTON := RemoteBuff.Read(SizeOfTBBUTTON) )
      || !pTRAYDATA := RemoteBuff.Read(SizeOfTRAYDATA, NumGet(pTBBUTTON + 8 + PtrSize) - RemoteBuff.ptr) {
      DetectHiddenWindows, %DHW_Prev%
      Return
   }

   WinExist("ahk_id" NumGet(pTRAYDATA+0))
   uID := NumGet(pTRAYDATA + PtrSize, "UInt")
   uCallbackMessage := NumGet(pTRAYDATA + PtrSize + 4, "UInt")

   for i, message in messages
      PostMessage, uCallbackMessage, uID, message
   
   DetectHiddenWindows, %DHW_Prev%
}

Class RemoteBuffer
{
   __New(PID, size)
   {
      static PROCESS_VM_OPERATION := 0x8, PROCESS_VM_WRITE := 0x20, PROCESS_VM_READ := 0x10
         , MEM_COMMIT := 0x1000, PAGE_READWRITE := 0x4
         
      if !(this.hProc := DllCall("OpenProcess", UInt, PROCESS_VM_OPERATION|PROCESS_VM_READ|PROCESS_VM_WRITE, Int, 0, UInt, PID, Ptr))
         Return
      
      if !(this.ptr := DllCall("VirtualAllocEx", UInt, this.hProc, UInt, 0, UInt, size, UInt, MEM_COMMIT, UInt, PAGE_READWRITE, Ptr))
         Return, "", DllCall("CloseHandle", Ptr, this.hProc)
   }
   
   __Delete()
   {
      DllCall("VirtualFreeEx", Ptr, this.hProc, Ptr, this.ptr, UInt, 0, UInt, MEM_RELEASE := 0x8000)
      DllCall("CloseHandle", Ptr, this.hProc)
   }
   
   Read(size, offset = 0)
   {
      static LocalBuff
      VarSetCapacity(LocalBuff, size, 0)
      if !DllCall("ReadProcessMemory", Ptr, this.hProc, Ptr, this.ptr + offset, Ptr, &LocalBuff, UInt, size, UInt, 0)
         Return, 0, DllCall("MessageBox", Ptr, 0, Str, "Не удалось прочитать данные`nОшибка " A_LastError, Str, "", UInt, 0)
      
      VarSetCapacity(LocalBuff, -1)
      Return &LocalBuff
   }
   
   Write(pLocalBuff, size, offset = 0)
   {
      res := DllCall("WriteProcessMemory", Ptr, this.hProc, Ptr, this.ptr + offset, Ptr, pLocalBuff, UInt, size, UInt, 0)
      Return res ? res : 0, (!res) ? DllCall("MessageBox", Ptr, 0, Str, "Не удалось записать данные`nОшибка " A_LastError, Str, "", UInt, 0)
   }
}

По названию процесса (или если ahk, то по имени скрипта), отправляем сообщения иконке Skype.exe:

#NoTrayIcon
PostMessage2TrayIconProcName("skype.exe", WM_RBUTTONDOWN := 0x204, WM_RBUTTONUP := 0x205)
Return

PostMessage2TrayIconProcName(ProcessName, messages*)
{
/*
Структура TRAYDATA
typedef TRAYDATA
{
IntPtr hwnd;
uint uID;
uint uCallbackMessage;
uint Reserved;
uint Reserved2;
IntPtr hIcon;
}
*/
   static WM_USER := 0x400, TB_BUTTONCOUNT := WM_USER + 24, TB_GETBUTTON := WM_USER + 23
      , PtrSize := A_Is64bitOS ? 8 : 4, SizeOfTBBUTTON := 8 + PtrSize*3, SizeOfTRAYDATA := 16 + PtrSize*2
   oWMI := ComObjGet("winmgmts:")
   DHW_Prev := A_DetectHiddenWindows
   DetectHiddenWindows, On
   
   Loop 2
   {
      ControlGet, hWnd, hwnd,, ToolbarWindow321, % "ahk_class " . (A_Index = 1 ? "Shell_TrayWnd" : "NotifyIconOverflowWindow")
      WinExist("ahk_id" hWnd)
      WinGet, PID, PID

      if (A_Index = 1 && !IsObject(RemoteBuff := New RemoteBuffer(PID, SizeOfTRAYDATA))) {
         DetectHiddenWindows, %DHW_Prev%
         Return, 0, DllCall("MessageBox", Ptr, 0, Str, "Не удалось создать удалённый буфер`nОшибка " A_LastError, Str, "", UInt, 0)
      }
      
      SendMessage, TB_BUTTONCOUNT
      Loop % ErrorLevel
      {
         SendMessage, TB_GETBUTTON, A_Index - 1, RemoteBuff.ptr
         if ! ( pTBBUTTON := RemoteBuff.Read(SizeOfTBBUTTON) )
            || !pTRAYDATA := RemoteBuff.Read(SizeOfTRAYDATA, NumGet(pTBBUTTON + 8 + PtrSize) - RemoteBuff.ptr) {
            DetectHiddenWindows, %DHW_Prev%
            Return
         }

         WinGet, PID, PID, % "ahk_id" hWnd := NumGet(pTRAYDATA+0)
         CurrentProcessName := oWMI.Get("Win32_Process.Handle=" PID).Name
         if (CurrentProcessName = "AutoHotkey.exe")
         {
            WinGetTitle, Title, % "ahk_id" hWnd
            CurrentProcessName := RegExReplace(Title, "i).*\\(.*) - autohotkey v[\.\d]+", "$1")
         }
         if (CurrentProcessName = ProcessName)
         {
            uID := NumGet(pTRAYDATA + PtrSize, "UInt")
            uCallbackMessage := NumGet(pTRAYDATA + PtrSize + 4, "UInt")

            for i, message in messages
               PostMessage, uCallbackMessage, uID, message,, % "ahk_id" hWnd
            DetectHiddenWindows, %DHW_Prev%
            Return
         }
      }
   }
   DetectHiddenWindows, %DHW_Prev%
   MsgBox, % "Иконка процесса " . ProcessName . " не найдена"
}

Class RemoteBuffer
{
   __New(PID, size)
   {
      static PROCESS_VM_OPERATION := 0x8, PROCESS_VM_WRITE := 0x20, PROCESS_VM_READ := 0x10
         , MEM_COMMIT := 0x1000, PAGE_READWRITE := 0x4
         
      if !(this.hProc := DllCall("OpenProcess", UInt, PROCESS_VM_OPERATION|PROCESS_VM_READ|PROCESS_VM_WRITE, Int, 0, UInt, PID, Ptr))
         Return
      
      if !(this.ptr := DllCall("VirtualAllocEx", UInt, this.hProc, UInt, 0, UInt, size, UInt, MEM_COMMIT, UInt, PAGE_READWRITE, Ptr))
         Return, "", DllCall("CloseHandle", Ptr, this.hProc)
   }
   
   __Delete()
   {
      DllCall("VirtualFreeEx", Ptr, this.hProc, Ptr, this.ptr, UInt, 0, UInt, MEM_RELEASE := 0x8000)
      DllCall("CloseHandle", Ptr, this.hProc)
   }
   
   Read(size, offset = 0)
   {
      static LocalBuff
      VarSetCapacity(LocalBuff, size, 0)
      if !DllCall("ReadProcessMemory", Ptr, this.hProc, Ptr, this.ptr + offset, Ptr, &LocalBuff, UInt, size, UInt, 0)
         Return, 0, DllCall("MessageBox", Ptr, 0, Str, "Не удалось прочитать данные`nОшибка " A_LastError, Str, "", UInt, 0)
      
      VarSetCapacity(LocalBuff, -1)
      Return &LocalBuff
   }
   
   Write(pLocalBuff, size, offset = 0)
   {
      res := DllCall("WriteProcessMemory", Ptr, this.hProc, Ptr, this.ptr + offset, Ptr, pLocalBuff, UInt, size, UInt, 0)
      Return res ? res : 0, (!res) ? DllCall("MessageBox", Ptr, 0, Str, "Не удалось записать данные`nОшибка " A_LastError, Str, "", UInt, 0)
   }
}