Серый форум — Найти ближайшее меньшее/большее число к заданному

Re: Найти ближайшее меньшее/большее число к заданному

2016-07-23T16:42:37Z

Или можно просто в лоб через Loop, parse:

nums := "5, 8, 365.45776, 346.45653, 573.4665356, 3, 364.4654565"

MsgBox, % nearMin := getNearMinOrMax(nums, 353.56644, "nearMin")
MsgBox, % nearMax := getNearMinOrMax(nums, 353.56644, "nearMax")

getNearMinOrMax(numStr, num, modifier)  {
	Loop, parse, numStr, `,, %A_Space%
	{
		(modifier = "nearMin" && A_LoopField < num && (near = "" || A_LoopField > near) && near := A_LoopField)
		(modifier = "nearMax" && A_LoopField > num && (near = "" || A_LoopField < near) && near := A_LoopField)
	}
	Return near
}

По производительности наверно это лучший вариант.

Re: Найти ближайшее меньшее/большее число к заданному

2016-07-23T16:09:25Z

Malcev, красиво, но можно короче:

var = 5, 8, 365.45776, 346.45653, 573.4665356, 3, 364.4654565
number = 353.56644

var .= "," number
Sort, var, N D,
RegexMatch(var, "([-\d\.]*),? ?\Q" number "\E,? ?([-\d\.]*)", match)
msgbox % "min: " match1 "`nmax: " match2

Re: Найти ближайшее меньшее/большее число к заданному

2016-07-23T16:04:02Z

Я так сделал.


num = 353.56644
str = 5, 8, 365.45776, 346.45653, 573.4665356, 3, 364.4654565  

NextNum(str, num, less, more)
MsgBox % "min: " less "`nmax: " more

NextNum(str, num, ByRef less, ByRef more) {
    Sort, str, N D`, 
	Loop, Parse, str, `,, %A_Space%
	{
		if (A_LoopField > num) && (more := A_LoopField) != ""
			break
		less := A_LoopField
	} 
}

Malcev в Regex ещё можно минуса добавить, мало ли, понадобятся отрицательные.

Re: Найти ближайшее меньшее/большее число к заданному

2016-07-23T15:41:24Z

Можно так:

var = 5, 8, 365.45776, 346.45653, 573.4665356, 3, 364.4654565
number = 353.56644

var := RegexReplace(var, " ") "," number
Sort, var, N U D,
RegexMatch(var, "([\d\.]*),?\Q" number "\E,?([\d\.]*)", match)
msgbox % "min: " match1 "`nmax: " match2

Найти ближайшее меньшее/большее число к заданному

2016-07-23T14:36:55Z

Здравствуйте.
Имеется ряд чисел, разделённых запятыми. В том числе и десятичные. Необходимо найти наиближайшее число из этого списка, большее/меньшее заданного.

Допустим: 5, 8, 365.45776, 346.45653, 573.4665356, 3, 364.4654565
Я задал 353.56644. Ближайшее большее 365.45776. Меньшее - 346.45653.

Как это проще всего сделать?