Серый форум — AHK: Random, настройка вероятности выпадения двух чисел

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (to4er) — Sun, 15 Feb 2015 21:22:07 +0000

Всё отлично работает в таком виде:

var := 2.75
F12::
rvar := Rand(var)
SendInput %rvar%

Rand(t) {
   static d := 0 
   Return r := Round(t+d), d += t - r
}

также, составил функцию по рэндому:

Rand(x)
{
r := Round(x, 0)
if r > %x%
{
z := r - 0.5 / (1 + x - r)
}
else
{
z := r + 0.5 / (1 - x + r)
}
Random, v, z, r
Return v := Round(v, 0)
}

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (serzh82saratov) — Sun, 15 Feb 2015 18:45:05 +0000

Да, отлично, ничего нескажешь. Но ещё одну строку уберём:

Rand(t) {
   static d := 0 
   Return r := Round(t+d), d += t - r
}

Не думаю, что мат.операции проиграют в скорости RegEx, конечно можно устроить "полевые испытания"

Ты наверное понял меня наоборот, мат.операции вместо RegEx, увеличат скорость раз в пять. А испытания уже были, как то обсуждалось. При "простом" поиске, связка SubStr и InStr работают минимум в 2 раза быстрее RegEx.

+ Хотя:

В данном случае, всего 15%.

SetBatchLines -1 
v := 6.425

Start := A_TickCount
loop 1000000
    p1 := Floor(v), p2 := Round(v - p1, 1) * 10 
MsgBox % A_TickCount - Start  
 
Start := A_TickCount
loop 1000000
    RegExMatch(Round(v, 1), "(.*)\.(.)", p)  
MsgBox % A_TickCount - Start

, но вряд ли это имеет большое значение - скорость не относится к числу сильных сторон AHK.

Тогда тем более получается, что такие мелочи, могут местами сильно повлиять.

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (to4er) — Sun, 15 Feb 2015 13:47:59 +0000

Irbis, это золото, я в шоке. Alectric, serzh82saratov так же огромное спасибо. Благодаря таким людям как вы хаос немного упорядочивается .

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (Irbis) — Sun, 15 Feb 2015 12:48:57 +0000

Теперь более-менее понятно. Вообще, по играм имеется своя ветка, но тут вопрос скорее прикладного характера, а не взаимодействия с приложением, санкций по этому поводу быть не должно.
Вот (надеюсь) самый простой вариант для усредненного представления нецелого числа в виде последовательности целых чисел.

F12::
loop 10
   SendInput % Rand(2.75) " "
   SendInput |{Space}
Return

Rand(t) {
   static d := 0
   r := Round(t+d), d += t - r
   Return r
}

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (to4er) — Sun, 15 Feb 2015 11:32:27 +0000

Спасибо огромное за количество вариантов, объясню ТЗ . Нужен no recoil для шутера. Чтобы прицел не дергался, я указываю задержку в 25 мс. Но количества пикселей, на которые корректируется прицел при такой задержке, не всегда достаточно для точной правки отдачи. То есть, если если я укажу для определенного ствола 2, то прицел может уходить вверх, а укажу 3 - может чрезмерно крениться вниз. Поэтому мне нужны более мягкие коэффициенты, в пределах одного знака после запятой достаточно. Я не видел решения, как разделить пиксели, и хотел это сделать через Random. Есть один минус - рэндом такой рэндом, что может в пределах очереди в 5 выстрелов, при указании коэффициента 2.5 выдать пять двоек или пять троек, но все же в долгосрочной перспективе будет более точным, чем указать 2 или 3. Я просто не могу осилить, как написать функцию, чтобы при указании 2.7 вне зависимости от количества итераций у меня выходило в среднем приближенно к 2.7 и при этом функция выдавала бы правильный результат даже если сделано всего два выстрела.
Вывод в виде sendinput тут только для наглядности, чтобы увидеть как оно работает в блокноте, на самом деле нужна именно функция, которая обрабатывает переменную.

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (Irbis) — Sun, 15 Feb 2015 09:54:09 +0000

В первую очередь из соображений производительности.

Не думаю, что мат.операции проиграют в скорости RegEx, конечно можно устроить "полевые испытания", но вряд ли это имеет большое значение - скорость не относится к числу сильных сторон AHK.

Как зачем, в ТЗ после запятых пробелы.

Сейчас понятно, хотя посты #4 и #6 указывают, что готовая строка не нужна, a нужно элементы выводить по одному посредством SendInput. Все-таки сумбурность изложения ТЗ располагает к полету фантазии помогающих решить задачу. Так что можно обратно парсить строку для поэлементного вывода, или использовать массив:

F12::
   if !(Arr.MaxIndex())
   {
      Arr:=Rand(6.4)
      SendInput % " " ; для наглядности
   }
   SendInput % Arr.Remove()
Return

Rand(v) {
   r := [], b := 1, p1 := Floor(v), p2 := Round(v - p1, 1) * 10 
   loop 10
      Random, b, r.Insert(b, p1+(A_Index > p2)), r.MaxIndex() ? r.MaxIndex()+1 : 1
   Return r
}

В этом примере каждые 10 элементов (1-10, 11-20 и т.д.) строго в указанной пропорции, в отличие от поста #10.

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (serzh82saratov) — Sun, 15 Feb 2015 07:35:39 +0000

Так лучше, все-таки RegEx'ы не так очевидны в работе.

В первую очередь из соображений производительности.

А зачем StringReplace?

Как зачем, в ТЗ после запятых пробелы.

И все это дело обернуть в функцию, как хотел ТС.

Ну, это нелёгкое дело, можно переложить и на плечи ТС.

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (Irbis) — Sun, 15 Feb 2015 07:21:35 +0000

Так лучше, все-таки RegEx'ы не так очевидны в работе. А зачем StringReplace? (Он тут лишний, на мой взгляд).
И все это дело обернуть в функцию, как хотел ТС.

MsgBox % Rand(6.4)

Rand(v)
{
   p1 := Floor(v), p2 := Round(v - p1, 1) * 10 
   loop 10
      r .= (A_Index > p2 ? p1 : p1 + 1) . (A_Index < 10 ? "," : "")
   Sort, r, Random D,
   Return r
}

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (serzh82saratov) — Sun, 15 Feb 2015 06:42:11 +0000

Возможно, хотя ТЗ конечно немного размытое.
Да, и RegEx тут излишний.

v := 6.425
p1 := Floor(v), p2 := Round(v - p1, 1) * 10 
loop 10
   r .= (A_Index > p2 ? p1 : p1 + 1) . (A_Index < 10 ? "|" : "")
Sort, r, Random D|
StringReplace, r, r, |, `,%A_Space%, 1
MsgBox % r

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (Irbis) — Sun, 15 Feb 2015 03:55:13 +0000

Хм.. О таком варианте я не подумал, что нужна просто последовательность с определенным соотношением чисел, хотя это наиболее очевидно из ТЗ. В моей же функции соотношение выполняется для больших последовательностей, а для 10 чисел разброс может быть значительным в обе стороны. Тогда ваш вариант правильный.

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (serzh82saratov) — Sat, 14 Feb 2015 21:14:02 +0000

Так в шапке речь только про 10 случайных результатов. Значит 6.425 = 6.4.
Ну ещё можно тут добавить округление до десятых.

v := 6.425
RegExMatch(Round(v, 1), "(.*)\.(.)", p)  
loop 10
   r .= (A_Index > p2 ? p1 : p1 + 1) . (A_Index < 10 ? "," : "")
Sort, r, Random D,
StringReplace, r, r, `,, `,%A_Space%, 1
MsgBox % r

А вот про необходимость тысячи результатов, я видимо где то далее непрочитал.

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (Irbis) — Sat, 14 Feb 2015 21:03:52 +0000

Какие мудреные конструкции, вместо функции из пары строк. А если соотношение вероятностей не кратно 10, например для 6.425?

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (Alectric) — Sat, 14 Feb 2015 20:01:39 +0000

Так работает, но первое нажатие не считается.

#NoEnv
SendMode Input

var := 5.5
avar:=(var-var//1)*10
loop,% avar
  rand.=Round(var//1) "`n"
loop,% 10-avar
  rand.=Round(var//1+1) "`n"

F12::
now:=now="" ? 1 : now=10 ? 1 : now+1
if now=1
{
  Sort,rand,Random
  loop,parse,rand,`n
    rand%a_index%:=a_loopfield
send,{enter}  ; -------------------------для проверки---------------------
}
SendInput % rand%now%
return

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (serzh82saratov) — Sat, 14 Feb 2015 18:25:47 +0000

v := 7.600

RegExMatch(v, "(.*)\.(.)", p)  
loop 10
   r .= (A_Index > p2 ? p1 : p1 + 1) . (A_Index < 10 ? "," : "")
Sort, r, Random D,
StringReplace, r, r, `,, `,%A_Space%, 1
MsgBox % r

Re: AHK: Random, настройка вероятности выпадения двух чисел

null@example.com (Irbis) — Sat, 14 Feb 2015 12:26:15 +0000

Функция:

Rand(t) {
   Random, b, 0, 1.0
   Return Floor(t) + ((t-Floor(t)) > b)
}

Проверка работы:

V := 2.7 ; (2 - 30%, 3 - 70% на большой дистанции)
loop 10
   SendInput % Rand(V) " " 
; проверка среднего значения на 1000 итераций
count := 0
Loop 1000 {
   count+=Rand(V)
}
MsgBox % count/1000
Return

Rand(t) {
   Random, b, 0, 1.0
   Return Floor(t) + ((t-Floor(t)) > b)
}