Серый форум — AHK: Рандомизация значений параметров команд

Re: AHK: Рандомизация значений параметров команд

null@example.com (Irbis) — Wed, 17 Jun 2015 23:07:35 +0000

Что и требовалось доказать - для пользователя лучше как проще (понять), а не как лучше. ))
Если уж и этот "наиболее понятный новичку" код копнуть, то не выглядит ли лишней двойная проверка?

else if (rand >= 0.2 && rand < 0.5)

Левая граница каждого интервала и так проверяется в предыдущем if.
Заодно и от абсолютных значений границ интервалов можно избавиться и для этого случая, как и для уже предложенных ранее.
Пример для 5 точек, с распределением 10 - 40 - 30 - 2.5 - 17.5 %

points := [ [200, 100], [300, 400], [500, 600] ] ; добавить для 4 и 5 точек
Random, rand, 0.0, 1.0

if      (rand < t:= 0.1)
   i := 1
else if (rand < t+= 0.4)
   i := 2
else if (rand < t+= 0.3)
   i := 3
else if (rand < t+= 0.025)
   i := 4
else
   i := 5

point := points[i]
; CoordMode, Mouse, Screen  ; раскомментировать, если координаты относительно экрана
MouseClick, R, point[1], point[2], 1, 100

Проверка:

SetBatchLines -1
Arr := [0,0,0,0,0]
loop 100000 {
Random, rand, 0.0, 1.0

if      (rand < t:= 0.1)
   Arr[1]++
else if (rand < t+= 0.4)
   Arr[2]++
else if (rand < t+= 0.3)
   Arr[3]++
else if (rand < t+= 0.025)
   Arr[4]++
else
   Arr[5]++
}
MsgBox % Arr[1] "  " Arr[2] "  " Arr[3] "  " Arr[4] "  " Arr[5]

Re: AHK: Рандомизация значений параметров команд

null@example.com (serzh82saratov) — Wed, 17 Jun 2015 22:22:45 +0000

Ну так разве как новичку обязательно знать как это работает, чтобы этим пользоватся?
Я вот например не изучал исходный код виндовс перед использованием.

points := {[200, 100]: 20, [300, 400]: 30, [500, 600]: 50} ; изменять только здесь, остальное не трогать.

for k, v in points, sum := 0
   sum += v 

1:: ; запуск подпрограммы
    Random, rand, , 1.
    for point, v in points, prev := 0
        prev += v/sum
    until rand <= prev  
    ; CoordMode, Mouse, Screen  ; раскомментировать, если координаты относительно экрана
    MouseClick, R, point[1], point[2], 1, 100
    Return

Вот всё что нужно, чтобы добавить ещё одни координаты.

points := {[50, 50]: 10, [200, 100]: 20, [300, 400]: 30, [500, 600]: 40}

Re: AHK: Рандомизация значений параметров команд

null@example.com (panamaboot) — Wed, 17 Jun 2015 21:43:24 +0000

Для меня, как для начинающего, более всего понятен код:

points := [ [200, 100], [300, 400], [500, 600] ]
Random, rand, 0.0, 1.0

if (rand < 0.2)
   i := 1
else if (rand >= 0.2 && rand < 0.5)
   i := 2
else
   i := 3

point := points[i]
; CoordMode, Mouse, Screen  ; раскомментировать, если координаты относительно экрана
MouseClick, R, point[1], point[2], 1, 100

Даже сварганил для четырёх и пяти точек ^_^. Всем спасибо господа.

Re: AHK: Рандомизация значений параметров команд

null@example.com (teadrinker) — Wed, 17 Jun 2015 18:56:02 +0000

Я просто хотел показать, что вариант с диапазонами ничем не хуже других. Точнее, все наши варианты, если их достаточно сократить, становятся похожими друг на друга. И даже твой первый вариант по сути "недосокращённый" алгоритм Уолкера.

Re: AHK: Рандомизация значений параметров команд

null@example.com (serzh82saratov) — Wed, 17 Jun 2015 18:48:35 +0000

Ну ты хватил на миллион, на тысячу в большинстве случаев как раз 0,5 процента погрешность.

Почему? Создание и проверку диапазонов значений можно ведь автоматизировать, причём в одном и том же цикле:

Собственно и спорить уже не о чем, вариант с процентами в массиве удобен и понятен, с портянкой условий был не айс.

Re: AHK: Рандомизация значений параметров команд

null@example.com (teadrinker) — Wed, 17 Jun 2015 18:34:29 +0000

Не совсем понял, почему без возможности повторов.

SetBatchLines, -1
obj := {A: 1.5, B: 97, C: 1.5}

for k, v in obj, sum := 0
   sum += v

test := {A: 0, B: 0, C: 0}
Loop % N := 10**6  {
   Random, rand,, 1.
   for k, v in obj, prev := 0
      prev += v/sum
   until rand <= prev && test[k]++
}
   
MsgBox, % "A — " Round(test.A/N*100, 1) "%`nB — " Round(test.B/N*100, 1) "%`nC — " Round(test.C/N*100, 1) "%"

(Займёт какое-то время на выполнение.)

Re: AHK: Рандомизация значений параметров команд

null@example.com (serzh82saratov) — Wed, 17 Jun 2015 18:29:39 +0000

Ну по теме на вряд ли это требуется, если уже и диапазоны в 5% предлагаются. Ну а так или 15 из 1000, или 2 вариант. Но учитывая что теоретически Random из 5 может 5 пятёрок выдать, 3 из 5 я сам видел, то 0,5 процента просто ни на что не повлияет. Для такой точности есть алгоритм без возможности повтора вариантов в диапазоне.

Re: AHK: Рандомизация значений параметров команд

null@example.com (teadrinker) — Wed, 17 Jun 2015 13:25:14 +0000

serzh82saratov пишет:

Создание строки условий для например 50 координат, и в будущем правка пары значений, то есть поиск где в массиве 22 и 39 ключ, и где их соответствие в строке условий, будет непростым.

Почему? Создание и проверку диапазонов значений можно ведь автоматизировать, причём в одном и том же цикле:

obj := {A: 2, B: 3, C: 5}

for k, v in obj, sum := 0
   sum += v

Random, rand,, 1.
for k, v in obj, prev := 0
    prev += v/sum   ; создаём диапазон для каждого ключа
until rand <= prev  ; и сразу проверяем, не попал ли rand в него
   
MsgBox, % k

Можно заметить, что этот вариант практически идентичен вышеприведённому алгоритму:

obj := {A: 2, B: 3, C: 5}
for k, v in obj, _sum := 0
   _sum += v

Random, peek, 1, _sum
for k, v in obj, sum := 0
   sum += v
until sum >= peek

MsgBox, % k

Проверяем правильность алгоритма:

obj := {A: 2, B: 3, C: 5}

for k, v in obj, sum := 0
   sum += v

test := {A: 0, B: 0, C: 0}
Loop % N := 10000  {
   Random, rand,, 1.
   for k, v in obj, prev := 0
      prev += v/sum
   until rand <= prev && test[k]++
}
   
MsgBox, % "A — " Round(test.A/N*100, 1) "%`nB — " Round(test.B/N*100, 1) "%`nC — " Round(test.C/N*100, 1) "%"

А теперь тебе вопрос на засыпку. Как с помощью твоего производительного способа можно рассчитать вероятность равную 1.5% ?

Re: AHK: Рандомизация значений параметров команд

null@example.com (Irbis) — Wed, 17 Jun 2015 09:45:19 +0000

teadrinker пишет:

Если не читал — молодец.

Тоже не читал, но хотел предложить подобный вариант. )) Правда, в нем было запланировано лишнее действие по нормализации суммы вероятностей - приведении к 100%, чтобы выбирать координату на основе случайного числа в интервале 1...100. Ваш вариант с числом от 1 до sum лучше.

teadrinker пишет:

Почему производительнее — не понимаю, там ведь лишнее действие

Массив один раз строится (предвычисление), а затем скорость получения n-го элемента не зависит от n.
В случае с for для n-ного элемента цикл совершит n итераций. Хотя в случае с небольшим количеством это роли не играет. Да и воoбще, как уже было сказано не раз, в списке причин для использовония autohotkey производительность находится далеко не в самом верху.

Re: AHK: Рандомизация значений параметров команд

null@example.com (serzh82saratov) — Wed, 17 Jun 2015 08:19:04 +0000

Этого не нужно.

А, ну да, ещё лучше.

Почему производительнее — не понимаю, там ведь лишнее действие.

Для получения результата требуется только извлечение из массива, никаких сравнений и переборов.
А какое лишнее действие?

Звучит не очень просто. В моём варианте ничего дополнительно создавать не нужно.

Создание строки условий для например 50 координат, и в будущем правка пары значений, то есть поиск где в массиве 22 и 39 ключ, и где их соответствие в строке условий, будет непростым. Ну а новичкам ведь всё равно как работает, и если он тот самый 1 из 1000, думаю объяснить это будет проще, чем Walker's Alias Method.

Re: AHK: Рандомизация значений параметров команд

null@example.com (teadrinker) — Wed, 17 Jun 2015 04:28:28 +0000

Если не читал — молодец.

Тут пары в массиве надо располагать по мере возрастания процентов.

Этого не нужно.

удобнее и производительнее

Почему производительнее — не понимаю, там ведь лишнее действие.

1 вариант тоже очень прост, создаётся "список" с одинаковыми "строками", количество которых равно количеству вариантов.

Звучит не очень просто. В моём варианте ничего дополнительно создавать не нужно.

Re: AHK: Рандомизация значений параметров команд

null@example.com (serzh82saratov) — Wed, 17 Jun 2015 03:15:35 +0000

я тоже прочитал

Честно говоря, я не читал.

Немного подправил #21, если процент будет значением в массиве, ещё нагляднее.

Считаю что в #21, 1 вариант без этого алгоритма, для работы с заранее известными вероятностями, удобнее и производительнее.

зато проще для понимания.

1 вариант тоже очень прост, создаётся "список" с одинаковыми "строками", количество которых равно количеству вариантов. Далее просто выбирается строка по случайному индексу.

Re: AHK: Рандомизация значений параметров команд

null@example.com (teadrinker) — Tue, 16 Jun 2015 23:34:54 +0000

serzh82saratov, я тоже прочитал про этот алгоритм — 1, 2, 3.

obj := {A: 20, B: 30, C: 50}
Random, peek, 1, 100
for k, v in obj, sum := 0
   sum += v
until sum >= peek
MsgBox, % k

В общем случае:

obj := {A: 2, B: 3, C: 5}
for k, v in obj, _sum := 0
   _sum += v

Random, peek, 1, _sum
for k, v in obj, sum := 0
   sum += v
until sum >= peek

MsgBox, % k

Проверка:

obj := {A: 2, B: 3, C: 5}
for k, v in obj, _sum := 0
   _sum += v

test := {A: 0, B: 0, C: 0}
Loop 10000  {
   Random, peek, 1, _sum
   for k, v in obj, sum := 0
      sum += v
   until sum >= peek && test[k]++
}

MsgBox, % test.A "`n" test.B "`n" test.C

Что же касается моего варианта, то он тоже вполне имеет право на существование, он хоть и менее нагляден, зато проще для понимания.

Re: AHK: Рандомизация значений параметров команд

null@example.com (Irbis) — Tue, 16 Jun 2015 18:01:10 +0000

Чуть позже напишу вариант, чтобы было скучно.

Re: AHK: Рандомизация значений параметров команд

null@example.com (serzh82saratov) — Tue, 16 Jun 2015 16:42:14 +0000

Да, не сообразил, но за-то при изменениях вероятностей будет всегда не скучно.