Серый форум — AHK: Не закрывает процесс

Re: AHK: Не закрывает процесс

null@example.com (Malcev) — Thu, 26 Feb 2015 12:57:36 +0000

Сегодня выдало ошибку - 0x80041002.
http://support.microsoft.com/kb/2465990/ru

Re: AHK: Не закрывает процесс

null@example.com (teadrinker) — Thu, 08 Jan 2015 14:00:42 +0000

Не уверен конечно на сто процентов, но, по-моему метод Terminate (как и команда Process, Close) убивает процесс без всяких условий, если есть права доступа и не зависла система. Можешь поэкспериментировать на всякий случай.

Re: AHK: Не закрывает процесс

null@example.com (Malcev) — Thu, 08 Jan 2015 13:53:31 +0000

Ну например в текущий момент он не может быть завершен из-за драйвера например видеокарты, а через какое-то время драйвер дает добро на завершение.
Так вот интересно, нужно ли опять его завершать или достаточно просто подождать Process, WaitClose?

Re: AHK: Не закрывает процесс

null@example.com (teadrinker) — Thu, 08 Jan 2015 13:41:56 +0000

Просто не вижу причины, почему процесс должен закрыться после второй попытки, если не закрылся после первой.

Re: AHK: Не закрывает процесс

null@example.com (Malcev) — Thu, 08 Jan 2015 13:34:21 +0000

А если процесс не закрылся с первого раза, то действительно долбать его не имеет смысла?

Re: AHK: Не закрывает процесс

null@example.com (teadrinker) — Thu, 08 Jan 2015 13:18:13 +0000

serzh82saratov пишет:

Непонятен фрагмент:

Согласен, это я не подумав из предыдущего варианта скопировал. Ещё логичнее так:

MyPpoc := "notepad.exe"
Loop 10
   Run, % MyPpoc

oProcesses := []
for process in ComObjGet("winmgmts:").InstancesOf("Win32_Process where Name='" . MyPpoc . "'")
   oProcesses[A_Index] := process.ProcessId, process.Terminate

for k, PID in oProcesses
   Process, WaitClose, %PID%, 10
until ErrorLevel && NotAllClosed := 1

if NotAllClosed
{
   for k, PID in oProcesses
   {
      Process, Exist, %PID%
      if ErrorLevel
         NotClosed .= (A_Index = 1 ? "" : ", ") . PID
   }
   MsgBox, Не удалось завершить процессы %NotClosed%
}

Re: AHK: Не закрывает процесс

null@example.com (serzh82saratov) — Thu, 08 Jan 2015 12:13:33 +0000

teadrinker пишет:

Если процесс не закрылся после однократного Process, close, не имеет смысла бомбить его этой командой далее.

Если действительно нет смысла, то я бы так написал:


process := "notepad.exe" 

Loop 10
    run %process%
    
For Proc In ComObjGet("winmgmts:").ExecQuery("Select * from Win32_Process where Name='" process "'")
{ 
    Process, Close, % Pid := Proc.ProcessId
    Process, WaitClose, %Pid%, 10 
    If ErrorLevel 
        MsgBox, Не удалось завершить процесс: %process%, пид: %Pid% за 10 секунд 
}
MsgBox, Все процессы: %process% завершены.

Непонятен фрагмент:

   Loop
      Process, WaitClose, %PID%, 1
   until !ErrorLevel || A_Index = 10
   if ErrorLevel

есть отличия от:

    Process, WaitClose, %Pid%, 10 
    If ErrorLevel

Re: AHK: Не закрывает процесс

null@example.com (serzh82saratov) — Thu, 08 Jan 2015 11:55:08 +0000

Они же в одном цикле находятся.

Мда, это я Break с Continue подсознательно попутал :LOL:. Праздники.

Думаю такой вариант проще:

process := "notepad.exe" 

Loop 10
    run %process%

Loop
{
   Process, Exist, %process%
   Process, Close, % Pid := ErrorLevel
   Process, WaitClose, %PID%, 10 
   If ErrorLevel 
        MsgBox, Не удалось завершить процесс: %process%, пид: %PID% за 10 секунд 
} Until !Pid

MsgBox, Все процессы: %process% завершены.

Re: AHK: Не закрывает процесс

null@example.com (Malcev) — Thu, 08 Jan 2015 11:43:08 +0000

Если процесс не закрывается, то у тебя тут вечный цикл, и сюда:
if (prev != ErrorLevel)
{
prev := ErrorLevel
n := ""
}
выполнение не дойдёт.

Как это не дойдет?
Они же в одном цикле находятся.

Re: AHK: Не закрывает процесс

null@example.com (teadrinker) — Thu, 08 Jan 2015 11:39:25 +0000

Ну, не знаю, мне мой вариант кажется более последовательным. Если процессов с одним именем много, логично к ним обращаться по PID. Если процесс не закрылся после однократного Process, close, не имеет смысла бомбить его этой командой далее.

Re: AHK: Не закрывает процесс

null@example.com (serzh82saratov) — Thu, 08 Jan 2015 11:39:12 +0000

Этот подход правильный?

Если несколько, то нет. Надо обращатся к идентификатору процесса, а не к его имени.

А таймер 10 секунд обнуляется в этой строчке:

   Process, Close, %process%
   Process, Exist, %process%
   if !ErrorLevel
      break

Если процесс не закрывается, то у тебя тут вечный цикл, и сюда:

   if (prev != ErrorLevel)
   {
      prev := ErrorLevel
      n := ""
   }

выполнение не дойдёт.

Re: AHK: Не закрывает процесс

null@example.com (Malcev) — Thu, 08 Jan 2015 11:29:32 +0000

Так и пускай обращается - нам же надо закрыть все процессы notepad.exe.
А таймер 10 секунд обнуляется в этой строчке:

   if (prev != ErrorLevel)
   {
      prev := ErrorLevel
      n := ""
   }

Re: AHK: Не закрывает процесс

null@example.com (teadrinker) — Thu, 08 Jan 2015 11:20:44 +0000

Не думаю, что так лучше.

   Process, Close, %process%
   Process, Exist, %process%
   if !ErrorLevel
      break

Вполне может оказаться, что в первой строчке код обращается к одному процессу, а во второй уже к другому, поэтому Errorlevel ни о чём не говорит.

Re: AHK: Не закрывает процесс

null@example.com (Malcev) — Thu, 08 Jan 2015 10:48:44 +0000

А я не знаю сколько их может быть.
И разве из-за несовсем неправильного подхода может код не срабатывать?
Этот подход правильный?

process := "notepad.exe"
n := prev := ErrorLevel := ""
Loop
{
   Process, Close, %process%
   Process, Exist, %process%
   if !ErrorLevel
      break
   if n = 100
      MsgBox, Не удалось завершить процесс %process% за 10 секунд
   sleep 100
   n++
   if (prev != ErrorLevel)
   {
      prev := ErrorLevel
      n := ""
   }
}

Re: AHK: Не закрывает процесс

null@example.com (teadrinker) — Wed, 07 Jan 2015 21:44:01 +0000

Нет, *32 — это не часть имени процесса, это просто метка.
Вообще-то, сам подход не совсем верный. Если процесс один, правильнее так:

Process, Close, WerFault.exe
Loop
   Process, WaitClose, WerFault.exe, 1
until !ErrorLevel || A_Index = 10
if ErrorLevel
   MsgBox, Не удалось завершить процесс WerFault.exe за 10 секунд

Если несколько, так:

oProcesses := []
for process in ComObjGet("winmgmts:").InstancesOf("Win32_Process where Name='WerFault.exe'")
   oProcesses[A_Index] := process.ProcessId

for k, PID in oProcesses
{
   Process, Close, %PID%
   Loop
      Process, WaitClose, %PID%, 1
   until !ErrorLevel || A_Index = 10
   if ErrorLevel
      MsgBox, Не удалось завершить процесс %PID% за 10 секунд
}