Серый форум — AHK: изменить размер шрифта в блокноте по Ctrl+колесико

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2017-08-14T11:47:02Z

Malcev пишет:

Устанавливал бы хуки на создание окон?

И так тоже бы не стал. Если в результате моей автоматизации появляются какие-то нежелательные окна, просто счёл бы задачу нерешённой.

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2017-08-14T11:43:08Z

А каким стал бы, если приложение нельзя автоматизировать без посылания кликов мышью.
Устанавливал бы хуки на создание окон?

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2017-08-14T11:38:18Z

Не пробовал. Я бы вообще не стал идти этим путём.

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2017-08-14T11:35:05Z

Тогда, получается, единственный вариант спрятать все действия - создать новый рабочий стол и им уже перекрыть?

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2017-08-14T11:11:48Z

Понятно, почему — меню тоже AlwaysOnTop, а запущено позже.

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2017-08-14T10:23:58Z

Кстати, попап меню почему-то не скрывает:

pToken := Gdip_Startup()
Gui, -Caption +E0x80000 +AlwaysOnTop +ToolWindow +hwndhGui
Gui, Show, NA
hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
pBitmap := Gdip_BitmapFromScreen()
Gdip_DrawImage(G, pBitmap)
UpdateLayeredWindow(hGui, hdc, 0, 0, A_ScreenWidth, A_ScreenHeight)
SelectObject(hdc, obm)
DeleteObject(hbm)
Gdip_DisposeImage(pBitmap)
DeleteDC(hdc)
Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)

ControlClick,,ahk_class Button ahk_exe explorer.exe,,R,,NA
sleep 2000

Gui, Destroy
return

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T19:53:23Z

Ещё в каждый код забыл DeleteDC(hdc) добавить, исправил.

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T19:35:26Z

Проще:

pToken := Gdip_Startup()
Gui, -Caption +E0x80000 +AlwaysOnTop +ToolWindow +hwndhGui +LastFound
Gui, Color, Black
Gui, Show, NA


hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
UpdateLayeredWindow(hGui, hdc, 0, 0, A_ScreenWidth, A_ScreenHeight)

SelectObject(hdc, obm)
DeleteObject(hbm)
DeleteDC(hdc)
Gdip_Shutdown(pToken)
WinSet, Transparent, 180

Sleep, 400
ExitApp

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T19:27:29Z

Что-то у меня или меня вчера переглючило и msgbox не убирался.
С затемнением можно так:

pToken := Gdip_Startup()
Gui, -Caption +E0x80000 +AlwaysOnTop +ToolWindow +hwndhGui
Gui, Color, Black
Gui, Show, NA, overlay


hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
pBitmap := Gdip_BitmapFromScreen()
Gdip_DrawImage(G, pBitmap)
UpdateLayeredWindow(hGui, hdc, 0, 0, A_ScreenWidth, A_ScreenHeight)

SelectObject(hdc, obm)
DeleteObject(hbm)
Gdip_DisposeImage(pBitmap)
Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)
WinSet, Transparent, 180, overlay


; для наглядности (можно потаскать мышью)

OnMessage(0x201, "WM_LBUTTONDOWN")

WM_LBUTTONDOWN()
{
   PostMessage, 0xA1, 2
}

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T13:11:37Z

Malcev, не понял вопроса. А какие варианты? В конец секции автовыполнения, конечно.

pToken := Gdip_Startup()
Gui, -Caption +E0x80000 +AlwaysOnTop +ToolWindow +hwndhGui
Gui, Show, NA

hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
pBitmap := Gdip_BitmapFromScreen()
Gdip_DrawImage(G, pBitmap)
UpdateLayeredWindow(hGui, hdc, 0, 0, A_ScreenWidth, A_ScreenHeight)

SelectObject(hdc, obm)
DeleteObject(hbm)
Gdip_DisposeImage(pBitmap)
DeleteDC(hdc)
Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)

MsgBox,,, Меня не видно!, .1
Sleep, 200
ExitApp

Nikva, про затемнение ничего не знаю.

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T11:09:09Z

Malcev пишет:

По типу, как это делает UAC, только без затемнения.

А как сделать такой же эффект как в посту 37 с затемнением?

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T04:20:32Z

А куда тут вставить MsgBox,,,, 0.1 чтоб его не было видно?

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T03:19:54Z

pToken := Gdip_Startup()
Gui, -Caption +E0x80000 +AlwaysOnTop +ToolWindow +hwndhGui
Gui, Show, NA

hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
pBitmap := Gdip_BitmapFromScreen()
Gdip_DrawImage(G, pBitmap)
UpdateLayeredWindow(hGui, hdc, 0, 0, A_ScreenWidth, A_ScreenHeight)

SelectObject(hdc, obm)
DeleteObject(hbm)
Gdip_DisposeImage(pBitmap)
DeleteDC(hdc)
Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)

; для наглядности (можно потаскать мышью)

OnMessage(0x201, "WM_LBUTTONDOWN")

WM_LBUTTONDOWN()
{
   PostMessage, 0xA1, 2
}

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T02:49:47Z

Что-то не получается:

f1::
SS_BITMAP := 0xE
pToken := Gdip_Startup()
pBitmap := Gdip_BitmapFromScreen()
hBitmap := Gdip_CreateHBITMAPFromBitmap(pBitmap)
Gdip_DisposeImage(pBitmap)
Gui, -Caption +ToolWindow +Owner +AlwaysOnTop +Border -DPIScale
;Gui, +E0x80000 
Gui, Margin, 0, 0
Gui, Add, Pic, hwndhPic %SS_BITMAP%
SetImage(hPic, hBitmap)
Gui, Show, x-1 y-1 w%A_ScreenWidth% h%A_ScreenHeight%
MsgBox,,,, 0.1
Gdip_Shutdown(pToken)
DllCall("DeleteObject", Ptr, hBitmap)
Gui, Destroy
return

Если зажать f1, то иногда появляются вспышки.
Если раскомментировать Gui, +E0x80000, то вспышек нет, но и msgbox видно.

Re: AHK: изменить размер шрифта в блокноте по Ctrl+колесико

2016-11-17T02:20:22Z

А, ну можно использовать Layered Window, как в туториале по GDI+.