Серый форум — AHK: Удаление строки из текстового файла

Re: AHK: Удаление строки из текстового файла

2023-12-13T17:30:29Z

Угу, чуть проще:

literalRegex(str)
{
    return RegExReplace(str, "\\E", "\E\\E\Q")
}

Re: AHK: Удаление строки из текстового файла

2023-12-13T16:46:49Z

teadrinker пишет:

text =
(
Text_Text - Reason
Text_Text - Reason
Text_Text - Reason
Hex_Hex \ Reason1
)

search := "Hex_Hex \ Reason1"

MsgBox, % "|" RegExReplace(text, "(^|(\R))\Q" . search . "\E(?(2)(?=(\R|$))|\R)") "|"

Здесь кроется ошибка, сам на нее недавно наткнулся и какое-то время не мог понять в чем причина.
Когда мы используем такой шаблон как "\Q" search "\E", то надо строку конвертировать:

text =
(
Text_Text - Reason
Text_Text - Reason
Text_Text - Reason
Hex_Hex \E Reason1
)

search := "Hex_Hex \E Reason1"

MsgBox, % "|" RegExReplace(text, "(^|(\R))\Q" . search . "\E(?(2)(?=(\R|$))|\R)") "|"
MsgBox, % "|" RegExReplace(text, "(^|(\R))\Q" . literalRegex(search) . "\E(?(2)(?=(\R|$))|\R)") "|"

literalRegex(str)
{
   if InStr(str, "\E", 1)
   {
      StringCaseSenseOld := A_StringCaseSense
      StringCaseSense, On
      str := StrReplace(str, "\E", "\E\\E\Q")
      StringCaseSense, % StringCaseSenseOld
   }
   return str
}

Re: AHK: Удаление строки из текстового файла

2017-02-01T13:10:39Z

Flasher. а, ну да, переписывает. Спасибо.

Re: AHK: Удаление строки из текстового файла

2017-02-01T12:25:22Z

svoboden
Я же показывал.
Регулярку можно взять из примера выше.

Re: AHK: Удаление строки из текстового файла

2017-02-01T12:03:27Z

Кто знает, можно ли заменить или удалить строку без использования команд: FileDelete, FileAppend. Спасибо!

Re: AHK: Удаление строки из текстового файла

2017-01-31T14:21:00Z

text =
(
Text_Text - Reason
Text_Text - Reason
Text_Text - Reason
Hex_Hex \ Reason1
)

search := "Hex_Hex \ Reason1"

MsgBox, % "|" RegExReplace(text, "(^|(\R))\Q" . search . "\E(?(2)(?=(\R|$))|\R)") "|"

Re: AHK: Удаление строки из текстового файла

2017-01-28T18:12:02Z

belyankin12, ясно.

Re: AHK: Удаление строки из текстового файла

2017-01-28T18:07:23Z

Ух ты, парни, я уже решил проблему по своему. Teadrinker, может быть и выдает, я не пытался. Просто я не использую то, чего не понимаю. Я не хочу каждый раз вас напрягать, задавая глупые вопросы. Потому, когда мне предлагают решение проблемы, я запоминаю метод и потом, в будущем, я смогу это сделать самостоятельно.

Re: AHK: Удаление строки из текстового файла

2017-01-28T17:59:30Z

А что, текст без пустой строки должен быть?

Re: AHK: Удаление строки из текстового файла

2017-01-28T17:20:32Z

Flasher, твой вариант:

Согласен.

Уж не говоря о:

Это было понятно. Спецсимволы не учитывал.

Re: AHK: Удаление строки из текстового файла

2017-01-28T17:19:04Z

Malcev

text =
(
Text_Text - Reason
Hex_Hex \ Reason1
test Hex_Hex \ Reason1
Text_Text - Reason
)

search := "Hex_Hex \ Reason1"
MsgBox, % "|" RegExReplace(text, "(^|\R)\Q" . search . "\E(\R|$)", $1$2) "|"

Re: AHK: Удаление строки из текстового файла

2017-01-28T17:16:56Z

svoboden

OutputVar =
(
Text_Text - Reason
Hex_Hex - Reason1
Text_Text - Reason
Text_Text - Reason
)

StringReplace, FileName, OutputVar, Hex_Hex - Reason1
MsgBox, % FileName

В этом примере пустая строка остаётся, а в этом

OutputVar =
(
Text_Text - Reason
test Hex_Hex - Reason1
Text_Text - Reason
Text_Text - Reason
)

StringReplace, FileName, OutputVar, Hex_Hex - Reason1
MsgBox, % FileName

вообще не то, что надо удаляется.

Re: AHK: Удаление строки из текстового файла

2017-01-28T17:15:40Z

Можно так:

text =
(
Text_Text - Reason
test Hex_Hex \ Reason1
Text_Text - Reason
Hex_Hex \ Reason1
)

search := "Hex_Hex \ Reason1"
MsgBox, % "|" RegExReplace(text, "(^|\R)\Q" . search . "\E(\R|$)", $1$2) "|"

Хотя нет.

Re: AHK: Удаление строки из текстового файла

2017-01-28T17:11:27Z

teadrinker, а что в моем варианте ни так?

Re: AHK: Удаление строки из текстового файла

2017-01-28T17:03:33Z

Да, есть косяк, не углядел. Правильно так:

text =
(
Text_Text - Reason
test Hex_Hex \ Reason1
Text_Text - Reason
Hex_Hex \ Reason1
)

search := "Hex_Hex \ Reason1"
patt := "^\Q" . search . "\E$"
MsgBox, % "|" RegExReplace(text, "m`a)\R" . patt . "|" . patt . "\R") "|"

Flasher, твой вариант:

All =
(
Hex_Hex - Reason1
Text_Text - Reason
Text_Text - Reason
Text_Text - Reason
)
StrDel := "Hex_Hex - Reason1"

MsgBox, % "|" RegExReplace(All, "(^|\R)" . StrDel . "|" . StrDel . "(\R|$)") "|"

Уж не говоря о:

All =
(
Hex_Hex \ Reason1
Text_Text - Reason
Text_Text - Reason
Text_Text - Reason
)
StrDel := "Hex_Hex \ Reason1"

MsgBox, % "|" RegExReplace(All, "(^|\R)" . StrDel . "|" . StrDel . "(\R|$)") "|"