Серый форум — AHK: Сравнение массива с массивом

Re: AHK: Сравнение массива с массивом

null@example.com (teadrinker) — Fri, 06 Mar 2020 23:23:20 +0000

Всё правильно, но только в моём примере элементы не равны. В первом массиве просто нет второго элемента, во втором он пустой, это не одно и то же.

Re: AHK: Сравнение массива с массивом

null@example.com (kolotilov256) — Fri, 06 Mar 2020 22:55:51 +0000

В моём случае эквивалентными массивами являются массивы, элементы которых соответственно равны.

Re: AHK: Сравнение массива с массивом

null@example.com (teadrinker) — Fri, 06 Mar 2020 15:34:15 +0000

Так это неправильно.

Re: AHK: Сравнение массива с массивом

null@example.com (kolotilov256) — Fri, 06 Mar 2020 15:31:22 +0000

teadrinker
Ну такие тонкости в реальной работе с массивом никак не помешают.
Тем не менее

if (a[2] == b[2])
	msgbox true
else msgbox false

выдает true, значит в ходе какого-нибудь процесса моя функция не должна поломать алгоритм.

Re: AHK: Сравнение массива с массивом

null@example.com (teadrinker) — Thu, 05 Mar 2020 20:59:20 +0000

Тоже не совсем:

a := [1]
a[3] := 3
b := [1, "", 3]
MsgBox, % equal(a, b)
MsgBox, % a.HasKey(2) "`n" b.HasKey(2)

equal(Array1,Array2) 
{
   if !isObject(Array1) 
   {
      if (Array1 == Array2)
         return true
      else return false
   }
   else
   {
      leng1 := Array1.Length()
      leng2 := Array2.Length()
      if (leng1 = leng2) 
      {
         Loop % leng1 
            if !equal(Array1[A_Index], Array2[A_Index])
               return false
         return true
      }
      else return false
   }
}

Re: AHK: Сравнение массива с массивом

null@example.com (kolotilov256) — Thu, 05 Mar 2020 20:36:52 +0000

teadrinker, да, не учёл частные случаи)
Теперь кажись нормально.

equal(Array1,Array2) 
{
   if !isObject(Array1) 
   {
      if (Array1 == Array2)
         return true
      else return false
   }
   else
   {
      leng1 := Array1.Length()
      leng2 := Array2.Length()
      if (leng1 = leng2) 
      {
         Loop % leng1 
            if !equal(Array1[A_Index], Array2[A_Index])
               return false
         return true
      }
      else return false
   }
}

Re: AHK: Сравнение массива с массивом

null@example.com (teadrinker) — Thu, 05 Mar 2020 15:20:19 +0000

kolotilov256
Ваша не работает:

a := [[]]
b := [[]]
MsgBox, % equal(a, b)

equal(Array1,Array2) {
   if !Array1[1] and !Array2[1] {
      if (Array1 = Array2)
         return true
      else return false
   } else {
      leng1 := Array1.Length()
      leng2 := Array2.Length()
      if (leng1 = leng2) {
         Loop % leng1 {
            if !equal(Array1[A_Index], Array2[A_Index])
               return false
         } return true
      } else return false
   }
}

Re: AHK: Сравнение массива с массивом

null@example.com (kolotilov256) — Thu, 05 Mar 2020 14:42:18 +0000

Хэш суммы это конечно хорошо, но старый дедовский метод работает в 5 раз быстрее (Проверял через A_TickCount)

equal(Array1,Array2) {
   if !Array1[1] and !Array2[1] {
      if (Array1 = Array2)
         return true
      else return false
   } else {
      leng1 := Array1.Length()
      leng2 := Array2.Length()
      if (leng1 = leng2) {
         Loop % leng1 {
            if !equal(Array1[A_Index], Array2[A_Index])
               return false
         } return true
      } else return false
   }
}

Также держите ещё бонусом функцию find(Array, Var) для поиска элемента Var в массиве Array (Var тоже может быть массивом)

find(Array,Var) {
	For i, val in Array
		if equal(val,Var) or find(val,Var)
			return true
		
    return false
}

Re: AHK: Сравнение массива с массивом

null@example.com (serzh82saratov) — Wed, 15 Nov 2017 14:30:38 +0000

a := ["123", "123", "123", "222"]
b := ["123", "123", "123", "222"]

MsgBox % ArrayCompare(a, b)

ArrayCompare(obj1, obj2) {
	Loop 2
		VarSetCapacity(Bin%A_Index%, Size%A_Index% := RawObjectSize(obj%A_Index%, 0) + 8, 0)
		, RawObject(obj%A_Index%, NumPut(Size%A_Index% - 8, &Bin%A_Index%, "Int64"), 0)
	If (Size1 != Size2)
		Return 0
	Return !DllCall("msvcrt\memcmp", Ptr, &Bin1, Ptr, &Bin2, Ptr, Size1)
	  ;	Return Size1 = DllCall("NtDll\RtlCompareMemory", Ptr, &Bin1, Ptr, &Bin2, Ptr, Size1, Ptr)
}

RawObject(obj, addr, buf := 0, objects := 0) {
	; Type.Enum:    Char.1 UChar.2 Short.3 UShort.4 Int.5 UInt.6 Int64.7 UInt64.8 Double.9 String.10 Object.11
	; Negative for keys and positive for values
	If !objects
		objects:={(""):0,(obj):0}
	Else
		objects[obj]:=(++objects[""])
	for k, v in obj
	{ ; 9 = Int64 for size and Char for type
		If IsObject(k) {
			If objects.HasKey(k)
				NumPut(-12,addr+0,"Char"),NumPut(objects[k],addr+1,"Int64"),addr+=9
			Else
				NumPut(-11,addr+0,"Char"),NumPut(sz:=RawObjectSize(k,buf),addr+1,"Int64"),RawObject(k,addr+9,buf,objects),addr+=sz+9
		} Else
			NumPut(-10,addr+0,"Char"),NumPut(sz:=StrPut(k,addr+9)*2,addr+1,"Int64"),addr+=sz+9
		If IsObject(v) {
			If objects.HasKey(v)
				NumPut(12,addr+0,"Char"),NumPut(objects[v],addr+1,"Int64"),addr+=9
			Else
				NumPut(11,addr+0,"Char"),NumPut(sz:=RawObjectSize(v,buf),addr+1,"Int64"),RawObject(v,addr+9,buf,objects),addr+=sz+9
		} Else
			NumPut(10,addr+0,"Char"),NumPut(sz:=buf?obj.GetCapacity(k):StrPut(v)*2,addr+1,"Int64"),DllCall("RtlMoveMemory","PTR",addr+9,"PTR",buf?obj.GetAddress(k):&v,"PTR",sz),addr+=sz+9
	}
}

RawObjectSize(obj,buf:=0,objects:=0){
	If !objects
		objects:={(obj):1}
	Else If !objects.HasKey(obj)
		objects[obj]:=1
	for k, v in obj
	{
		If IsObject(k)
			sz+=objects.HasKey(k)?9:RawObjectSize(k,buf,objects)+9
		Else
			sz+=StrPut(k)*2+9
		If IsObject(v)
			sz+=objects.HasKey(v)?9:RawObjectSize(v,buf,objects)+9
		Else
			sz+=(buf?obj.GetCapacity(k):StrPut(v)*2)+9
	}
	Return sz
}

Re: AHK: Сравнение массива с массивом

null@example.com (teadrinker) — Wed, 15 Nov 2017 01:04:51 +0000

Написано, что доступна, начиная с Windows 2000.

Re: AHK: Сравнение массива с массивом

null@example.com (stealzy) — Wed, 15 Nov 2017 00:49:11 +0000

А, понял, RtlCompareMemory может не быть в XP.

Re: AHK: Сравнение массива с массивом

null@example.com (teadrinker) — Tue, 14 Nov 2017 23:46:33 +0000

Оба варианта вроде работают:

VarSetCapacity(var1, 4, 0)
VarSetCapacity(var2, 4, 0)

VarSetCapacity(var3, 4, 0)
VarSetCapacity(var4, 4, 0)

Loop 4  {
   i := A_Index
   Loop 4
      NumPut( (i = 4 && A_Index = 4) ? 2 : 1, var%i%, A_Index - 1, "UChar")  ; четвёртый буфер отличается
}

MsgBox, % DllCall("NtDll\RtlCompareMemory", Ptr, &var1, Ptr, &var2, Ptr, 4, Ptr)
MsgBox, % DllCall("NtDll\RtlCompareMemory", Ptr, &var3, Ptr, &var4, Ptr, 4, Ptr)

MsgBox, % DllCall("msvcrt\memcmp", Ptr, &var1, Ptr, &var2, Ptr, 4)
MsgBox, % DllCall("msvcrt\memcmp", Ptr, &var3, Ptr, &var4, Ptr, 4)

Re: AHK: Сравнение массива с массивом

null@example.com (stealzy) — Tue, 14 Nov 2017 23:37:47 +0000

https://autohotkey.com/boards/viewtopic … dac5#p9976

MsgBox % FileCompare("D:\Image_004.png"
	, "D:\11.gif")
;Pass a relative or absolute filename for each file1 and file2
;Returns true if the contents of file1 = file2, or false if there are differences
FileCompare(file1, file2)
{
  FileGetSize, sFile1, %file1%
  FileGetSize, sFile2, %file2%
  if (sFile1 != sFile2)
    return 0  ;Not the same size so impossible to have the same contents
  FileRead, bFile1, *c %file1%
  FileRead, bFile2, *c %file2%
  return sFile1 = DllCall("ntdll\RtlCompareMemory", "ptr", &bFile1, "ptr", &bFile2, "ptr", sFile1)
}

Интересно, что Lazlo использовал в своем коде RtlFillMemory, RtlMoveMemory, а для сравнения задействовал memcmp из библиотеки msvcrt.

Re: AHK: Сравнение массива с массивом

null@example.com (Malcev) — Tue, 14 Nov 2017 21:58:16 +0000

teadrinker пишет:

stealzy пишет:
Все же интересно, для ресурсов в памяти должен ведь быть способ побитовой сверки?
Winapi-функции вроде нет.

RtlCompareMemory?
https://msdn.microsoft.com/en-us/librar … s.85).aspx

Re: AHK: Сравнение массива с массивом

null@example.com (ypppu) — Tue, 14 Nov 2017 20:34:13 +0000

serzh82saratov пишет:

Есть у кого мысли по поводу предыдущего поста, не нашёл в справке про то что бинарные данные можно сравнивать.

Мож это?

AutoHotkey(RUS).chm пишет:

Переменные и выражения
...
^ Побитовое исключающиее ИЛИ (^)

Если в результате этого действия получаем ноль, значит строки одинаковые.