Серый форум — AHK: Отправление виртуального кода клавиши

Re: AHK: Отправление виртуального кода клавиши

null@example.com (serzh82saratov) — Sun, 30 Sep 2018 11:48:29 +0000

Hotkey, % "~Esc & " Name, Input

Re: AHK: Отправление виртуального кода клавиши

null@example.com (becauseim) — Mon, 17 Sep 2018 23:45:01 +0000

serzh82saratov, Задействованная в сочетании клавиша Esc не работает в отдельности, т.е. сама по себе. Как это исправить?

Loop % 0xFF + 0x153
	If ((Name := Name(A_Index)) != "")
		Hotkey, % "Esc & " Name, Input

Re: AHK: Отправление виртуального кода клавиши

null@example.com (teadrinker) — Sun, 29 May 2016 16:30:32 +0000

serzh82saratov пишет:

Попробуй закрыть условие, и класс правильно прописать.

Ага, так работает.

Re: AHK: Отправление виртуального кода клавиши

null@example.com (teadrinker) — Sun, 29 May 2016 16:29:08 +0000

А, нет, неправильно класс написал:

#IfWinActive, ahk_class Notepade

Если правильно, моя работает, но печать — нет.

Re: AHK: Отправление виртуального кода клавиши

null@example.com (serzh82saratov) — Sun, 29 May 2016 16:26:08 +0000

Попробуй закрыть условие, и класс правильно прописать.

#IfWinActive, ahk_class Notepad
^Space:: MsgBox 
#IfWinActive

Re: AHK: Отправление виртуального кода клавиши

null@example.com (teadrinker) — Sun, 29 May 2016 16:23:18 +0000

У меня не работает ни печать, ни моя горячая клавиша.

Re: AHK: Отправление виртуального кода клавиши

null@example.com (serzh82saratov) — Sun, 29 May 2016 16:20:57 +0000

А что не так, вроде всё работает.

Re: AHK: Отправление виртуального кода клавиши

null@example.com (teadrinker) — Sun, 29 May 2016 16:03:39 +0000

А если так:

#NoEnv
SetBatchLines -1
ListLines Off

Loop % 0xFF + 0x153
	If ((Name := Name(A_Index)) != "")
		Hotkey, % "Esc & " Name, Input
Return

Input() {
	Key := SubStr(A_ThisHotkey, InStr(A_ThisHotkey, "&") + 2)
	SendStr(GetKeyState("Shift", "P") ? "{" Key "}" : Key)
	KeyWait, % (Instr(Key, "Wheel") ? "" : Key)
}

Name(I) {
	Static Names := {}
	Code := Format((I > 0xFF ? "sc" : "vk") "{:X}", I - (I > 0xFF ? 0xFF : 0))
	If Names[Name := GetKeyName(Code)]
		Return
	Names[Name] := 1, Chr := StrLen(Name) = 1 && !Instr("1234567890-=", Name)
	Return Chr ? (Instr(Code, "sc") ? "" : Code) : (Instr(Name, "Shift") ? "" : Name)
}

SendStr(Str) {  
	ControlGetFocus, Ctrl, % "ahk_id" WinExist("A")
	Loop, Parse, Str
		PostMessage, 0x102, Ord(A_LoopField), 1, %Ctrl%   ;  WM_CHAR
}

#IfWinActive, ahk_class Notepade
^Space:: MsgBox

Re: AHK: Отправление виртуального кода клавиши

null@example.com (becauseim) — Sun, 29 May 2016 08:22:46 +0000

serzh82saratov, спасибо, все получилось!

Re: AHK: Отправление виртуального кода клавиши

null@example.com (serzh82saratov) — Sun, 29 May 2016 08:06:52 +0000

becauseim пишет:

Но это мелочи, можно привыкнуть.

Или тут просто фигурные скобки переставить:

SendStr(GetKeyState("Shift", "P") ? "{" Key "}" : Key)

becauseim пишет:

при расположении сценария в конце файла он не работает

Тут ещё проще, тут же сразу идёт Return, то есть то что до него

Loop % 0xFF + 0x153
	If ((Name := Name(A_Index)) != "")
		Hotkey, % "Esc & " Name, Input

надо поместить до своих циклов, вверху, то что называют в справке "секция автовыполнения", то что после Return поместить после циклов.

Re: AHK: Отправление виртуального кода клавиши

null@example.com (becauseim) — Sun, 29 May 2016 07:58:18 +0000

serzh82saratov, последний вариант работает идеально, то, что нужно! Правда, например, я больше перечисляю отправляиваемые клавиши, нежели задаю горячие, и, наверное, было бы удобнее поменять местами условия, при нажатии на Esc и Shift+Esc. Но это мелочи, можно привыкнуть.

Более всего для меня вновь затруднительно разместить сценарий в одном файле с другими, т.к. при расположении сценария в конце файла он не работает, а в начале - предотвращает отображение GUI и, например, TrayMenu. Я уже несколько раз интересовался по поводу этого вопроса, однако для меня он по-прежнему остался открытым, т.к. даже после прочтения справки мне не ясно, существует ли способ, который полностью разделяет сценарии для предотвращения воздействия друг на друга или же это безвыходная ситуация, когда единственным решением может быть разделение на два файла.

Re: AHK: Отправление виртуального кода клавиши

null@example.com (serzh82saratov) — Sat, 28 May 2016 22:57:47 +0000

Кстати SendInput подводит например в случае с Escape & LWin, и запускает при печати Win+L. Потому лучше отправлять через WM_CHAR, либо печатать после KeyWait.

#NoEnv
SetBatchLines -1
ListLines Off

Loop % 0xFF + 0x153
	If ((Name := Name(A_Index)) != "")
		Hotkey, % "Esc & " Name, Input
Return

Input() {
	Key := SubStr(A_ThisHotkey, InStr(A_ThisHotkey, "&") + 2)
	SendStr(GetKeyState("Shift", "P") ? "{" Key "}" : Key)
	KeyWait, % (Instr(Key, "Wheel") ? "" : Key)
}

Name(I) {
	Static Names := {}
	Code := Format((I > 0xFF ? "sc" : "vk") "{:X}", I - (I > 0xFF ? 0xFF : 0))
	If Names[Name := GetKeyName(Code)]
		Return
	Names[Name] := 1, Chr := StrLen(Name) = 1 && !Instr("1234567890-=", Name)
	Return Chr ? (Instr(Code, "sc") ? "" : Code) : (Instr(Name, "Shift") ? "" : Name)
}

SendStr(Str) {  
	ControlGetFocus, Ctrl, % "ahk_id" WinExist("A")
	Loop, Parse, Str
		PostMessage, 0x102, Ord(A_LoopField), 1, %Ctrl%   ;  WM_CHAR
}

Re: AHK: Отправление виртуального кода клавиши

null@example.com (serzh82saratov) — Sat, 28 May 2016 22:11:13 +0000

Ещё так можно назначить все кнопки, включая мышь.

#NoEnv 
SetBatchLines -1
ListLines Off

Loop % 0xFF + 0xFFF
	If ((Name := Name(A_Index)) != "")
		Hotkey, % "Esc & " Name, Input
Return

Input() {
	Key := SubStr(A_ThisHotkey, InStr(A_ThisHotkey, "&") + 2)
    SendInput, % "{Raw}" (GetKeyState("Shift", "P") ? "{" Key "}" : Key) 
	KeyWait, % (Instr(Key, "Wheel") ? "" : Key)
}

Name(I) {
	Code := Format((I > 0xFF ? "sc" : "vk") "{:X}", I - (I > 0xFF ? 0xFF : 0))
	Name := GetKeyName(Code), Chr := StrLen(Name) = 1 && !Instr("1234567890-=", Name)
	Return Chr ? (Instr(Code, "sc") ? "" : Code) : (Instr(Name, "Shift") ? "" : Name)
}

Re: AHK: Отправление виртуального кода клавиши

null@example.com (teadrinker) — Sat, 28 May 2016 19:26:05 +0000

serzh82saratov пишет:

По моему надёжнее и проще так

Ну, это уже детали. Можно через RegEx в одно выражение. Я о принципе определения интересовался, работает, или нет.

Re: AHK: Отправление виртуального кода клавиши

null@example.com (serzh82saratov) — Sat, 28 May 2016 19:21:11 +0000

teadrinker пишет:

Так я пока только про буквенные говорю.

Я думал мы говорим про сценарий который выдаёт вк коды всех тех клавиш, которые нуждаются в этом для независимости от раскладки, и именах остальных.

becauseim пишет:

Иными словами, чтобы у буквенных символов отправлялись виртуальные коды, а у всех остальных - названия, которые одинакого воспринимаются при любой раскладке.