Серый форум — AHK: Сокращение клавиатуры до 9 клавиш

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (serzh82saratov) — Wed, 01 Apr 2015 05:35:50 +0000

Не, я про то что Ты и так уже упростил до нельзя. По поводу скорости ввода для ТС, я бы в твоей идее, смену вариантов повесил бы на Ctrl,Alt,Shift.

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (Irbis) — Tue, 31 Mar 2015 20:00:03 +0000

Буду только рад, если можно сделать проще.
Вроде и так до минимума сократил, можно откинуть индикацию русской раскладки - будет веселей набирать на великом и могучем, с подсказкой "QWE...". ))

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (serzh82saratov) — Tue, 31 Mar 2015 19:20:13 +0000

Ну вот опять всё упрощать, Алану Тьюрингу это бы всё понравилось, зуб даю.

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (Irbis) — Tue, 31 Mar 2015 19:02:46 +0000

Присоединяюсь к вопросу про клавиатуру. Все-таки любые попытки длительно и в больших объемах работать с "усеченными" вариантами отдают мазохизмом. Если мышь работает (что уже хорошо), можно переключение наборов повесить на колесико. Включение/отключение режима - комбинацией Ctrl+Shift+Z.

#NoEnv
Keys:= {"vk51":["vk51","vk52","vk55","vk50"]
       ,"vk57":["vk57","vk54","vk49","vkDB"]
       ,"vk45":["vk45","vk59","vk4F","vkDD"]
       ,"vk41":["vk41","vk46","vk4A","vkBA"]
       ,"vk53":["vk53","vk47","vk4B","vkDE"]
       ,"vk44":["vk44","vk48","vk4C","vkDC"]
       ,"vk5A":["vk5A","vk56","vk4D","vkBF"]
       ,"vk58":["vk58","vk42","vkBC","vk8"]
       ,"vk43":["vk43","vk4E","vkBE","vkD"]}
Set:=1
Tips := {"English":["QWE`nASD`nZXC","RTY`nFGH`nVBN","UIO`nJKL`nM , .","P [ ]`n; ' \`n/B En"]
        ,"Russian":["ЙЦУ`nФЫВ`nЯЧС","КЕН`nАПР`nМИТ","ГШЩ`nОЛД`nЬБЮ","ЗХЪ`nЖЭ\`n.B En"]}
for k, v in Keys {
   HotKey, if, Print
   Hotkey, %k%, MKey
}
SetTimer, Watch, 50
return

^+vk5A:: Print:=!Print ; Ctrl+Shift+Z
#If Print
WheelUp::(Set<4)&&Set++
WheelDown::(Set>1)&&Set--
#If

MKey:
SendInput % "{" . Keys[A_ThisHotkey][Set] . "}"
Return
Watch:
   Tooltip % Print? Tips[InputLayout()][Set] : ""
Return

InputLayout(window := "A") {
   If !(hWnd := WinExist(window))
      return
   WinGetClass, Class
   if (Class == "ConsoleWindowClass"){
       WinGet, consolePID, PID
       DllCall("AttachConsole", Ptr, consolePID)
       VarSetCapacity(buff, 16)
       DllCall("GetConsoleKeyboardLayoutName", Str, buff),
       DllCall("FreeConsole")
       langID := "0x" . SubStr(buff, -3)
   }
   Else langID := DllCall("GetKeyboardLayout", Ptr, DllCall("GetWindowThreadProcessId", Ptr, hWnd, UInt, 0, Ptr), Ptr) & 0xFFFF
   Size := (DllCall("GetLocaleInfo", UInt, langID, UInt, 0x1001, UInt, 0, UInt, 0) * 2)   ; LOCALE_SENGLANGUAGE := 0x1001
   VarSetCapacity(localeSig, Size, 0)
   DllCall("GetLocaleInfo", UInt, langID, UInt, 0x1001, Str, localeSig, UInt, Size)
   return localeSig
}

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (ypppu) — Tue, 31 Mar 2015 16:56:18 +0000

Купить новую клавиатуру или починить старую не проще, чем запоминать массу комбинаций?

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (serzh82saratov) — Tue, 31 Mar 2015 16:35:20 +0000

На 27 букв хватит, + ещё сами 9 кнопок. Если добавить Shift то 63+9.

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (HideGenius) — Tue, 31 Mar 2015 15:40:50 +0000

Alectric, и как мне с помощю ctrl+alt заменить все буквы клавиатуры?

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (Alectric) — Tue, 31 Mar 2015 13:58:01 +0000

Может будет оптимальней использовать комбинации вроде: Ctrl+Alt+"буква". Да и по скорости не так медленно будет.

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (HideGenius) — Tue, 31 Mar 2015 12:22:40 +0000

serzh82saratov, скорости печати. Сейчас нужно удерживать Q и нажимать W тогда будет буква R да и если поодиночно нажимать быстро одинарные (Q W E) клавиши то они не печатают ничего. Быстрее будет если нажимаешь Q, отпускаешь и если в течении милисекунди нажимаешь W то тогда будет буква R.

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (serzh82saratov) — Fri, 27 Mar 2015 16:53:09 +0000

Скорости чего?

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (HideGenius) — Fri, 27 Mar 2015 12:01:52 +0000

serzh82saratov, спаисбо все работает. Жаль вот скорости нельзя добавить.

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (serzh82saratov) — Fri, 27 Mar 2015 05:35:32 +0000

ТС пишет:

we = u
ew = i
qw = r
wq = y

Тут в Action указаны только эти сочетания, по аналогии надо дописать далее.

#UseHook

Action := {"vk57-vk45":"{vk55}","vk45-vk57":"{vk49}"  ; we = u , ew = i
    , "vk51-vk57":"{vk52}","vk57-vk51":"{vk59}"}   ; qw = r  , wq = y

Keys := "vk51|vk57|vk45|vk41|vk53|vk44|vk5A|vk58|vk43"
   ;   " Q  | W  | E  | A  | S  | D  | Z  | X  | C  "
   
Loop, Parse, Keys, |
{
    Hotkey, %A_LoopField%, Hotkey
    Hotkey, %A_LoopField% Up, Hotkey_Up
}
Return

Hotkey: 
    If (k = "")
        k := A_ThisHotkey, i := 0
    Else If (k != A_ThisHotkey && (i := 1))
        SendInput % Action[k "-" A_ThisHotkey] 
    Return
    
Hotkey_Up:
    If ((TH := SubStr(A_ThisHotkey, 1, -3)) = k && !(k := ""))
        If !i
            SendInput {%TH%}
    Return

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (Malcev) — Fri, 27 Mar 2015 00:17:12 +0000

q & w::
w & q::
Hotkey, *q up, off
Hotkey, *w up, off
if GetKeyState("control", "P")
   send ctrl q w
else if GetKeyState("alt", "P")
      send  alt q w
else
      send  q w
KeyWait q
KeyWait w
Hotkey, *q up, on
Hotkey, *w up, on
return

*q up::
if GetKeyState("control", "P")
      send  ctrl q
else if GetKeyState("alt", "P")
      send  alt q
else
      send  q
return

*w up::
if GetKeyState("control", "P")
      send  ctrl w
else if GetKeyState("alt", "P")
      send  alt w
else
      send  w
return

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (HideGenius) — Thu, 26 Mar 2015 23:38:46 +0000

Malcev, сочетание ctrl+w все равно не работает как и другие.

Re: AHK: Сокращение клавиатуры до 9 клавиш

null@example.com (Malcev) — Thu, 26 Mar 2015 22:45:40 +0000

Например так:

q & w::
w & q::
Send, r
return

*q up::
if !GetKeyState("w", "P")
   Send, q
return

*w up::
if !GetKeyState("q", "P")
   Send, w
return