Серый форум — AHK: Самозакрытие при повторном запуске

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Sun, 08 Jan 2017 21:02:04 +0000

И ещё немного, получше разобравшись в теме:

#Persistent
#SingleInstance, force
OnExit(Func("Exit"))
Return

Exit(ExitReason)  {
   if ExitReason not in Single,Reload
      Return
   
   MyPID := DllCall("GetCurrentProcessId")
   VarSetCapacity(buff, buffSize := 4096, 0)
   DllCall("Psapi\EnumProcesses", Ptr, &buff, UInt, buffSize, UIntP, bytes)
   Loop % bytes//4  {
      PID := NumGet(buff, A_Index * 4, "UInt")
      if (MyPID != PID && InStr(GetCommandLine(PID), A_ScriptFullPath))
         Process, Close, % PID
   }
}

GetCommandLine(PID)  {
   static PROCESS_QUERY_INFORMATION := 0x400, PROCESS_VM_READ := 0x10, STATUS_SUCCESS := 0
   
   VarSetCapacity(PBI, 48)
   hProc := DllCall("OpenProcess", UInt, PROCESS_QUERY_INFORMATION|PROCESS_VM_READ, Int, 0, UInt, PID, Ptr)

   (A_Is64bitOS && DllCall("IsWow64Process", Ptr, hProc, UIntP, IsWow64))
   if (!A_Is64bitOS || IsWow64)
      PtrSize := 4, szPtr := "UInt", pPtr := "UIntP", offsetCMD := 0x44
   else
      PtrSize := 8, szPtr := "Int64", pPtr := "Int64P", offsetCMD := 0x78

   if (A_PtrSize < PtrSize)  {    ; скрипт 32, процесс 64
      QueryInformationProcess := "Ntdll\NtWow64QueryInformationProcess64"
      ReadProcessMemory := "Ntdll\NtWow64ReadVirtualMemory64"
      info := 0, szPBI := 48, offsetPEB := 8
   }
   else  {
      QueryInformationProcess := "Ntdll\NtQueryInformationProcess"
      ReadProcessMemory := "ReadProcessMemory"
      if (A_PtrSize > PtrSize)    ; скрипт 64, процесс 32
         info := 26, szPBI := 8, offsetPEB := 0
      else
         info := 0, szPBI := PtrSize * 6, offsetPEB := PtrSize
   }
   if DllCall(QueryInformationProcess, Ptr, hProc, UInt, info, Ptr, &PBI, UInt, szPBI, UIntP, bytes) != STATUS_SUCCESS  {
      DllCall("CloseHandle", Ptr, hProc)
      Return
   }
   pPEB := NumGet(&PBI + offsetPEB, szPtr)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pPEB + PtrSize * 4, pPtr, pRUPP, szPtr, PtrSize, UIntP, bytes)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pRUPP + offsetCMD, pPtr, pCMD, szPtr, PtrSize, UIntP, bytes)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pRUPP + offsetCMD - PtrSize, UShortP, szCMD, szPtr, 2, UIntP, bytes)
   
   VarSetCapacity(buff, szCMD, 0)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pCMD, Ptr, &buff, szPtr, szCMD, UIntP, bytes)
   DllCall("CloseHandle", Ptr, hProc)
   Return StrGet(&buff, "UTF-16")
}

Нужно понимать, что в таком виде функция EnumProcesses перечисляет не все процессы, а QueryInformationProcess выдаёт информацию только о процессах, запущенных от имени пользователя. Для получения командной строки AHK-скриптов это не важно, а для получения информации обо всех процессах нужно добавить

SeDebugPrivilege()

SeDebugPrivilege()  {
   static PROCESS_QUERY_INFORMATION := 0x400, TOKEN_ADJUST_PRIVILEGES := 0x20, SE_PRIVILEGE_ENABLED := 0x2
   
   hProc := DllCall("OpenProcess", UInt, PROCESS_QUERY_INFORMATION, Int, false, UInt, DllCall("GetCurrentProcessId"), Ptr)
   DllCall("Advapi32\OpenProcessToken", Ptr, hProc, UInt, TOKEN_ADJUST_PRIVILEGES, PtrP, token)
   
   VarSetCapacity(TOKEN_PRIVILEGES, 16, 0)
   NumPut(1, TOKEN_PRIVILEGES, 0, "UInt")
   DllCall("Advapi32\LookupPrivilegeValue", Ptr, 0, Str, "SeDebugPrivilege", Int64P, luid)
   NumPut(luid, TOKEN_PRIVILEGES, 4, "Int64")
   NumPut(SE_PRIVILEGE_ENABLED, TOKEN_PRIVILEGES, 12, "UInt")
   DllCall("Advapi32\AdjustTokenPrivileges", Ptr, token, Int, false, Ptr, &TOKEN_PRIVILEGES, UInt, 0, Ptr, 0, Ptr, 0)
   
   DllCall("CloseHandle", Ptr, token)
   DllCall("CloseHandle", Ptr, hProc)
}

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Sun, 08 Jan 2017 19:35:44 +0000

Ещё немного подправил размерность в связи с

Unsigned 64-bit integers produced by a function are not supported.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Sun, 08 Jan 2017 19:12:02 +0000

Подправленный второй вариант:

#Persistent
#SingleInstance, force
OnExit(Func("Exit"))
Return

Exit(ExitReason)  {
   if ExitReason not in Single,Reload
      Return
   
   MyPID := DllCall("GetCurrentProcessId")
   VarSetCapacity(buff, buffSize := 4096, 0)
   DllCall("Psapi\EnumProcesses", Ptr, &buff, UInt, buffSize, UIntP, bytes)
   Loop % bytes//4  {
      PID := NumGet(buff, A_Index * 4, "UInt")
      if (MyPID != PID && InStr(GetCommandLine(PID), A_ScriptFullPath))
         Process, Close, % PID
   }
}

GetCommandLine(PID)  {
   static PROCESS_QUERY_INFORMATION := 0x400, PROCESS_VM_READ := 0x10
   
   VarSetCapacity(PBI, 48)
   hProc := DllCall("OpenProcess", UInt, PROCESS_QUERY_INFORMATION|PROCESS_VM_READ, Int, 0, UInt, PID, Ptr)

   (A_Is64bitOS && DllCall("IsWow64Process", Ptr, hProc, UIntP, IsWow64))
   if (!A_Is64bitOS || IsWow64)
      PtrSize := 4, szPtr := "UInt", pPtr := "UIntP", offsetCMD := 0x44
   else
      PtrSize := 8, szPtr := "Int64", pPtr := "Int64P", offsetCMD := 0x78

   if (A_PtrSize < PtrSize)  {    ; скрипт 32, процесс 64
      QueryInformationProcess := "Ntdll\NtWow64QueryInformationProcess64"
      ReadProcessMemory := "Ntdll\NtWow64ReadVirtualMemory64"
      info := 0, szPBI := 48, offsetPEB := 8
   }
   else  {
      QueryInformationProcess := "Ntdll\NtQueryInformationProcess"
      ReadProcessMemory := "ReadProcessMemory"
      if (A_PtrSize > PtrSize)    ; скрипт 64, процесс 32
         info := 26, szPBI := 8, offsetPEB := 0
      else
         info := 0, szPBI := PtrSize * 6, offsetPEB := PtrSize
   }
   DllCall(QueryInformationProcess, Ptr, hProc, UInt, info, Ptr, &PBI, UInt, szPBI, pPtr, bytes)
   pPEB := NumGet(&PBI + offsetPEB, szPtr)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pPEB + PtrSize * 4, pPtr, pRUPP, szPtr, PtrSize, pPtr, bytes)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pRUPP + offsetCMD, pPtr, pCMD, szPtr, PtrSize, pPtr, bytes)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pRUPP + offsetCMD - PtrSize, UShortP, szCMD, szPtr, 2, pPtr, bytes)
   
   VarSetCapacity(buff, szCMD, 0)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pCMD, Ptr, &buff, szPtr, szCMD, pPtr, bytes)
   DllCall("CloseHandle", Ptr, hProc)
   Return StrGet(&buff, "UTF-16")
}

Re: AHK: Самозакрытие при повторном запуске

null@example.com (serzh82saratov) — Sun, 08 Jan 2017 19:10:07 +0000

Также.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (Flasher) — Sun, 08 Jan 2017 19:07:54 +0000

Win 7 SP1 Max x86, AutoHotkey(A|U)32.exe 1.1.24.04.
Процесс остаётся на месте. После второго вызова часто выскакивает окно:

[Window Title]
AutoHotkey Unicode 32-bit
[Main Instruction]
Прекращена работа программы "AutoHotkey Unicode 32-bit"
[Content]
Возникшая проблема привела к прекращению работы программы. Закройте эту программу.
[Закрыть программу]

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Sun, 08 Jan 2017 18:38:46 +0000

Только что специально в XP x86 перезагрузился, попробовал — всё работает, так что не знаю, в чём проблема. Проверяй версию AHK.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (Flasher) — Sun, 08 Jan 2017 18:19:37 +0000

Вот я про неё как раз.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Sun, 08 Jan 2017 18:01:50 +0000

У меня оба срабатывают. А какая ОС?

Re: AHK: Самозакрытие при повторном запуске

null@example.com (Flasher) — Sun, 08 Jan 2017 17:57:46 +0000

На 32-бит оба не срабатывают.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Sat, 07 Jan 2017 23:51:52 +0000

Если без WMI, то так можно:

#Persistent
#SingleInstance, force
OnExit(Func("Exit"))
Return

Exit(ExitReason)  {
   if ExitReason not in Single,Reload
      Return
   
   MyPID := DllCall("GetCurrentProcessId")
   VarSetCapacity(buff, buffSize := 4096, 0)
   DllCall("Psapi\EnumProcesses", Ptr, &buff, UInt, buffSize, UIntP, bytes)
   Loop % bytes//4  {
      PID := NumGet(buff, A_Index * 4, "UInt")
      if (MyPID != PID && InStr(GetCommandLine(PID), A_ScriptFullPath))
         Process, Close, % PID
   }
}

GetCommandLine(PID)  {
   static SYNCHRONIZE := 0x100000, STANDARD_RIGHTS_REQUIRED := 0xF0000, offsetSize := A_IsUnicode ? 2 : 1
        , PROCESS_ALL_ACCESS := STANDARD_RIGHTS_REQUIRED|SYNCHRONIZE|0xFFF, INFINITE := 0xFFFFFFFF
        
   hProc := DllCall("OpenProcess", UInt, PROCESS_ALL_ACCESS, Int, 0, UInt, PID, Ptr)
   if A_Is64bitOS  {
      DllCall("IsWow64Process", Ptr, hProc, UIntP, bool)
      if (bool && A_PtrSize = 8) || (!bool && A_PtrSize = 4)  {
         DllCall("CloseHandle", Ptr, hProc)
         ; MsgBox, Скрипт и целевой процесс разных битностей, функция не будет работать!
         Return
      }
   }
   hModule := DllCall("GetModuleHandle", "str", "Kernel32.dll", Ptr)
   pFunc := DllCall("GetProcAddress", Ptr, hModule, AStr, "GetCommandLine" . (A_IsUnicode ? "W" : "A"), Ptr)
   if !hThrd := DllCall("CreateRemoteThread", Ptr, hProc, Ptr, 0, Ptr, 0, Ptr, pFunc, Ptr, 0, UInt, 0, UInt, 0)  {
      DllCall("CloseHandle", Ptr, hProc)
      Return
   }
   DllCall("WaitForSingleObject", Ptr, hThrd, UInt, INFINITE)
   DllCall("GetExitCodeThread", Ptr, hThrd, UIntP, pPtr)
   DllCall("CloseHandle", Ptr, hThrd)

   VarSetCapacity(buff, 2048, 0)
   Loop  {
      offset := (A_Index - 1) * offsetSize
      DllCall("ReadProcessMemory", Ptr, hProc, Ptr, pPtr + offset, Ptr, &buff + offset, Ptr, offsetSize, Ptr, 0)
   } until !NumGet(&buff + offset, A_IsUnicode ? "UShort" : "UChar")

   DllCall("CloseHandle", Ptr, hProc)
   Return StrGet(&buff)
}

Или так:

#Persistent
#SingleInstance, force
OnExit(Func("Exit"))
Return

Exit(ExitReason)  {
   if ExitReason not in Single,Reload
      Return
   
   MyPID := DllCall("GetCurrentProcessId")
   VarSetCapacity(buff, buffSize := 4096, 0)
   DllCall("Psapi\EnumProcesses", Ptr, &buff, UInt, buffSize, UIntP, bytes)
   Loop % bytes//4  {
      PID := NumGet(buff, A_Index * 4, "UInt")
      if (MyPID != PID && InStr(GetCommandLine(PID), A_ScriptFullPath))
         Process, Close, % PID
   }
}

GetCommandLine(PID)  {
   static PROCESS_QUERY_INFORMATION := 0x400, PROCESS_VM_READ := 0x10
   
   VarSetCapacity(PBI, 48)
   hProc := DllCall("OpenProcess", UInt, PROCESS_QUERY_INFORMATION|PROCESS_VM_READ, Int, 0, UInt, PID, Ptr)

   (A_Is64bitOS && DllCall("IsWow64Process", Ptr, hProc, UIntP, IsWow64))
   if (!A_Is64bitOS || IsWow64)
      PtrSize := 4, szPtr := "UInt", pPtr := "UIntP", offsetCMD := 0x44
   else
      PtrSize := 8, szPtr := "UInt64", pPtr := "UInt64P", offsetCMD := 0x78

   if (A_PtrSize < PtrSize)  {    ; скрипт 32, процесс 64
      QueryInformationProcess := "Ntdll\NtWow64QueryInformationProcess64"
      ReadProcessMemory := "Ntdll\NtWow64ReadVirtualMemory64"
      info := 0, szPBI := 48, offsetPEB := 8
   }
   else  {
      QueryInformationProcess := "Ntdll\NtQueryInformationProcess"
      ReadProcessMemory := "ReadProcessMemory"
      if (A_PtrSize > PtrSize)    ; скрипт 64, процесс 32
         info := 26, szPBI := 8, offsetPEB := 0
      else
         info := 0, szPBI := PtrSize * 6, OffsetPEB := PtrSize
   }
   DllCall(QueryInformationProcess, Ptr, hProc, UInt, info, Ptr, &PBI, UInt, szPBI, pPtr, bytes)
   pPEB := NumGet(&PBI + OffsetPEB, szPtr)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pPEB + PtrSize * 4, pPtr, pRUPP, szPtr, PtrSize, pPtr, bytes)
   DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pRUPP + offsetCMD, pPtr, pCMD, szPtr, PtrSize, pPtr, bytes)

   VarSetCapacity(buff, 1024, 0)
   Loop  {
      offset := (A_Index - 1) * 2
      DllCall(ReadProcessMemory, Ptr, hProc, szPtr, pCMD + offset, Ptr, &buff + offset, szPtr, 2, pPtr, bytes)
   } until !NumGet(&buff + offset, "UShort")

   DllCall("CloseHandle", Ptr, hProc)
   Return StrGet(&buff, "UTF-16")
}

Re: AHK: Самозакрытие при повторном запуске

null@example.com (Flasher) — Fri, 06 Jan 2017 17:21:33 +0000

Поспешил с выводами. Ладно, пойдёт.

Но с #SingleInstance, Force было бы лучше.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Fri, 06 Jan 2017 17:06:15 +0000

Который? У меня всё вроде на месте. В цикле столько итераций, сколько есть окон с путём скрипта в заголовке.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (Flasher) — Fri, 06 Jan 2017 17:01:43 +0000

А как же Return?

Re: AHK: Самозакрытие при повторном запуске

null@example.com (teadrinker) — Fri, 06 Jan 2017 16:59:22 +0000

Flasher пишет:

постоянно будет крутиться функция с циклом поиска окон

А с чего ей постоянно крутиться? Поиск окон идёт только один раз при запуске.

Re: AHK: Самозакрытие при повторном запуске

null@example.com (Flasher) — Fri, 06 Jan 2017 16:46:11 +0000

Не, народ, мне нужно что-то полегче для процессорной накачки. Иконки в трее можно опустить, их скорее не будет.
Не нравится, что в скриптах, где, скажем, выполняется быстрый хоткей постоянно будет крутиться функция с циклом поиска окон, почему я и хочу проверять по A_ExitReason или какому-то иному событию.