Серый форум — AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-13T09:39:02Z

serzh82saratov

Именно по закрытию плеера, трудоёмко будет, а сбрасывать при новом показе можно.

Спасибо большое Вам, такой вариант даже более подходит и логичнее.

P.S.
Если будет свободное время, может быть обратите внимание на вот эту задачу по Авто-Бэкапу файлов и папок?

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-11T10:48:01Z

Именно по закрытию плеера, трудоёмко будет, а сбрасывать при новом показе можно.


#SingleInstance Force
#NoEnv

oTitles := ["ahk_class Notepad ahk_exe notepad.exe"
			, "ahk_class CalcFrame ahk_exe calc.exe"]

Global hGui, Show, Manual
, Effect := 0x00080000	; 0x00000010 - расширение, 0x00080000 - затухание, 0x00000001 - слева направо, 0x00000004 - сверху вниз
, EffectDuration := 333	; длительность эффекта

Gui, -DPIScale -Caption +AlwaysOnTop +HWNDhGui +Owner
Gui, Show,% "Hide x0 y0 w" A_ScreenWidth " h" A_ScreenHeight
OnMessage(0x201, "WM_LBUTTONDOWN")

Loop
{
	Sleep, 200
	If Manual
		Continue
	SysGet, MonitorCount, MonitorCount
	If (MonitorCount <> 2)
		Continue
	SysGet, MonitorPrimary, MonitorPrimary
	MonitorSecond := MonitorPrimary = 1 ? 2 : 1
	SysGet, Mon2, Monitor, %MonitorSecond%

	For i, Title in oTitles, HasSecond := 0
	{
		If !(hWnd := WinActive(Title))
			Continue
		WinGetPos, X, Y, , , % "ahk_id" hWnd
		If (X >= Mon2Left && X <= Mon2Right && Y >= Mon2Top && Y <= Mon2Bottom && (HasSecond := 1))
			Break
	}
	If (HasSecond && !Show)
		Show()
	Else If (!HasSecond && Show)
		Show(0)
}

Esc::  ExitApp

#If !Show
1:: Show(), Manual := 1
#If

Show(_Show = 1) { 
	If _Show
	{
		ChangeColor(0)
		DllCall("AnimateWindow", "Ptr", hGui, "Int", EffectDuration, "UInt", Effect)
		Gui, Show,% "NA x0 y0 w" A_ScreenWidth " h" A_ScreenHeight
		Gui, +AlwaysOnTop
	}
	Else
		DllCall("AnimateWindow", "Ptr", hGui, "Int", EffectDuration, "UInt", Effect|0x00010000)
	Show := _Show
}

ChangeColor(old = 1) {
	Static Colors := [["FF0000", 1], ["00FF00", 2], ["0000FF", 3]], i := 0
	If !old
		i := 0
 	Gui, Color, % Colors[i := ++i > Colors.MaxIndex() ? 1 : i][1]
	SetTimer, ChangeColor, % "-" . Colors[i][2] . "000"
}

WM_LBUTTONDOWN() {
	Show(0), Manual := 0
}

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-11T06:35:20Z

serzh82saratov
Спасибо за реализацию, но я так понял, при закрытии плеера, не происходит обнуления таймера цвета?

Объясню в чём загвоздка, вся эта очерёдность цветов, нужна, чтобы по прошествии долгого времени, происходила резкая смена цвета на несколько секунд, но если посмотрев фильм, до следующего цвета осталось несколько минут, то после следующего старта MPC-BE, эта смена произойдёт слишком рано, что не очень приятно и не имеет практического смысла. Можно ли, чтобы при каждом новом запуске плеера, цвета шли по очереди от самого первого?

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-08T17:13:15Z

Редактирование в самой функции, время в секундах для удобства.


#SingleInstance Force
#NoEnv

oTitles := ["ahk_class Notepad ahk_exe notepad.exe"
			, "ahk_class CalcFrame ahk_exe calc.exe"]

Global hGui, Show, Manual
, Effect := 0x00080000	; 0x00000010 - расширение, 0x00080000 - затухание, 0x00000001 - слева направо, 0x00000004 - сверху вниз
, EffectDuration := 333	; длительность эффекта

Gui, -DPIScale -Caption +AlwaysOnTop +HWNDhGui +Owner
Gui, Show,% "Hide x0 y0 w" A_ScreenWidth " h" A_ScreenHeight
ChangeColor(), OnMessage(0x201, "WM_LBUTTONDOWN")

Loop
{
	Sleep, 200
	If Manual
		Continue
	SysGet, MonitorCount, MonitorCount
	If (MonitorCount <> 2)
		Continue
	SysGet, MonitorPrimary, MonitorPrimary
	MonitorSecond := MonitorPrimary = 1 ? 2 : 1
	SysGet, Mon2, Monitor, %MonitorSecond%

	For i, Title in oTitles, HasSecond := 0
	{
		If !(hWnd := WinActive(Title))
			Continue
		WinGetPos, X, Y, , , % "ahk_id" hWnd
		If (X >= Mon2Left && X <= Mon2Right && Y >= Mon2Top && Y <= Mon2Bottom && (HasSecond := 1))
			Break
	}
	If (HasSecond && !Show)
		Show()
	Else If (!HasSecond && Show)
		Show(0)
}

Escape::  ExitApp

#If !Show
1:: Show(), Manual := 1
#If

Show(_Show = 1) {
	DllCall("AnimateWindow", "Ptr", hGui, "Int", EffectDuration, "UInt", Effect|(!_Show ? 0x00010000 : 0x0))
	If _Show
	{
		Gui, Show,% "NA x0 y0 w" A_ScreenWidth " h" A_ScreenHeight
		Gui, +AlwaysOnTop
	}
	Show := _Show
}

ChangeColor() {
	Static Colors := [["FF0000", 1], ["00FF00", 2], ["0000FF", 3]], i := 0
 	Gui, Color, % Colors[i := ++i > Colors.MaxIndex() ? 1 : i][1]
	SetTimer, ChangeColor, % "-" . Colors[i][2] . "000"
}

WM_LBUTTONDOWN() {
	Show(0), Manual := 0
}

Balux пишет:

И кстати, подскажите пожалуйста, в случае перехода в будущем 1-ого монитора на разрешение 1920x1200 или 1920x1080, будет ли корректно работать код?

Да, для любых разрешений обоих мониторов, и любого размещения вторичного монитора относительно главного. При изменении этих условий не требуется перезагрузка скрипта, или собственно какие то изменения в нём.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-07T06:03:50Z

serzh82saratov
А возможно ли сделать так, чтобы можно было добавлять разные цвета в строчку, а в скобочках время их показа, как в примере, и всё это по кругу? Конечно, если реализация для Вас крайне проста.

ChangeColor() {
 	Gui, Color, % Color := Color = 000000 (600000) : 000011 (600000) : 000000 (600000) : 000011 (600000) : 000000 (600000) : 0000FF (1000) : 000000 (600000)
}

И кстати, подскажите пожалуйста, в случае перехода в будущем 1-ого монитора на разрешение 1920x1200 или 1920x1080, будет ли корректно работать код?

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-06T08:17:58Z

Да, цвета именно так меняются.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-06T07:39:43Z

serzh82saratov

То есть затемнение может быть только если окно плеера активно и на втором мониторе?

Да, на практике это оказалось очень удобно.

У меня такого нет, от ОС может зависеть, добавил окну опцию, возможно поможет.

В Вашем новом варианте всё хорошо.

По нажатию на хоткей появляется, по клику исчезает.

Спасибо, так ещё удобней.

Спасибо большое за модификацию, вот теперь то, что надо. Не буду забегать вперёд, но пока всё работает отлично. Получилась отличная программа для связки монитор + ТВ.

А по поводу изменения цвета, это происходит с периодичностью 10 минут вот эти два цвета 000011 : 000000, 10 минут один и 10 минут другой?

ChangeColor() {
 	Gui, Color, % Color := Color = 000000 ? 000011 : 000000
}

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-05T22:30:49Z

То есть затемнение может быть только если окно плеера активно и на втором мониторе? Я изначально понял, что просто если окно на втором мониторе находится.


#SingleInstance Force
#NoEnv

oTitles := ["ahk_class Notepad ahk_exe notepad.exe"
			, "ahk_class CalcFrame ahk_exe calc.exe"]

Global Color, hGui, Show, Manual
, Effect := 0x00000010	; 0x00000010 - расширение, 0x00080000 - затухание, 0x00000001 - слева направо, 0x00000004 - сверху вниз
, EffectDuration := 333	; длительность эффекта

Gui, Color, % Color := 000000
Gui, -DPIScale -Caption +AlwaysOnTop +HWNDhGui +Owner
Gui, Show,% "Hide x0 y 0" "w" A_ScreenWidth " h" A_ScreenHeight
SetTimer, ChangeColor, 600000
OnMessage(0x201, "WM_LBUTTONDOWN")

Loop
{
	Sleep, 200
	If Manual
		Continue
	SysGet, MonitorCount, MonitorCount 
	If (MonitorCount <> 2)
		Continue
	SysGet, MonitorPrimary, MonitorPrimary
	MonitorSecond := MonitorPrimary = 1 ? 2 : 1
	SysGet, Mon2, Monitor, %MonitorSecond%
	
	For i, Title in oTitles, HasSecond := 0
	{
		If !(hWnd := WinActive(Title))
			Continue
		WinGetPos, X, Y, , , % "ahk_id" hWnd
		If (X >= Mon2Left && X <= Mon2Right && Y >= Mon2Top && Y <= Mon2Bottom) 
		{
			HasSecond := 1
			Break
		}
	}
	If (HasSecond && !Show)
		Show()
	Else If (!HasSecond && Show)
		Show(0)
}

Escape::  ExitApp

#If !Show
1:: Show(), Manual := 1
#If

Show(_Show = 1) {
	DllCall("AnimateWindow", "Ptr", hGui, "Int", EffectDuration, "UInt", Effect|(!_Show ? 0x00010000 : 0x0))
	If _Show
	{
		Gui, Show,% "NA x0 y 0" "w" A_ScreenWidth " h" A_ScreenHeight
		Gui, +AlwaysOnTop
	}
	Show := _Show
}

ChangeColor() {
 	Gui, Color, % Color := Color = 000000 ? 000011 : 000000
}

WM_LBUTTONDOWN() {
	Show(0), Manual := 0
}

Balux пишет:

на панели задач остаётся иконка от GUI AHK

У меня такого нет, от ОС может зависеть, добавил окну опцию, возможно поможет.

3) В варианте Alectric, можно было по горячей клавише вызывать затемнение, даже если MPC-BE не запущен.

По нажатию на хоткей появляется, по клику исчезает.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-05T21:15:58Z

serzh82saratov
Я не знаю, возможно ли считывать логику с кода, но посмотрите пожалуйста вариант из 14 сообщения.

Опишу подробно, запускается плеер на 1-ом экране, если есть надобность смотреть на 2-ом, жестом плеер отправляется на 2-ой дисплей за 1680 пиксель, 1-ый затемняется. В процессе просмотра ставится на паузу видео, курсор возвращается на 1-ый экран, щёлкаем ЛКМ по затемнению, оно исчезает и дальше, что-то поделав в браузере, курсор возвращается на 2-ой дисплей, там на паузе в Fullscreen или в окне находится фильм, щёлкаем по нему ЛКМ (т.е. затемнение всегда, если MPC-BE в фокусе), продолжается воспроизведение и 1-ый монитор затемняется. После просмотра, плеер жестом отправляется на 1-ый дисплей и закрывается, затемнение исчезает.

Хотя основная функциональность в Вашем варианте работает отлично, опишу что не так:

1) После закрытия плеера, затемненение исчезает, но на панели задач остаётся иконка от GUI AHK. Перезагрузив вручную скрипт, она исчезает.

2) Если во время просмотра, щёлкнуть ЛКМ по затемнению, оно исчезнет, но вернув в фокус MPC-BE, уже не появляется. Более того, при следующем запуске плеера тоже, нужно перезагружать скрипт вручную, дабы он заработал.

3) В варианте Alectric, можно было по горячей клавише вызывать затемнение, даже если MPC-BE не запущен. В Вашем, при нажатии хоткея, затемнение появляется и мгновенно исчезает, видимо не обнаружив запущенного на 2-ом мониторе MPC-BE.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-05T20:15:03Z

Нет, это я так написал, ручное отключение как и по хоткею "выключить затемнение". Напишите развёрнуто всю логику, мало понятно желаемое в деталях.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-05T20:09:16Z

serzh82saratov
Ого, спасибо большое, ещё и с продвинутыми эффектами , похоже проблема мельканий (затемнений) полностью устранена.

Но я так понял, в Вашем варианте нет авто-затемнения при возврате в фокус (ЛКМ по MPC-BE), как у Alectric, функция doonce помоему? Это очень удобно, что-то поделал на 1-ом мониторе, щёлкнул ЛКМ по фильму, пошло воспроизведение и 1-ый экран затемнился.

Ещё что странно, если щёлкнуть по затемнению, оно отключается, появляется значок AHK на панели задач, и при следующем запуске MPC-BE, затемнение уже не происходит, нужно вручную пепезагрузить скрипт, чтобы всё заработало. Это проблема на моей стороне?

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-05T00:27:31Z

У плееров обычно много всяких окон, если смотреть координаты просто за пределами главного монитора, то можно принять например свёрнутое окно за искомое, так как у него координаты -32000 по х и у. Ну и в любом случае добавить в критерии ещё хотя бы класс окон.


#SingleInstance Force
#NoEnv

oTitles := ["ahk_class Notepad ahk_exe notepad.exe"
			, "ahk_class CalcFrame ahk_exe calc.exe"]

Global Color, hGui, Show, Off
, Effect := 0x00000010   ; 0x00000010 - расширение, 0x00080000 - затухание, 0x00000001 - слева направо, 0x00000004 - сверху вниз
, EffectDuration := 333   ; длительность эффекта

Gui, Color, % Color := 000000
Gui, -DPIScale -Caption +AlwaysOnTop +E0x08000000 +HWNDhGui
Gui, Show,% "Hide x0 y 0" "w" A_ScreenWidth " h" A_ScreenHeight
SetTimer, ChangeColor, 600000
OnMessage(0x201, "WM_LBUTTONDOWN")

Loop
{ 
	Sleep, 200
	If Off
		Continue
	SysGet, MonitorCount, MonitorCount
	If (MonitorCount < 2)
		Continue
	SysGet, MonitorPrimary, MonitorPrimary
	MonitorSecond := MonitorPrimary = 1 ? 2 : 1
	SysGet, Mon2, Monitor, %MonitorSecond%
	
	For i, Title in oTitles, HasSecond := 0
	{
		WinGet, Id, List, %Title%
		Loop, %Id%
		{ 
			WinGetPos, X, Y, , , % "ahk_id" Id%A_Index%
			If (X >= Mon2Left && X <= Mon2Right && Y >= Mon2Top && Y <= Mon2Bottom) 
			{
				HasSecond := 1
				Break 2
			} 
		}
	}
	If (HasSecond && !Show)
		Show()
	Else If (!HasSecond && Show)
		Show(0)
}

Escape::  ExitApp

1::
	Off := Show
	Show(!Off)
	Return

Show(_Show = 1) {
	DllCall("AnimateWindow", "Ptr", hGui, "Int", EffectDuration, "UInt", Effect|(!_Show ? 0x00010000 : 0x0))
	If _Show
		Gui, +AlwaysOnTop
	Show := _Show
}

ChangeColor() {
 	Gui, Color, % Color := Color = 000000 ? 000011 : 000000
}

WM_LBUTTONDOWN() {
	Show(0), Off := 1
}

Этот вариант определяет номер монитора и его координаты, если монитор один, то ждёт появление второго, клик по окну скрывает его, есть несколько эффектов, периодическая смена цвета фона, работает с несколькими копиями одного плеера.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-04T22:26:11Z

Alectric
Видимо некие области MPC-BE, например прогресс бар, посылают сигнал, что они не mpc-be64.exe, причём даже без нажатия ЛКМ. Ну жить можно, жаль конечно, что в коде нельзя напрямую прописать, чтобы работал только за 1680 пикселем рабочего стола.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-04T15:38:17Z

У себя не могу повторить этой ошибки. У меня 1 монитор. Даже не знаю с чем связанно.

Re: AHK: Заполнить монитор №1 чёрным цветом по горячей клавише

2016-04-03T23:28:09Z

Alectric
К большому сожалению, проявилась ошибка, но не в Вашем крайнем изменении, а вообще. Когда MPC-BE находится на 1-ом мониторе, при клике по прогресс-бару появляется миллисекундное затемнение, как-будто мелькает экран, но что странно это затемнение бывает происходит и без клика, а при простом наведении мыши на плеер. А при попытке смены аудиодорожки, происходит полное затемнение, будто плеер на 2-ом мониторе.

В целом пользоваться конечно можно, но если Вы знаете в чём причина такого поведения, помогите пожалуйста. Т.к. MPC-BE находится на 1-ом (1680x1050) мониторе, совершенно непонятно почему скрипт реагирует на плеер.