Серый форум — AHK: Автосмена регистра перед вводом заглавных букв

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-15T19:55:15Z

Спасибо вам serzh82saratov огромное то что нужно.

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-15T18:39:48Z

Ядрён пишет:

А можно сделать что бы сразу после точки была заглавная буква, без пробела.

#NoEnv
#SingleInstance, Force
#KeyHistory 0
ListLines Off
SetBatchLines -1
SetKeyDelay -1


endSentence := "?!…"
endChars := " "
endKeys := "{vk1}"
end := "."

Loop
{
	Input, key, E L1 V, % endSentence endKeys end
	If InStr(ErrorLevel, "EndKey:")
		wait := InStr(endSentence, SubStr(ErrorLevel, 8)) ? 1 : 2
	Else If (wait && InStr(endChars, key))
		wait := 2
	Else If (wait = 2 && !(wait := 0) && key ~= "(*UCP)\w")
		SendInput, % "{Backspace}" Format("{:U}", key)
	Else If (wait = 1)
		wait := 0
}

~Backspace:: wait := 0
~LButton:: wait := 2

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-15T15:06:50Z

Ядрён, приведенные сокращения никак не противопостовляются развернутости выражения мысли.
Кроме всего прочего, стоит присесть за чужой компьютер - привычка писать без пробелов обернется боком.

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-15T13:21:46Z

becauseim, по такому случаю ("т.к.", "т.е.", "в т.ч."), а такой случай случается нечасто, можно скрипт и на паузу поставить. Зато основной текст набирать без напряга и в удовольствие, да и это всё ("т.к.", "т.е.", "в т.ч.") сокращение, а я лично люблю давать развёрнутые ответы без сокращений.

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-15T10:55:57Z

Ядрён, а как же "т.к.", "т.е.", "в т.ч.", "www.script-coding.com"?

Протестировал последний код. Неудобно использовать, когда необходимо ввести слово вместо выделенных слов, т.к. Выделенные слова могут быть и в середине предложения, а текст печатается с заглавной.

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-15T10:00:35Z

Уважаемый serzh82saratov всё работает как надо. А можно сделать что бы сразу после точки была заглавная буква, без пробела. Просто я частенько не ставлю пробел после точки, легче будет расставить пробелы чем возвращаться и перепечатывать текст. Потому что если писать сразу после точки буква печатается в нижнем регистре.

Пример:
Привет.Как дела.

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-12T20:46:01Z

Input не дружит с мышью, можно так:

#NoEnv
#SingleInstance, Force
#KeyHistory 0
ListLines Off
SetBatchLines -1
SetKeyDelay -1

endSentence := "?!.…"
endChars := " "


Loop
{
	Input, key, E L1 V, % endSentence endKeys
	If InStr(ErrorLevel, "EndKey:")
		wait := InStr(endSentence, SubStr(ErrorLevel, 8)) ? 1 : 2
	Else If (wait && InStr(endChars, key))
		wait := 2
	Else If (wait = 2 && !(wait := 0) && key ~= "(*UCP)\w")
		SendInput, % "{Backspace}" Format("{:U}", key)
	Else If (wait = 1)
		wait := 0
}

~Backspace:: wait := 0
~LButton:: wait := 2

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-11T01:10:39Z

Доброго времени суток. Уважаемый serzh82saratov , а почему не работает активация скрипта по клавише "vk1", если вместо неё вписать любую другую клавишу клавиатуры, то активация работает по этой клавише.

#NoEnv
#SingleInstance, Force
#KeyHistory 0
ListLines Off
SetBatchLines -1
SetKeyDelay -1


endSentence := "?!.…"
endChars := " "
endKeys := "{vk1}"


Loop
{
	Input, key, E L1 V, % endSentence endKeys  
	If InStr(ErrorLevel, "EndKey:")
		wait := InStr(endSentence, SubStr(ErrorLevel, 8)) ? 1 : 2
	Else If (wait && InStr(endChars, key))
		wait := 2
	Else If (wait = 2 && !(wait := 0) && key ~= "(*UCP)\w")
		SendInput, % "{Backspace}" Format("{:U}", key)
	Else If (wait = 1)
		wait := 0
}

~Backspace:: wait := 0

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-09T23:49:16Z

Костыль для первой буквы:

Hotkey ~*LButton, L
Hotkey ~*Tab, L

L:
Input, key, L1, {LCtrl}{RCtrl}{LAlt}{RAlt}
If InStr(ErrorLevel, "EndKey:")
	Return
clipTmp := Clipboard
Clipboard =
Send {ShiftDown}{Left}{ShiftUp}
Sleep 20
SendPlay ^{Ins}
ClipWait .3
Send {Right}
letter:=Clipboard
if (((letter = "") || (letter = "`n") || (letter = "`r`n")) && (key ~= "(*UCP)\w"))
	Send % Format("{:U}", key)
else
	Send % key
Return

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-09T23:33:13Z

Если быстро печатать, то несовсем на ура. Где то вроде видел аналогичное решение парой строк автозамены. Я это запостил собственно для автора выше выложенного кода, чтобы обсудить необходимость танцев вокруг кириллицы. На счёт первой буквы, и в целом идеи, считаю что всё окажется костылём, так что увольте.

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-09T23:00:03Z

Уважаемый serzh82saratov , ваш код работает на ура . Только самая первая буква печатается в нижнем регистре. Может как нибудь по изменению курсора("If A_Cursor = Unknown") + клик сделать активацию верхнего регистра самой первой буквы. Или сделать так что бы скрипт реагировал на первое нажатие пробела и менял первую букву слова в верхний регистр , а остальные нажатия пробела не влияли бы на смену регистра , потому что пробел был нажат после точки ("?!.…") и.т.д. .

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-09T21:19:28Z

Не понятно, зачем столько танцев с кирилицей. Вроде с любым языком должно работать.


#NoEnv
#SingleInstance, Force
#KeyHistory 0
ListLines Off
SetBatchLines -1

endSentence := "?!.…"
endChars := " "
endKeys := "{Enter}"

Loop
{
	Input, key, E L1 V, % endSentence endKeys 
	If InStr(ErrorLevel, "EndKey:")
		wait := InStr(endSentence, SubStr(ErrorLevel, 8)) ? 1 : 2
	Else If (wait && InStr(endChars, key))
		wait := 2
	Else If (wait = 2 && !(wait := 0) && key ~= "(*UCP)\w")
		SendInput, % "{Backspace}" Format("{:U}", key)
	Else If (wait = 1)
		wait := 0
}

~Backspace:: wait := 0

stealzy пишет:

Ядрён, вам надо как-то узнавать, что вот эта вот буква - первая.

Ядрён пишет:

Я вам так скажу на "андроид" как то условие сделали (первая буква всегда заглавная )

Кто его знает как там, но скорее всего там универсально по счёт поля ввода текста, и к нему всегда есть доступ. Также и на винде можно сделать, но только с теми контролами с которыми "возможно работать".

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-09T20:50:26Z

stealzy, да. Но мое предложение связано в большей степени со странным, на мой взгляд, особым отношением комьюнити именно к точкам в конце сообщений. Хотя природу этого явления мне помогли определить ранее. Или просто узнал, не помню. А сейчас лишь отметил.

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-09T20:42:35Z

Я вам так скажу на "андроид" как то условие сделали (первая буква всегда заглавная ) там тоже клавиатура , хоть и виртуальная.

+ открыть спойлер

Не ужели никто не сможет помочь ,хотя бы расширением для "Google Chrome" .

Re: AHK: Автосмена регистра перед вводом заглавных букв

2017-04-09T17:54:24Z

Ядрён, начальное предложение и у меня не всегда с большой, а после окончания предложения и следом идущим пробелом - вроде стабильно.