Серый форум — AHK: Копирование адресной строки браузера и дальнейшая работа с ней

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Sat, 05 May 2018 10:44:53 +0000

В общем с #If существуют ограничения, так что код из 31 поста, наверное, единственный способ.
https://autohotkey.com/boards/viewtopic … mp;t=48444

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Tue, 01 May 2018 05:37:16 +0000

Там если и ответят, то только на вопрос почему acc не работает с директивой.
Так попробуйте:

LButton::
if test()
   tooltip 11111111111111
else
{
   Click Down
   Keywait, LButton
   Click Up
}

test()
{
   Critical
   MouseGetPos, , , WinId, ControlNN
   WinGet, Process, ProcessName, ahk_id %WinId%
   if (Process = "chrome.exe")
      Control := "", name := "Address and search bar"
   else if (Process = "firefox.exe")
      Control := "", name := "Search or enter address"
   else
      return 0
   if (ControlNN != Control)
      return 0
   if (Acc_c(child).accName(child) = name)
      return 1
}

Acc_c(ByRef _idChild_ = "", x = "", y = "")
{
	Static	h
	If Not	h
		h:=DllCall("LoadLibrary","Str","oleacc","Ptr")
	If	DllCall("oleacc\AccessibleObjectFromPoint", "Int64", x==""||y==""?0*DllCall("GetCursorPos","Int64*",pt)+pt:x&0xFFFFFFFF|y<<32, "Ptr*", pacc, "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild)=0
	Return	ComObjEnwrap(9,pacc,1), _idChild_:=NumGet(varChild,8,"UInt")
}

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (DD) — Mon, 30 Apr 2018 20:01:49 +0000

Не понял, как там все это работает. Наверное, подожду, спасибо.

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Mon, 30 Apr 2018 19:37:22 +0000

DD пишет:

первый работает с директивой и без

С директивой работает неправильно.
Вам остаётся объединить 26 код с 27, но не использовать директиву а проверять куда был совершен клик после нажатия левой кнопки мыши.
Ну или ждать, что ответят на оффоруме.
Я написал там об этом.

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (DD) — Mon, 30 Apr 2018 18:52:37 +0000

То же самое — первый работает с директивой и без, а второй — никак. А что если считывание текста из строки адреса сочетать с проверкой формы курсора? Или если возможно — наличием полосы прокрутки справа, тогда без настроек это работало бы во всех браузерах?

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Mon, 30 Apr 2018 15:46:56 +0000

У меня почему-то при директиве #If AccessibleObjectFromPoint выдает неверный результат.
Попробуйте навести мышку на адрессную строку и понажимать f10, f11.

#If !test()
f10:: return 
#If
return

f11::test()
return

test()
{
tooltip % Acc_c(child).accName(child)
}

Acc_c(ByRef _idChild_ = "", x = "", y = "")
{
	Static	h
	If Not	h
		h:=DllCall("LoadLibrary","Str","oleacc","Ptr")
	If	DllCall("oleacc\AccessibleObjectFromPoint", "Int64", x==""||y==""?0*DllCall("GetCursorPos","Int64*",pt)+pt:x&0xFFFFFFFF|y<<32, "Ptr*", pacc, "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild)=0
	Return	ComObjEnwrap(9,pacc,1), _idChild_:=NumGet(varChild,8,"UInt")
}

А так вообще ошибку выдаёт:

Error 0x8001010D - An outgoing call cannot be made since the application dispatching an input-synchronous call

#If !test()
f10:: return 
#If
return


test()
{
hwndChrome := WinExist("ahk_class Chrome_WidgetWin_1")
AccChrome := Acc_ObjectFromWindow(hwndChrome)
AccAddressBar := GetElementByName(AccChrome, "Address and search bar")
}

GetElementByName(AccObj, name) {
   if (AccObj.accName(0) = name)
      return AccObj
   
   for k, v in Acc_Children(AccObj)
      if IsObject(obj := GetElementByName(v, name))
         return obj
}

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (DD) — Mon, 30 Apr 2018 12:49:39 +0000

Точно, название есть — в первый раз смотрел встроенным AU3_Spy.exe)). Но тут еще контрол используется, которого в Хроме нет и закомментирование результатов не даёт:


#If IsHomeKey()
LButton:: tooltip 11111111111111
#If

IsHomeKey() { 
    MouseGetPos, , , WinId, ControlNN 
    if !InStr( ControlNN, "ToolbarWindow")
        return 0
    WinGet, Process, ProcessName, ahk_id %WinId%
    if Process != chrome.exe 
        return 0
    return GetTextUnderMouse() = "Адресная строка и строка поиска" ? 1 : 0
} 

GetTextUnderMouse()  {
    Static h
    If !h
        h := DllCall("LoadLibrary","Str","oleacc","Ptr")
    If DllCall("oleacc\AccessibleObjectFromPoint"
                , "Int64", DllCall("GetCursorPos","Int64*",pt)+pt
                , "Ptr*", pacc, "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild)=0
    Acc:=ComObjEnwrap(9,pacc,1), child:=NumGet(varChild,8,"UInt")
    try value := Acc.accValue(child)
    if value =
        try value := Acc.accName(child) 
    return value
}

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Mon, 30 Apr 2018 12:33:54 +0000

DD пишет:

Скрипты по ссылке вроде на контролы и текст реагируют, тогда как в адресной строке не за что зацепиться (в частности, в Хроме).

У меня в хроме в адресной строке ahkspy показывает acc name - Address and search bar.

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (DD) — Mon, 30 Apr 2018 11:28:35 +0000

Вроде ничё так получилось)). Единственно не смог понять, как регулировать верхнюю границу — чтобы немного спустить? У меня она едва достигает адресной строки —


CoordMode, Mouse
#If WinActive ("ahk_exe chrome.exe") && (Area := WhatArea()) && (A_Cursor = "IBeam")
~LButton:: 
    If Area = 4
        tooltip 111111111111111111
    Else If Area = 5
        tooltip 22222222222222
    Return
#If
   
WhatArea()  {
    Static R := [[0.0,0.5,0.05,1]
                , [0.0,0.05,0.05,0.5]
                , [0.0,0.0,0.05,0.05]
                , [0.05,0.0,0.5,0.05]
                , [0.5,0.0,1,0.05]]
    MouseGetPos, X, Y
    X := X / A_ScreenWidth, Y := Y / A_ScreenHeight
    For K, V in R
        If (X >= V[1] && X <= V[3] && Y >= V[2] && Y <= V[4])
            Return K
}

На случай клика ниже адресной строки — можно добавить условие для контрола основного окна браузера. В скрипте различается правая и левая половины адресной строки — то есть, можно проводить в два раза больше действий)).

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (DD) — Mon, 30 Apr 2018 11:20:58 +0000

Будет ли юзабельным отслеживать изменение курсора на определенной высоте окна, в пределах панели инструментов браузера? Как раз в адресной строке он принимает форму, готовую к выделению текста?

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (DD) — Mon, 30 Apr 2018 11:14:28 +0000

Скрипты по ссылке вроде на контролы и текст реагируют, тогда как в адресной строке не за что зацепиться (в частности, в Хроме).

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Mon, 30 Apr 2018 08:43:44 +0000

http://forum.script-coding.com/viewtopic.php?id=9480

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (DD) — Mon, 30 Apr 2018 03:30:33 +0000

А есть ли способ как-то отличать адресную строку браузера (которые обычно без контрола), чтобы, к примеру, клик в пределах неё производил некое действие?

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Wed, 12 Aug 2015 16:45:15 +0000

Да и вообще, зачем изобретать велосипед?
http://www.autohotkey.com/board/topic/1 … owser-tab/

Re: AHK: Копирование адресной строки браузера и дальнейшая работа с ней

null@example.com (Malcev) — Wed, 12 Aug 2015 07:23:00 +0000

Проверял на 2 компах.
На одном: path=4.24.3.2
На втором: path=4.26.3.2

Тоже не пойдёт, у меня например accName не "Address and search bar".

Можно сделать несколько вариантов в зависимости от локализации.