Серый форум — Пропуск действия \ отмена Sleep

Re: Пропуск действия \ отмена Sleep

null@example.com (ypppu) — Tue, 16 Dec 2014 10:17:59 +0000

По мотивам примера от Malcev:

1::
Soundbeep, 1000, 300
Sleep(1000)
Soundbeep, 2000, 300
Sleep(2000)
Soundbeep, 3000, 300
Sleep(3000)
Soundbeep, 4000, 300
Return

2:: n := 0

Sleep(x)
    {
    global n
    n := 1
    Loop, % x/100
    Sleep, % 100*n
    }

Re: Пропуск действия \ отмена Sleep

Sun, 14 Dec 2014 22:13:56 +0000

А зачем примитивный Sleep вообще? Сам ответ - по любому, какие то переменные "шевелит". Вот их и надо ловить.

Re: Пропуск действия \ отмена Sleep

null@example.com (serzh82saratov) — Sun, 14 Dec 2014 22:04:56 +0000

Пропуск задержки по запускающей-же клавише:


$1::
    i := i = 4 ? 0 : i
Input:
    SendInput % "{f6}/c " (["текст 1","текст 2","текст 3","текст 4"][++i]) "{enter}"
    SetTimer Input, % i = 4 ? "Off" : "-2000"
    Return

Re: Пропуск действия \ отмена Sleep

null@example.com (serzh82saratov) — Sun, 14 Dec 2014 20:57:21 +0000

Как вариант:


$1::
    i := 0
Input:
    SendInput % "{f6}/c " (["текст 1","текст 2","текст 3","текст 4"][++i]) "{enter}"
    SetTimer Input, % i = 4 ? "Off" : "-2000" 
    Return
     
$2:: SetTimer Input, % i = 4 ? "Off" : "-1"

Re: Пропуск действия \ отмена Sleep

null@example.com (dewy.thefirst) — Sun, 14 Dec 2014 19:36:08 +0000

teadrinker пишет:

Так как-нибудь:

SleepTime := 10000
1::
   SendInput {f6}/c 1{enter}
   Gosub, waiting
   SendInput {f6}/c 2{enter}
   Gosub, waiting
   SendInput {f6}/c 3{enter}
   Gosub, waiting
   SendInput {f6}/c 4{enter}
   return
   
2:: cancel := true
   
waiting:
   start := A_TickCount
   while A_TickCount - start < SleepTime && !cancel
      Sleep, 10
   cancel := false
   Return

Как все сложно..
Спасибо большое.

Re: Пропуск действия \ отмена Sleep

null@example.com (teadrinker) — Sun, 14 Dec 2014 19:19:57 +0000

Так как-нибудь:

SleepTime := 10000
1::
   SendInput {f6}/c 1{enter}
   Gosub, waiting
   SendInput {f6}/c 2{enter}
   Gosub, waiting
   SendInput {f6}/c 3{enter}
   Gosub, waiting
   SendInput {f6}/c 4{enter}
   return
   
2:: cancel := true
   
waiting:
   start := A_TickCount
   while A_TickCount - start < SleepTime && !cancel
      Sleep, 10
   cancel := false
   Return

Re: Пропуск действия \ отмена Sleep

null@example.com (Malcev) — Sun, 14 Dec 2014 19:05:50 +0000

Не так понял вопрос.
Вместо sleep можно использовать keywait:

KeyWait, a, D T20 
msgbox

Re: Пропуск действия \ отмена Sleep

null@example.com (dewy.thefirst) — Sun, 14 Dec 2014 18:55:53 +0000

Malcev пишет:

x := 2000
1::
Sleep % x
Sleep % x
Sleep % x
msgbox
return

2::
x := ""
return

Или если разные значения sleep:

x := 1
1::
Sleep % 2000*x
Sleep % 3000*x
Sleep % 5000*x
msgbox
return

2::
x := ""
return

А какой смысл, не пойму?

Re: Пропуск действия \ отмена Sleep

null@example.com (dewy.thefirst) — Sun, 14 Dec 2014 18:50:43 +0000

teadrinker пишет:

Правильно ли я понял, что отмена ожидания должна быть по нажатию какой-нибудь клавиши? Всё равно, какой?

Да.

Клавишу подставлю.

Re: Пропуск действия \ отмена Sleep

null@example.com (Malcev) — Sun, 14 Dec 2014 18:47:52 +0000

x := 2000
1::
Sleep % x
Sleep % x
Sleep % x
msgbox
return

2::
x := ""
return

Или если разные значения sleep:

x := 1
1::
Sleep % 2000*x
Sleep % 3000*x
Sleep % 5000*x
msgbox
return

2::
x := ""
return

Re: Пропуск действия \ отмена Sleep

null@example.com (teadrinker) — Sun, 14 Dec 2014 18:16:21 +0000

Правильно ли я понял, что отмена ожидания должна быть по нажатию какой-нибудь клавиши? Всё равно, какой?

Re: Пропуск действия \ отмена Sleep

null@example.com (dewy.thefirst) — Sun, 14 Dec 2014 18:11:18 +0000

Объясню по другому.
В игре я провожу тест на вступление, сделал биндер, который каждые 20 секунд задает вопрос.
Так вот, допустим человек ответил на вопрос быстрее, чем 20 секунд.
Пусть даже через 2-3 секунды. И что бы не стоять и не ждать еще ~17 секунд просто так, я бы хотел сделать пропуск этой задержки, как вы уже поняли.
Возможно такое вообще?

Re: Пропуск действия \ отмена Sleep

null@example.com (teadrinker) — Sun, 14 Dec 2014 17:04:23 +0000

dewy.thefirst пишет:

Как сделать пропуск Sleep?

Не пишите его, где не надо.

Пропуск действия \ отмена Sleep

null@example.com (dewy.thefirst) — Sun, 14 Dec 2014 11:54:02 +0000

Всем привет.
Как сделать пропуск Sleep?
К примеру, у меня есть бинд:


1::
SendInput {f6}/c 1{enter}
Sleep 10000
SendInput {f6}/c 2{enter}
Sleep 10000
SendInput {f6}/c 3{enter}
Sleep 10000
SendInput {f6}/c 4{enter}
return

Вот оно написало "1", через 10 секунд написало "2", а что бы написать "3" мне уже не нужно ждать 10 секунд, и я хочу что бы при нажатии кнопки, Sleep 10000 пропускалось, и выполнялось след. действие.
Не знаю как сделать, даже примерно.
Помогите пожалуйста.