Серый форум — А как сделать чтобы одним ярлыком запустить два разных скрипта?

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (kamenschik) — Tue, 05 May 2015 07:10:31 +0000

Malcev пишет:

Что-то вы усложняете.
Пример обмена сообщениями между скриптами по ссыдке в самом низу.
http://ahkscript.org/docs/commands/OnMessage.htm

Что-то да, усложняю. Но всё равно пригодится, не в данном случае , так потом.
Просто может случится так что мне всё же нужно будет использовать Joy для того чтобы запустить тот скрипт, возможно это хорошо что он параллельно запускает и некоторые команды. Но не все нужно тогда.

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (Malcev) — Tue, 05 May 2015 04:44:37 +0000

Что-то вы усложняете.
Пример обмена сообщениями между скриптами по ссыдке в самом низу.
http://ahkscript.org/docs/commands/OnMessage.htm

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (kamenschik) — Mon, 04 May 2015 18:35:29 +0000

Так. Что-то странное творится, не спал вчера ночью, показалось что такое безобразие запустилось, сейчас проверил - что-то я наверное не то писал - не может вообще скрипт запустится так, пишет ошибку.

Теперь всё ясно.

Не ясно только как отправить:

f:=0

Из закрывающегося первого скрипта в открытый.

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (kamenschik) — Mon, 04 May 2015 14:34:10 +0000

Malcev пишет:

У комманды OnExit только один параметр - это метка, куда перейдет скрипт перед тем как прекратить работу.
То есть нужно создать метку и уже под ней вписать необходимые комманды.

А можно сделать так?:
Скрипт закрывается при нажатии на Joy5 и открывается второй. В первом скрипте я пишу первую часть команды OnExit, а метку пишу во втором. После перехода на метку, во втором скрипте, отдаётся команда :

f:=0

Просто во втором у меня написано что:

Joy5::f:=1

Получается так, что при запуске второго скрипта выполняется и эта команда, а мне это не надо. Нужно сразу отключить.

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (kamenschik) — Tue, 28 Apr 2015 21:51:26 +0000

yalanne пишет:

Вроде как исправил этот баг то что едет в угол + сделал дополнительное окно, показывает каким стиком управляется и скорость по x и y.

Нет, не исправил Всё равно уезжает, ехать начинает безостановочно сразу после запуска.

Я сделал. Всё рабочее - джойстики, кнопки, крестовина работает как кнопки Вперёд-Назад-Влево-Вправо. Потом допишу чтобы при зажатии крестовины двигалось пока не отпустишь. Спасибо за идею написать Stick1,Stick2. C Joy1,Joy2 почему-то не вышло.

Теперь оба в одном коде.


Stick1Multiplier = 0.3
Stick2Multiplier = 0.015

Stick1Threshold = 3
Stick2Threshold = 3

InvertYAxis := false
InvertZAxis := false

ButtonLeft = 1
ButtonRight = 3

Stick1Number = 1
Stick2Number = 1

#SingleInstance

Stick1Prefix = %Stick1Number%Joy
Stick2Prefix = %Stick2Number%Joy
Hotkey, %Stick1Prefix%%ButtonLeft%, ButtonLeft
Hotkey, %Stick2Prefix%%ButtonRight%, ButtonRight

Stick1ThresholdUpper := 50 + Stick1Threshold
Stick1ThresholdLower := 50 - Stick1Threshold
if InvertYAxis
    YAxisMultiplier = -1
else
    YAxisMultiplier = 1

SetTimer, WatchStick1, 10

Stick2ThresholdUpper := 50 + Stick2Threshold
Stick2ThresholdLower := 50 - Stick2Threshold
if InvertZAxis
    ZAxisMultiplier = -1
else
    ZAxisMultiplier = 1

SetTimer, WatchStick2, 10

GetKeyState, JoyInfo, %Stick1Number%JoyInfo
IfInString, JoyInfo, P
    SetTimer, WatchPOV, 5
return

ButtonLeft:
SetMouseDelay, -1
MouseClick, left,,, 1, 0, D
SetTimer, WaitForLeftButtonUp, 10
return

ButtonRight:
SetMouseDelay, -1 
MouseClick, right,,, 1, 0, D
SetTimer, WaitForRightButtonUp, 10
return

WaitForLeftButtonUp:
if GetKeyState(Stick1Prefix . ButtonLeft)
    return
SetTimer, WaitForLeftButtonUp, off
SetMouseDelay, -1
MouseClick, left,,, 1, 0, U
return

WaitForRightButtonUp:
if GetKeyState(Stick2Prefix . ButtonRight)
    return 
SetTimer, WaitForRightButtonUp, off
MouseClick, right,,, 1, 0, U
return

WatchStick1:
MouseNeedsToBeMoved := false
SetFormat, float, 03
GetKeyState, joyx, %Stick1Number%JoyX
GetKeyState, joyy, %Stick1Number%JoyY

if joyx > %Stick1ThresholdUpper%
{
    MouseNeedsToBeMoved := true
    DeltaX := joyx - Stick1ThresholdUpper
}
else if joyx < %Stick1ThresholdLower%
{
    MouseNeedsToBeMoved := true
    DeltaX := joyx - Stick1ThresholdLower
}
else
    DeltaX = 0
if joyy > %Stick1ThresholdUpper%
{
    MouseNeedsToBeMoved := true
    DeltaY := joyy - Stick1ThresholdUpper
}
else if joyy < %Stick1ThresholdLower%
{
    MouseNeedsToBeMoved := true
    DeltaY := joyy - Stick1ThresholdLower
}
else
    DeltaY = 0
if MouseNeedsToBeMoved
{
    SetMouseDelay, -1
    MouseMove, DeltaX * Stick1Multiplier, DeltaY * Stick1Multiplier * YAxisMultiplier, 0, R
}
return

WatchStick2:
MouseNeedsToBeMoved := false
SetFormat, float, 03
GetKeyState, joyr, %Stick2Number%JoyR
GetKeyState, joyz, %Stick2Number%JoyZ

if joyr > %Stick2ThresholdUpper%
{
    MouseNeedsToBeMoved := true
    DeltaX := joyr - Stick2ThresholdUpper
}
else if joyr < %Stick2ThresholdLower%
{
    MouseNeedsToBeMoved := true
    DeltaX := joyr - Stick2ThresholdLower
}
else
    DeltaX = 0
if joyz > %Stick2ThresholdUpper%
{
    MouseNeedsToBeMoved := true
    DeltaY := joyz - Stick2ThresholdUpper
}
else if joyz < %Stick2ThresholdLower%
{
    MouseNeedsToBeMoved := true
    DeltaY := joyz - Stick2ThresholdLower
}
else
    DeltaY = 0
if MouseNeedsToBeMoved
{
    SetMouseDelay, -1
    MouseMove, DeltaX * Stick2Multiplier, DeltaY * Stick2Multiplier * ZAxisMultiplier, 0, R
}
return

WatchPOV:
GetKeyState, POV, JoyPOV
KeyToHoldDownPrev = %KeyToHoldDown%
if POV < 0
    KeyToHoldDown =
else if POV > 31500
    KeyToHoldDown = Up
else if POV between 0 and 4500
    KeyToHoldDown = Up
else if POV between 4501 and 13500
    KeyToHoldDown = Right
else if POV between 13501 and 22500
    KeyToHoldDown = Down
else
    KeyToHoldDown = Left

if KeyToHoldDown = %KeyToHoldDownPrev%
    return

SetKeyDelay -1
if KeyToHoldDownPrev
    Send, {%KeyToHoldDownPrev% up}
if KeyToHoldDown
    Send, {%KeyToHoldDown% down}
return

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (yalanne) — Sun, 26 Apr 2015 13:34:52 +0000

Вроде как исправил этот баг то что едет в угол + сделал дополнительное окно, показывает каким стиком управляется и скорость по x и y.

#Persistent
speed_stick1 = 0.3
speed_stick2 = 0.09
JoyThreshold = 3

gui add,text,w150 h50,
gui show,x0 y0 NA

SetMouseDelay, -1
JoyThresholdUpper := getkeystate("joyx","p") + JoyThreshold
JoyThresholdLower := getkeystate("joyx","p") - JoyThreshold
settimer cursor_joy,10
return
cursor_joy:
DeltaX := getkeystate("joyx","p")
DeltaY := getkeystate("joyy","p")
DeltaU := getkeystate("joyu","p")
DeltaV := getkeystate("joyv","p")

buf_x := (DeltaX < JoyThresholdLower) ? -1 : (DeltaX > JoyThresholdUpper) ? 1
    : (DeltaV < JoyThresholdLower) ? -2 : (DeltaV > JoyThresholdUpper) ? 2 : 0

buf_y := (DeltaY < JoyThresholdLower) ? -1 : (DeltaY > JoyThresholdUpper) ? 1
    : (DeltaU < JoyThresholdLower) ? -2 : (DeltaU > JoyThresholdUpper) ? 2 : 0


Xmove := Round((buf_x = -1) ? (DeltaX-JoyThresholdLower)*speed_stick1 : (buf_x = 1) ? (DeltaX-JoyThresholdUpper)*speed_stick1 
         : (buf_x = -2) ? (DeltaV-JoyThresholdLower)*speed_stick2 : (buf_x = 2) ? (DeltaV-JoyThresholdUpper)*speed_stick2 : 0 )

Ymove := Round((buf_x = -1) ? (DeltaY-JoyThresholdLower)*speed_stick1 : (buf_x = 1) ? (DeltaY-JoyThresholdUpper)*speed_stick1 
         : (buf_x = -2) ? (DeltaU-JoyThresholdLower)*speed_stick2 : (buf_x = 2) ? (DeltaU-JoyThresholdUpper)*speed_stick2 : 0 )

guicontrol,, static1, % (((buf_x=-1) or (buf_x=1) or (buf_y=-1) or (buf_y=1)) ? "Первый стик" 
    : ((buf_x=-2) or (buf_x=2) or (buf_y=-2) or (buf_y=2)) ? "Второй стик" 
    : "Не используется") "`nСкорость по X:" Xmove "`nСкорость по Y:" Ymove
if Xmove or Ymove
MouseMove, Xmove, Ymove, 0, R
return

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (yalanne) — Thu, 23 Apr 2015 16:51:34 +0000

У меня вот так работает: Видео
Для трансляции экрана телефона я использовал программу BBQScreen Client
А для эмулирования геймпада Monect

п.с как видео вставлять в этом форуме?

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (yalanne) — Thu, 23 Apr 2015 15:12:39 +0000

А едет при каких условиях?

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (kamenschik) — Thu, 23 Apr 2015 15:00:07 +0000

yalanne пишет:

Вот вторая версия:

Всё равно уезжает, но я попробую переделать.
Ушёл думать.

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (Malcev) — Thu, 23 Apr 2015 14:48:52 +0000

У комманды OnExit только один параметр - это метка, куда перейдет скрипт перед тем как прекратить работу.
То есть нужно создать метку и уже под ней вписать необходимые комманды.

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (kamenschik) — Thu, 23 Apr 2015 14:23:44 +0000

Malcev пишет:

Так понятней?

Мне понятно что ExitSub имеет отношение к запуску msgbox и только, и очевидно не поможет мне закрыть скрипт для второго джойстика. И ещё то, что попытки записать:

OnExit, WinClose, Metro2033_2.ahk

Ровно как и:

OnExit, WinClose, Metro2033_2-Блокнот

Закончились неудачей. Потому что логика у записи видимо должна быть другой, а примеров там нет такого рода.

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (Malcev) — Thu, 23 Apr 2015 04:36:53 +0000

Я нашёл в переводе про OnExit, но там так написано что начинающему трудно понять

Так понятней?

#Persistent
OnExit, ExitSub
return

ExitSub:
msgbox, скрипт закончил свою работу
ExitApp

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (yalanne) — Wed, 22 Apr 2015 21:32:20 +0000

Вот вторая версия:

#Persistent
speed_stick1 = 0.3
speed_stick2 = 0.09

SetMouseDelay, -1
default := Ceil(getkeystate("joyx","p"))
settimer cursor_joy,10
return
cursor_joy:
DeltaX := Ceil(getkeystate("joyx","p"))
DeltaY := Ceil(getkeystate("joyy","p"))
DeltaU := Ceil(getkeystate("joyu","p"))
DeltaV := Ceil(getkeystate("joyv","p"))
% (buf := (DeltaX != default) + ((DeltaV != default) ? 2 : 0))
Xmove := Ceil((default - ((buf=1) ? DeltaX : (buf>=2) ? DeltaV : "")) * ((buf=1) ? speed_stick1 : (buf>=2) ? speed_stick2 : 0))*-1
Ymove := Ceil((default - ((buf=1) ? DeltaY : (buf>=2) ? DeltaU : "")) * ((buf=1) ? speed_stick1 : (buf>=2) ? speed_stick2 : 0))*-1
if Xmove or Ymove
MouseMove, Xmove, Ymove, 0, R
return

в этой версии скорость надо указывать в дробях.

+ Как это работает

+ Строка 1

#Persistent

без этой строки скрипт сразу же закроется при запуске.

+ Строка 2-3

speed_stick1 = 0.3
speed_stick2 = 0.09

Скорость первого и второго стика. указывать дробью

+ Строка 5

SetMouseDelay, -1

уберает задержку у команды MouseMove

+ Строка 6

default := Ceil(getkeystate("joyx","p"))

в переменной default будет хранится начальная позиция стиков. по ходу работы скрипта эта переменная не меняется.С помощью Ceil число округляется в большую сторону.

+ Строка 7-8

settimer cursor_joy,10
return

каждые 10мс будет вызываться метка cursor_joy

+ Строка 10-13

DeltaX := Ceil(getkeystate("joyx","p"))
DeltaY := Ceil(getkeystate("joyy","p"))
DeltaU := Ceil(getkeystate("joyu","p"))
DeltaV := Ceil(getkeystate("joyv","p"))

записывает положение стиков.XY для первого и UV для второго

+ Строка 14

% (buf := (DeltaX != default) + ((DeltaV != default) ? 2 : 0))

В переменную buf записывается число от 1 до 3.Если цифра 1 то используется первый стик. Если 2-3 то второй стик

+ Строка 15-16

Xmove := Ceil((default - ((buf=1) ? DeltaX : (buf>=2) ? DeltaV : "")) * ((buf=1) ? speed_stick1 : (buf>=2) ? speed_stick2 : 0))*-1

X\Ymove хранится число на которое будет смещение курсора.
Из начальной позиции вычитает положение стика умножается на ту цифру скорости которая соответствует стику и умножает на -1 что бы стороны соответствовали.

+ Строка 17-18

Если новый x и y не равно нулю то курсор смещается

+ Строка 10

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (kamenschik) — Wed, 22 Apr 2015 21:23:21 +0000

teadrinker пишет:

yalanne пишет:
Экспериментировал не совсем на джостике.
А на смартфоне эмулирующий джостик который по wifi передает ноуту команды джостика.
Возможно с настоящим будет работать не так как задумано.

Курсор едет в верхний левый угол.

Re: А как сделать чтобы одним ярлыком запустить два разных скрипта?

null@example.com (teadrinker) — Wed, 22 Apr 2015 21:05:40 +0000

yalanne пишет:

Вот что у меня получилось.
#Persistent
speed_stick1 = 10
speed_stick2 = 5

SetMouseDelay, -1
default := getkeystate("joyx","p")
settimer cursor_joy,1
return
cursor_joy:
DeltaX := getkeystate("joyx","p")
DeltaY := getkeystate("joyy","p")
DeltaU := getkeystate("joyu","p")
DeltaV := getkeystate("joyv","p")
Xmove := ((buf := (DeltaX != default) + ((DeltaV != default) ? 2 : 0)) and (buf=1) ? speed_stick1 : (buf>=2) ? speed_stick2 : 0), ((DeltaX < default) or (DeltaV < default)) and (Xmove*=-1)
Ymove := ((buf := (DeltaY != default) + ((DeltaU != default) ? 2 : 0)) and (buf=1) ? speed_stick1 : (buf>=2) ? speed_stick2 : 0), ((DeltaY < default) or (DeltaU < default)) and (Ymove*=-1)
if Xmove or Ymove
MouseMove, Xmove, Ymove, 0, R
return
У первого стика будет скорость передвижения мыши 10
У второго стика будет скорость передвижения мыши 5
Экспериментировал не совсем на джостике.
А на смартфоне эмулирующий джостик который по wifi передает ноуту команды джостика.
Возможно с настоящим будет работать не так как задумано.