Серый форум — Одновременное нажатие клавиш в игре

Re: Одновременное нажатие клавиш в игре

null@example.com (Nikva) — Mon, 31 Aug 2015 08:41:45 +0000

+ Alectric

Alectric пишет:

GetKeyState("sc11", "P") ? 200:-1
Какой смысл в этом операторе, если цикл завершается при отпускании кнопки?
Результат всегда будет 200.

Да тут не имеет смысла.
Не обратил внимание, копировал с своего скрипта, в котором много таких проверок.

+ skeleton

skeleton пишет:

~*sc11::
    sleep 1000
    shag:=0
    send {shift down}
return
Возможно как то прервать sleep если я отпутил W раньше 1000 мс? Чтобы дальше не выполнялось?

Видел такой вариант решения на форуме:

~*sc11:: ; w
shag:=0
T:="" 
while GetKeyState("SC011","p")
{
    if (A_TickCount > T) and (T := A_TickCount + 1000)
        send {shift down}
    sleep 10
}
return

Re: Одновременное нажатие клавиш в игре

null@example.com (yalanne) — Fri, 28 Aug 2015 11:36:13 +0000

Вот мой вариант, вроде как все стабильно работает:

#if !GetKeyState("LButton","P")
~*sc11::
KeyWait sc11,T1
If !ErrorLevel
    return
sendInput {shift down}
KeyWait sc11
return
~*sc11 up::
sendInput {shift Up}
return
#if GetKeyState("sc11","P")
~*LButton::sendInput {shift Up}
~*LButton Up::sendInput {shift Down}
#if

Re: Одновременное нажатие клавиш в игре

null@example.com (skeleton) — Fri, 28 Aug 2015 07:32:54 +0000

~*sc11::
    sleep 1000
    shag:=0
    send {shift down}
return

Возможно как то прервать sleep если я отпутил W раньше 1000 мс? Чтобы дальше не выполнялось?

Re: Одновременное нажатие клавиш в игре

null@example.com (skeleton) — Fri, 28 Aug 2015 06:39:04 +0000

~*sc11::
    shag:=0
    send {shift down}
return

~*sc11 up::
    if (!shag)
    {
        send {shift up}
    }
return

~LButton & sc11::
    if (!shag)
    {
        send {shift up}
        shag:=1
    }
    while GetKeyState("sc11","p") or GetKeyState("LButton","p")
    {
    }
return

В блокноте работает как часы, вечером попробую в игре.

Re: Одновременное нажатие клавиш в игре

null@example.com (Alectric) — Thu, 27 Aug 2015 13:47:01 +0000

GetKeyState("sc11", "P") ? 200:-1

Какой смысл в этом операторе, если цикл завершается при отпускании кнопки?
Результат всегда будет 200.

while GetKeyState("sc11","P")

...
И какой смысл каждые 200 ms отправлять нажатие {Shift Down}, если его можно нажать 1 раз?
Или я чего-то не знаю и повторно нажатие не воспринимается?

...
Поправил код.

Re: Одновременное нажатие клавиш в игре

null@example.com (Nikva) — Thu, 27 Aug 2015 07:30:55 +0000

Точно как она работает я не знаю, но мне обычно помогает.
Может-быть слишком частый спам Send'ом вызывает это окошко.

Sleep, GetKeyState("sc11", "P") ? 200:-1(Тернарный условный оператор).
Если коротко: Ждёт если клавиша нажата 200ms или если не нажата -1 (т.е. нет задержки).

Re: Одновременное нажатие клавиш в игре

null@example.com (skeleton) — Thu, 27 Aug 2015 06:54:20 +0000

Спасибо за подсказку по MaxHotkeysPerInterval, вот только не пойму какая горячая клавиша по W запускается? Вроде нет ничего...

и можно пояснить что делает строчка Sleep, GetKeyState("sc11", "P") ? 200:-1

Re: Одновременное нажатие клавиш в игре

null@example.com (Nikva) — Thu, 27 Aug 2015 06:07:08 +0000

#MaxHotkeysPerInterval 1000
~sc11::
    while GetKeyState("sc11","P") and !GetKeyState("LButton","P")
    {
        Send {sc2A down}
        Sleep, GetKeyState("sc11", "P") ? 200:-1
    }
    Send {sc2A up}
    return

Прочитайте про #MaxHotkeysPerInterval, это про всплывающее сообщение.
И к вашему скрипту добавил задержку (её можно уменьшить, если в игре не успевает срабатывать), т.к. быстрый спам шифтом обычно не нужен.

Re: Одновременное нажатие клавиш в игре

null@example.com (skeleton) — Thu, 27 Aug 2015 05:17:03 +0000

Как-то сложновато, может есть попроще вариант? В принципе мой код выше тоже работает, но во время игры частенько выскакивает какая-то табличка АХК типа "бла бла... hotkeys 1180 ms... бла бла" и клавиши "да" и "нет" если нажать да - продолжается дальше, если нет - скрипт завершается и выходит из трея. Если бы не эта табличка было бы норм.

Насколько я понял в моем коде пока выполняется условие, шифт нажимается по циклу, а можно ему назначить состояние как будто клавиша Шифт нажата и удерживается?

Re: Одновременное нажатие клавиш в игре

null@example.com (Alectric) — Wed, 26 Aug 2015 08:55:57 +0000

Так?

#singleinstance,forse
SetBatchLines,-1

time=1 ; время в секундах до возобновления работы shift

loop
{
  sleep,100
  if (!t:=t="" ? 1 : t>time*10 ? 0 : t+1)
    lb=
}

~*vk57:: ; w
if (!lb and !sh)
{
  sh=1
  send,{shift down}
}
return

~*vk57 up::
if (!lb and sh)
{
  sh=
  send,{shift up}
}
return

~*lbutton::
t=1
lb=1
sh=
send,{shift up}
return

Одновременное нажатие клавиш в игре

null@example.com (skeleton) — Wed, 26 Aug 2015 08:07:38 +0000

Как реализовать алгоритм:

До тех пор пока нажата W (физически) нажать и удерживать SHIFT (логически). Если во время зажатия и удержания W я нажал и удерживаю ЛКМ (физически) SHIFT моментально отпускался (логически). А так же если я сначала нажал и удерживаю ЛКМ и затем нажал и удерживаю W - shift НЕ нажимался.

Т.е. При простом нажатии W нажимался SHIFT, как только W работает совместно с ЛКМ (в любом порядке нажатия) shift отключался.

Вот что у меня получилось но мне кажется этого не достаточно.

~sc11::
    while GetKeyState("sc11","P") and !GetKeyState("LButton","P")
    {
        send {sc2A down}
    }
    send {sc2A up}
    return