Серый форум — AHK: Обработка текстового документа.

Re: AHK: Обработка текстового документа.

null@example.com (Vicoriyan) — Mon, 18 Sep 2017 19:13:02 +0000

Malcev Догнал.

For k, v in Arr
   res .= A_Index ". " k " - " v "`n"
MsgBox % res

Re: AHK: Обработка текстового документа.

null@example.com (Malcev) — Mon, 18 Sep 2017 18:57:20 +0000

Vicoriyan, ну а из чего по-вашему получается итоговая строка res?

Re: AHK: Обработка текстового документа.

null@example.com (Vicoriyan) — Mon, 18 Sep 2017 18:29:56 +0000

stealzy Все равно не понял где.

Re: AHK: Обработка текстового документа.

null@example.com (stealzy) — Mon, 18 Sep 2017 15:59:27 +0000

Vicoriyan пишет:

Куда следует поставить A_Index, что бы шла нумерация строк

Вероятно в начало строки, из вариаций которой склеивается итоговая строка(ваш К.О.).

Re: AHK: Обработка текстового документа.

null@example.com (Vicoriyan) — Mon, 18 Sep 2017 10:23:16 +0000

Malcev Куда следует поставить A_Index, что бы шла нумерация строк. На примере это выглядит так:

1. 0xFF0146BF - 980
2. 0xFFDBA51E - 220
3. 0xFF002F87 - 198
4. 0xFF181822 - 102
5. 0xFF8B99A6 - 98
6. 0xFFE66B70 - 52
7. 0xFF7D1F2D - 44
8. 0xFF5D9CEC - 24
9. 0xFF00469E - 11
10. 0xFFFFFEFF - 10
11. 0xFF145348 - 7
12. 0xFF006756 - 1
13. 0xFF871423 - 1
И так далее.

Re: AHK: Обработка текстового документа.

null@example.com (Malcev) — Sat, 26 Aug 2017 18:22:00 +0000

SetBatchLines, -1
CoordMode, Pixel, screen
pToken := Gdip_Startup()
pBitmap := Gdip_BitmapFromScreen()
width := Gdip_GetImageWidth(pBitmap)
height := Gdip_GetImageHeight(pBitmap)
Gdip_LockBits(pBitmap, 0, 0, width, height, Stride, Scan0, BitmapData)
Arr:={}
loop % width
{
   A_Index_X := A_Index-1
   loop % height
   {
      CurrentPixel := Gdip_GetLockBitPixel(Scan0, A_Index_X, A_Index-1, Stride)
      If Arr.HasKey("" CurrentPixel)
         ++Arr["" CurrentPixel]
      Else
         Arr["" CurrentPixel]:=1
   }
}
Gdip_UnlockBits(pBitmap, BitmapData)
Gdip_DisposeImage(pBitmap)
Gdip_Shutdown(pToken)
For k, v in Arr
   res .= k " - " v "`n"
MsgBox % res

Re: AHK: Обработка текстового документа.

null@example.com (Vicoriyan) — Sat, 26 Aug 2017 17:59:56 +0000

Malcev есть картинка например 50х50. В этой картинке 2500 пикселей. Мне нужно, чтоб скрипт проанализировал сколько шт пикселей того или иного цвета есть на этой картинке. Результат должен выглядеть так:
0xFF0146BF - 980
0xFFDBA51E - 220
0xFF002F87 - 198
0xFF181822 - 102
0xFF8B99A6 - 98
0xFFE66B70 - 52
0xFF7D1F2D - 44
0xFF5D9CEC - 24
0xFF00469E - 11
0xFFFFFEFF - 10
0xFF145348 - 7
0xFF006756 - 1
0xFF871423 - 1
И так далее.

Re: AHK: Обработка текстового документа.

null@example.com (Malcev) — Sat, 26 Aug 2017 17:52:08 +0000

Мне лично непонятна задача, что имеем и что хотим получить.

Re: AHK: Обработка текстового документа.

null@example.com (Vicoriyan) — Sat, 26 Aug 2017 17:03:35 +0000

serzh82saratov Долго в плане обработки пикселей или для поиска самого решения? А вопрос наверное нельзя дублировать в другой теме. Если уж задал тут, может кто поможет.

Re: AHK: Обработка текстового документа.

null@example.com (serzh82saratov) — Sat, 26 Aug 2017 16:43:07 +0000

Можете наверное, но это очень долго, я бы искал решение в вашей теме про пиксели.

Re: AHK: Обработка текстового документа.

null@example.com (Vicoriyan) — Sat, 26 Aug 2017 13:50:51 +0000

serzh82saratov Могу ли я применить Ваш скрипт для определения, сколько раз встречается тот или иной пиксель в выделенной области?
Пиксели ищем с помощью этого скрипта:


SetBatchLines, -1
CoordMode, Pixel, screen
pixelArray := []
pToken := Gdip_Startup()
pBitmap := Gdip_BitmapFromScreen("100|0|10|10")
width := Gdip_GetImageWidth(pBitmap)
height := Gdip_GetImageHeight(pBitmap)
Gdip_LockBits(pBitmap, 0, 0, width, height, Stride, Scan0, BitmapData)
loop % width
{
   A_Index_X := A_Index-1
   loop % height
   {
      pixelArray[A_Index_X, A_Index-1] := Gdip_GetLockBitPixel(Scan0, A_Index_X, A_Index-1, Stride)
   }
}
Gdip_UnlockBits(pBitmap, BitmapData)
Gdip_DisposeImage(pBitmap)
Gdip_Shutdown(pToken)

Re: AHK: Обработка текстового документа.

null@example.com (Mox) — Mon, 07 Aug 2017 12:07:59 +0000

serzh82saratov
Так норм. Ещё раз спасибо!

Re: AHK: Обработка текстового документа.

null@example.com (serzh82saratov) — Mon, 07 Aug 2017 11:04:35 +0000

А так?


cars = cars.txt
FileRead, list, *t %cars%

Loop, Parse, % List . Arr := {}, `n, `r 
	If (A_LoopField ~= "\S+" && !Arr.HasKey(A_LoopField) && Arr[A_LoopField] := 1)
		RegExReplace(List, "m`ai)^\Q" A_LoopField "\E$", "", Count) 
		, Res .= A_LoopField " - " Count "`n"

FileDelete, %cars%
FileAppend, %res%, %cars%
msgbox, % res

Re: AHK: Обработка текстового документа.

null@example.com (Mox) — Mon, 07 Aug 2017 10:59:44 +0000

Всё ровно какая-то фигня.
Содержимое .txt файла:


a
a

aa
a
aaa
aa
a

aaa

Скрипт, который я слепил:


cars = cars.txt
Arr:={}
FileRead, list, %cars%
list := RegExReplace(List, "\R\s*(?=\R)")
Loop, parse, list, `n, `r
	If Arr.HasKey(A_LoopField)
		++Arr[A_LoopField]
	Else
		Arr[A_LoopField]:=1

For k, v in Arr
	res .= k " - " v "`n"
FileDelete, %cars%
FileAppend, %res%, %cars%
msgbox, % res

Он удаляет все пустые строки в промежутках, но всё ровно в конце одна не удаляется... и он её считает. И выдаёт:


 - 1
a - 4
aa - 2
aaa - 2

Как это пофиксить?

Re: AHK: Обработка текстового документа.

null@example.com (Mox) — Mon, 07 Aug 2017 09:40:28 +0000

serzh82saratov
Вкурил. Спасибо огромное.