Серый форум — AHK: Включение синхронизации с сервером времени.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (powercat) — Sun, 18 Jun 2017 20:24:45 +0000

teadrinker пишет:

А чтобы сработало без ошибок, можно проверять оба варианта:

Вот этот вариант очень хорошо работает, протестировал на windows 7/10 x32 системах. Спасибо за помощь!

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 14:42:27 +0000

lexikos пишет:

I would suggest testing the following:
Run directly from a 32-bit command prompt. That is, launch C:\Windows\SysWow64\cmd.exe and paste your command line there.
Run the 64-bit command processor from AutoHotkey 32-bit. That is, RunWait C:\Windows\SysNative\cmd.exe ....
Run w32tm 32-bit directly (see below). w32tm is an executable; cmd.exe is not needed except to force the output to remain on screen (but you can get around that).
Run w32tm 64-bit directly. That is, RunWait C:\Windows\SysNative\w32tm.exe ....

Имхо, сюда незачем примешивать ещё и битность cmd.exe, она ведь в реальности не используется. Протестировать можно так:

cmd = w32tm /config /update /manualpeerlist:"0.pool.ntp.org 1.pool.ntp.org 2.pool.ntp.org 3.pool.ntp.org" /syncfromflags:MANUAL /reliable:yes
MsgBox, % StdOut(cmd, "cp866")

StdOut(sCmd, encoding)
{
   static STARTF_USESTDHANDLES := 0x100, CREATE_NO_WINDOW := 0x08000000
   
   DllCall("CreatePipe", PtrP, hStdInRd, PtrP, hStdInWr, UInt, 0, UInt, 0)
   DllCall("CreatePipe", PtrP, hStdOutRd, PtrP, hStdOutWr, UInt, 0, UInt, 0)
   DllCall("SetHandleInformation", Ptr, hStdInRd, UInt, 1, UInt, 1)
   DllCall("SetHandleInformation", Ptr, hStdOutWr, UInt, 1, UInt, 1)
   
   VarSetCapacity(pi, A_PtrSize*2 + 8, 0)
   NumPut( VarSetCapacity(      si, A_PtrSize*4 + 4*8 + A_PtrSize*5, 0), si )
   NumPut(STARTF_USESTDHANDLES, si, A_PtrSize*4 + 4*7)
   NumPut(hStdInRd            , si, A_PtrSize*4 + 4*8 + A_PtrSize*2)
   NumPut(hStdOutWr           , si, A_PtrSize*4 + 4*8 + A_PtrSize*3)
   NumPut(hStdOutWr           , si, A_PtrSize*4 + 4*8 + A_PtrSize*4)

   DllCall("CreateProcess", UInt, 0, Ptr, &sCmd, UInt, 0, UInt, 0, Int, True, UInt, CREATE_NO_WINDOW, UInt, 0, UInt, 0, Ptr, &si, Ptr, &pi)
   
   for k, v in [NumGet(pi, 0), NumGet(pi, A_PtrSize), hStdOutWr, hStdInRd, hStdInWr]
      DllCall("CloseHandle", Ptr, v)

   VarSetCapacity(sTemp, 4095)
   while DllCall("ReadFile", UInt, hStdOutRd, Ptr, &sTemp, UInt, 4095, UIntP, nSize, UInt, 0)
      sOutput .= StrGet(&sTemp, nSize, encoding)
   DllCall("CloseHandle", Ptr, hStdOutRd)
   Return sOutput
}

А чтобы сработало без ошибок, можно проверять оба варианта:

ComObjError(false)
w32time := ComObjGet("winmgmts:").Get("Win32_Service.Name='w32time'")
if A_LastError
{
   RunWait w32tm /register,, Hide
   msgbox нужен рестарт компьютера
   ExitApp
}
state := w32time.state
if (state = "stopped")
{
   StartMode := w32time.StartMode
   if (StartMode = "Disabled")
      w32time.ChangeStartMode("Automatic")
   w32time.StartService
}
for k, quotes in ["""", """"""""]  {
   RunWait, % "w32tm /config /update /manualpeerlist:"
             . quotes . "0.pool.ntp.org 1.pool.ntp.org 2.pool.ntp.org 3.pool.ntp.org" . quotes
             . " /syncfromflags:MANUAL /reliable:yes",, Hide
;  MsgBox, % ErrorLevel
} until !ErrorLevel
RunWait w32tm /resync /force,, Hide

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (Malcev) — Sat, 17 Jun 2017 05:49:14 +0000

Отписал. Посмотрим, что ответят.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 05:28:24 +0000

Malcev пишет:

Но если же запускать через ahk32 бит, то нужно эти кавычки утраивать.

Действительно, похоже на баг. Попробуй спросить на форуме, интересно, в чём проблема.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 05:17:58 +0000

teadrinker пишет:

У меня первые два варианта выдают одинаковую ошибку

Похоже, лишний пробел вставлял.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 05:15:09 +0000

Ага, подтверждаю.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (Malcev) — Sat, 17 Jun 2017 05:10:56 +0000

Ну так я о чём.
С одним сервером кавычки не нужны.
Если же список серверов, то нужны кавычки (в 26 посте я привёл ссылку).
И самое интересное, что если запускать скрипт через ahk64 бит, то указываешь одинарные кавычки, что логично, т ак как это строка.
Но если же запускать через ahk32 бит, то нужно эти кавычки утраивать.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 05:08:03 +0000

Выяснил, что если указывать один сервер, то работает с любым. Значит, просто синтаксис неверный.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 05:05:35 +0000

А, нет, неправильно просто написал, перед сервером пробел поставил. С моим работает.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (Malcev) — Sat, 17 Jun 2017 05:03:42 +0000

У меня работает так и на 32-бит и на 64:

runwait, cmd.exe /k w32tm /config /update /manualpeerlist:time-a.nist.gov /syncfromflags:MANUAL /reliable:yes

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 05:00:32 +0000

А сейчас вот у меня даже с моим сервером не работает:

Следующие аргументы были непредвиденными:
time-a.nist.gov

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (Malcev) — Sat, 17 Jun 2017 04:55:20 +0000

Работает, потому что с одним сервером кавычки вообще не нужны:

manualpeerlist:—Sets the manual peer list to , which is a space-delimited list of Domain Name System (DNS) and/or IP addresses. When you are specifying multiple peers, this option must be enclosed in quotation marks (“).

https://technet.microsoft.com/en-us/lib … s.11).aspx

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 04:50:18 +0000

У меня с моим сервером на 32-битном работает так же.

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (Malcev) — Sat, 17 Jun 2017 04:39:09 +0000

Интересно.
На 64-битном ahk надо запускать с одинарными кавычками:

runwait, cmd.exe /k w32tm /config /update /manualpeerlist:"0.pool.ntp.org 1.pool.ntp.org 2.pool.ntp.org 3.pool.ntp.org" /syncfromflags:MANUAL /reliable:yes

А на 32-битном с тройными:

runwait, cmd.exe /k w32tm /config /update /manualpeerlist:"""0.pool.ntp.org 1.pool.ntp.org 2.pool.ntp.org 3.pool.ntp.org""" /syncfromflags:MANUAL /reliable:yes

Баг что ли?

Re: AHK: Включение синхронизации с сервером времени.

null@example.com (teadrinker) — Sat, 17 Jun 2017 04:15:35 +0000

У меня первые два варианта выдают одинаковую ошибку:

Следующие аргументы были непредвиденными:
"0.pool.ntp.org 1.pool.ntp.org 2.pool.ntp.org 3.pool.ntp.org"

Третий тоже не работает:

Неизвестная команда /config /update /manualpeerlist:"0.pool.ntp.org.

Зато с сервером, прописанным у меня, всё в порядке:

runwait, cmd.exe /k w32tm /config /update /manualpeerlist:"time-a.nist.gov" /syncfromflags:MANUAL /reliable:yes

Команда выполнена успешно.

С одинарными кавычками.