Серый форум — AHK: Управление микшером в контексте приложений

Re: AHK: Управление микшером в контексте приложений

2018-06-20T09:39:46Z

serzh82saratov, добавьте, пожалуйста, хоткей на сброс параметров микшера до 100% для всех приложений (если возможно, то в т.ч. и закрытых в данный момент), кроме системных звуков.

Re: AHK: Управление микшером в контексте приложений

2018-06-18T15:48:16Z

У меня это работает, писал давно, с тех пор код не причёсывал.
Работает с окном под курсором.


1:: AppVolume("Vol", -10)
2:: AppVolume("Vol", +10)
3:: AppVolume("Mute", 2)  ; переключать Mute
4:: ExclusiveAppVolume() ; оставить звук только этого приложения 
5:: AppVolume("SetVol", 10)
6:: AppVolume("Mute", "Get")
7:: AppVolume("GetVol")

AppVolume(Key, Val = "") { 
	MouseGetPos, , , winid
	WinGet, PID, PID, ahk_id %winid%
    WinGet, ProcessName, ProcessName, ahk_id %winid%   
	StringUpper, ProcessName, ProcessName
	SplitPath, ProcessName, , , , ProcessName					
    if ProcessName = explorer 
        Pid := 0 , ProcessName := "Системные`nзвуки"
    Res := VA_AppVolume(Key, Val, Pid)
	if Res =
		Message := ProcessName "`n`nОтсутствует в микшере", ColorF := "Red", Font := 22
	else if Key = Mute
		Message := ProcessName "`n`n" (Res = 0 ? "Mute OFF": "Mute ON") , ColorF := (Res = 0 ? "Yellow" : "Red") , Font := 22
	else
		Message := ProcessName "`n`n" Res  " `%", Font := (Res / 10 + 20), ColorF := 0xFFFFFF
	GuiTip( Message, Font, ColorF)
}

ExclusiveAppVolume() {
    Static T, PrPid
	MouseGetPos, , , winid
	WinGet, PID, PID, ahk_id %winid%
    WinGet, Text, ProcessName, ahk_pid %Pid%
    Text := RTrim( Text, "\.exe")
    StringUpper, Text, Text
	if Text = explorer 
        Pid := 0 , Text := "Системные звуки" 
    ListPid := 0 "|" VA_AppVolume("ListPid")
    ListPid := RTrim( RegExReplace( ListPid, "S)(^|\|)" Pid "($|\|)", "$1", Count, 1), "|") 
    If !Count
        Return
    T := PrPid = Pid ? !T : 1
    PrPid := Pid
    Loop, parse, ListPid, | 
        VA_AppVolume("Mute", T, A_LoopField) 
    VA_AppVolume("Mute", 0, Pid)    
	GuiTip( "Exclusive app sound `n" (T ? "Только `n`n""  " Text """ " : "`nВсе звуки включены "), 22, !T ? "Yellow" : "Red", 696969, 1500)
}

GuiTip( Text, sFont, ColorF = "", ColorG = "7890A1", Timer = 1000)     {
    Static hToolTip 
    Gui, TT: +AlwaysOnTop +ToolWindow -0x400000 +E0x08000000
    Gui, TT: Color, %ColorG% 
    Gui, TT: Font, s%sFont% Italic, Times New Roman
	DllCall("DestroyWindow", "Ptr", hToolTip) 
    Gui TT: Add, Text, Center gDestroyTT hwndhToolTip x30 y10 c%ColorF%, % Text 
	Gui TT: Show, NA xCenter y5 AutoSize
    SetTimer, DestroyTT, -%Timer%
    Return 
    DestroyTT:  
        Gui, TT: Destroy
        Return
}

VA_AppVolume(Key, Val = "", Pid = "!")
{
    dev := VA_GetDevice()
    if !dev
        Return
    if VA_IMMDevice_Activate(dev, "{77AA99A0-1BD6-484F-8BC7-2C654C9A9B6F}", 7, 0, mgr) != 0 ; IID_IAudioSessionManager2
        Return ObjRelease(dev)
    ObjRelease(dev)
    if VA_IAudioSessionManager2_GetSessionEnumerator(mgr, enm) != 0
        Return ObjRelease(mgr)
    ObjRelease(mgr)
    VA_IAudioSessionEnumerator_GetCount(enm, count) 
    Loop % count
    {
        VA_IAudioSessionEnumerator_GetSession(enm, A_Index-1, ssn)
        VA_IAudioSessionControl2_GetProcessId(ssn, curpid)
        if (Pid = curpid) 
        {
			sav := ComObjQuery(ssn, "{87CE5498-68D6-44E5-9215-6DA47EF883D8}") ; IID_ISimpleAudioVolume
			ObjRelease(ssn)
			if !sav
				Return
            DllCall(NumGet(NumGet(sav+0)+6*A_PtrSize), "uint", sav, "int*", mute) ; GetMute
			if (Key = "Vol")
			{
				DllCall(NumGet(NumGet(sav+0)+4*A_PtrSize), "uint", sav, "float*", volume) ; GetVolume
				if mute = 1
					DllCall(NumGet(NumGet(sav+0)+5*A_PtrSize), "uint", sav, "int", 0, "uint", 0, "uint", VA_GUID("")) ; SetMute
				vol := (volume + Val / 100)
				vol := (vol > 1) ? 1 : (vol < 0) ? 0 : vol
				DllCall(NumGet(NumGet(sav+0)+3*A_PtrSize), "uint", sav, "float", vol, "uint", VA_GUID("")) ; SetVolume
				Return Round(vol*100), ObjRelease(sav), ObjRelease(enm)
			}
            if (Key = "Mute")
            {
				if (Val = "Get")
					Return mute, ObjRelease(sav), ObjRelease(enm)
				DllCall(NumGet(NumGet(sav+0)+5*A_PtrSize), "uint", sav, "int", mute := (Val = 2) ? !mute : Val, "uint", VA_GUID("")) ; SetMute
                Return mute, ObjRelease(sav), ObjRelease(enm)
            }
			if (Key = "SetVol")
			{
				if mute = 1
					DllCall(NumGet(NumGet(sav+0)+5*A_PtrSize), "uint", sav, "int", 0, "uint", VA_GUID("")) ; SetMute
				DllCall(NumGet(NumGet(sav+0)+3*A_PtrSize), "uint", sav, "float", Val / 100, "uint", VA_GUID("")) ; SetVolume
				Return Val, ObjRelease(sav), ObjRelease(enm)
			}
			if (Key = "GetVol")
			{
				DllCall(NumGet(NumGet(sav+0)+4*A_PtrSize), "uint", sav, "float*", volume) ; GetVolume
				Return Round(volume*100), ObjRelease(sav), ObjRelease(enm)
			}
        }
        ObjRelease(ssn)
		ListPid .= curpid "|"
    }
    ObjRelease(enm)

	if (Key = "ListPid")
	{
		Loop, parse, ListPid, |
			List .= (WinExist("ahk_pid " A_LoopField) ? A_LoopField "|" : "")
		Return RTrim( List, "|")
	}
}

Re: AHK: Управление микшером в контексте приложений

2018-06-18T15:14:20Z

В каком посте последняя обновленная рабочая версия скрипта?

Re: AHK: Управление микшером в контексте приложений

2018-06-18T15:02:17Z

Не, не использую.
Я даже не вдавался в подробности, как этот интерфейс работает.

serzh82saratov пишет:

Заменил 0 на VA_GUID(""), тоже норм.

До следующего апдейта. )))

Re: AHK: Управление микшером в контексте приложений

2018-06-18T14:58:47Z

Я из описания не понял что это и зачем, подумал может ты это как то используешь.
Заменил 0 на VA_GUID(""), тоже норм.

Re: AHK: Управление микшером в контексте приложений

2018-06-18T14:47:10Z

https://msdn.microsoft.com/en-us/librar … s.85).aspx
И кстати, он не равен нулю.

msgbox % VA_GUID("")

Re: AHK: Управление микшером в контексте приложений

2018-06-18T14:29:32Z

Кстати не знаешь что должен делать VA_GUID(EventContext) в SetMute и SetVolume.

Re: AHK: Управление микшером в контексте приложений

2018-06-18T14:17:54Z

Да, действительно добавил нули, заработало. Значит ошибка была в предыдущих версиях, вроде в DllCall последние опущенные параметры равнялись нулю, во всяком случае я так думал.

Re: AHK: Управление микшером в контексте приложений

2018-06-18T14:08:57Z

Если вставить этот параметр, то работает.

Re: AHK: Управление микшером в контексте приложений

2018-06-18T14:06:19Z

Давно писал уже, видимо тогда хотелось всё сократить, но там последний параметр всё равно 0.

Re: AHK: Управление микшером в контексте приложений

2018-06-18T13:57:25Z

Ну раз не работает, значит не тоже самое.
А зачем ты сократил изначальную функцию:

VA_ISimpleAudioVolume_SetMute(this, Mute, EventContext="") {
    return DllCall(NumGet(NumGet(this+0)+5*A_PtrSize), "uint", this, "int", Mute, "uint", VA_GUID(EventContext))

на:

DllCall(NumGet(NumGet(sav+0)+5*A_PtrSize), "uint", sav, "int", mute := (Val = 2) ? !mute : Val) ; SetMute

Re: AHK: Управление микшером в контексте приложений

2018-06-18T13:32:29Z

А тут где не рабочая, разве не тоже самое?
Во вторых интересно почему на 1.1.28.02 и более ранних всё работает.

Re: AHK: Управление микшером в контексте приложений

2018-06-18T13:29:56Z

А чего не хочешь заменить свою функцию, на ту, которая работает?

Re: AHK: Управление микшером в контексте приложений

2018-06-18T13:08:40Z

Блин не проверил, тот работает. Не работает этот, Mute не переключается, громкость не регулируется. На предыдущих версиях уже очень давно всё норм.
Работает с окном под курсором.


#SingleInstance Force
#NoEnv

1::AppVolume("Vol", -10)
2:: AppVolume("Vol", +10)
3:: AppVolume("Mute", 2)  ;	Toggle Mute


AppVolume(Key, Val) { 
	MouseGetPos, , , winid
	WinGet, PID, PID, ahk_id %winid%
    WinGet, ProcessName, ProcessName, ahk_id %winid%   
	StringUpper, ProcessName, ProcessName
	SplitPath, ProcessName, , , , ProcessName					
    if ProcessName = explorer 
        Pid := 0 , ProcessName := "Системные`nзвуки"
    Res := VA_AppVolume(Key, Val, Pid)
	if Res =
		Message := ProcessName "`n`nОтсутствует в микшере", ColorF := "Red", Font := 22
	else if Key = Mute
		Message := ProcessName "`n`n" (Res = 0 ? "Mute OFF": "Mute ON") , ColorF := (Res = 0 ? "Yellow" : "Red") , Font := 22
	else
		Message := ProcessName "`n`n" Res  " `%", Font := (Res / 10 + 20), ColorF := 0xFFFFFF
	GuiTip( Message, Font, ColorF)
}

GuiTip( Text, sFont, ColorF = "", ColorG = "7890A1", Timer = 1000)     {
    Static hToolTip 
    Gui, TT: +AlwaysOnTop +ToolWindow -0x400000 +E0x08000000
    Gui, TT: Color, %ColorG% 
    Gui, TT: Font, s%sFont% Italic, Times New Roman
	DllCall("DestroyWindow", "Ptr", hToolTip) 
    Gui TT: Add, Text, Center gDestroyTT hwndhToolTip x30 y10 c%ColorF%, % Text 
	Gui TT: Show, NA xCenter y5 AutoSize
    SetTimer, DestroyTT, -%Timer%
    Return 
    DestroyTT:  
        Gui, TT: Destroy
        Return
}	

VA_AppVolume(Key, Val = "", Pid = "!")
{
    dev := VA_GetDevice()
    if !dev
        Return
    if VA_IMMDevice_Activate(dev, "{77AA99A0-1BD6-484F-8BC7-2C654C9A9B6F}", 7, 0, mgr) != 0 ; IID_IAudioSessionManager2
        Return ObjRelease(dev)
    ObjRelease(dev)
    if VA_IAudioSessionManager2_GetSessionEnumerator(mgr, enm) != 0
        Return ObjRelease(mgr)
    ObjRelease(mgr)
    VA_IAudioSessionEnumerator_GetCount(enm, count) 
    Loop % count
    {
        VA_IAudioSessionEnumerator_GetSession(enm, A_Index-1, ssn)
        VA_IAudioSessionControl2_GetProcessId(ssn, curpid)
        if (Pid = curpid)
        {
			sav := ComObjQuery(ssn, "{87CE5498-68D6-44E5-9215-6DA47EF883D8}") ; IID_ISimpleAudioVolume
			ObjRelease(ssn)
			if !sav
				Return
            DllCall(NumGet(NumGet(sav+0)+6*A_PtrSize), "uint", sav, "int*", mute) ; GetMute
			if (Key = "Vol")
			{
				DllCall(NumGet(NumGet(sav+0)+4*A_PtrSize), "uint", sav, "float*", volume) ; GetVolume
				if mute = 1
					DllCall(NumGet(NumGet(sav+0)+5*A_PtrSize), "uint", sav, "int", 0) ; SetMute
				vol := (volume + Val / 100)
				vol := (vol > 1) ? 1 : (vol < 0) ? 0 : vol
				DllCall(NumGet(NumGet(sav+0)+3*A_PtrSize), "uint", sav, "float", vol) ; SetVolume
				Return Round(vol*100), ObjRelease(sav), ObjRelease(enm)
			}
            if (Key = "Mute")
            {
				if (Val = "Get")
					Return mute, ObjRelease(sav), ObjRelease(enm)
				DllCall(NumGet(NumGet(sav+0)+5*A_PtrSize), "uint", sav, "int", mute := (Val = 2) ? !mute : Val) ; SetMute
                Return mute, ObjRelease(sav), ObjRelease(enm)
            }
			if (Key = "SetVol")
			{
				if mute = 1
					DllCall(NumGet(NumGet(sav+0)+5*A_PtrSize), "uint", sav, "int", 0) ; SetMute
				DllCall(NumGet(NumGet(sav+0)+3*A_PtrSize), "uint", sav, "float", Val / 100) ; SetVolume
				Return Val, ObjRelease(sav), ObjRelease(enm)
			}
			if (Key = "GetVol")
			{
				DllCall(NumGet(NumGet(sav+0)+4*A_PtrSize), "uint", sav, "float*", volume) ; GetVolume
				Return Round(volume*100), ObjRelease(sav), ObjRelease(enm)
			}
        }
        ObjRelease(ssn)
		ListPid .= curpid "|"
    }
    ObjRelease(enm)

	if (Key = "ListPid")
	{
		Loop, parse, ListPid, |
			List .= (WinExist("ahk_pid " A_LoopField) ? A_LoopField "|" : "")
		Return RTrim( List, "|")
	}
}

Re: AHK: Управление микшером в контексте приложений

2018-06-18T12:58:47Z

У меня на такой же системе 1.1.29.01 код из 8 поста работает.