Серый форум — AHK: Как прервать цикл?

Re: AHK: Как прервать цикл?

null@example.com (autokey) — Thu, 22 Mar 2018 08:31:53 +0000

2teadrinker
спасибо с массивом будет не так громоздко, то что надо

и глупый вопрос про синтаксис
break 2 необходим для прерывания двух циклов или просто опечатка?

Re: AHK: Как прервать цикл?

null@example.com (teadrinker) — Wed, 21 Mar 2018 23:28:43 +0000

Как вариант:

keyArray := [ ["1"], ["2", 500], ["3", 200], ["7"], ["8", 500], ["9", 200] ]

$1::
   Critical
   if (toggle := !toggle)
      SetTimer, StartStop, -10
   Return

StartStop:
   Loop  {
      for k, v in keyArray  {
         SendInput, % v[1]
         if v.HasKey(2)
            Sleep, v[2]
         if !toggle
            break 2
      }
   }
   Return

Re: AHK: Как прервать цикл?

null@example.com (stealzy) — Wed, 21 Mar 2018 21:21:53 +0000

autokey, в AHK_H можно:
• делать Sleep внутри Send -

Send 12{500}3{200}78{500}9{200}

• запустить метку в отдельном потоке и завершить его в любой момент.

Re: AHK: Как прервать цикл?

null@example.com (autokey) — Wed, 21 Mar 2018 19:48:19 +0000

2Malcev когда в цикле более 100 строк и потенциально он еще разрастется раз в 10...
тогда уж проще будет запускать цикл отдельным скриптом и просто тушить его когда не нужен

Re: AHK: Как прервать цикл?

null@example.com (Malcev) — Wed, 21 Mar 2018 19:03:55 +0000

autokey, а чего некрасивого-то?

loop
{
   send 1
   if !toggle
      break
   send 2
   if !toggle
      break
   send 3
   if !toggle
      break
}

Re: AHK: Как прервать цикл?

null@example.com (qqlexa) — Wed, 21 Mar 2018 18:20:04 +0000

autokey,Создать функцию на проверку. Я как раз хочу найти об этом информацию, так как это годнота)

Re: AHK: Как прервать цикл?

null@example.com (autokey) — Wed, 21 Mar 2018 18:09:13 +0000

думал об этом, но у меня там около 100 строчек как то не красиво получается

Re: AHK: Как прервать цикл?

null@example.com (stealzy) — Wed, 21 Mar 2018 17:46:42 +0000

Тогда вставляйте проверку перед каждым Send.

Re: AHK: Как прервать цикл?

null@example.com (autokey) — Wed, 21 Mar 2018 17:25:56 +0000

2KusochekDobra
спасибо попробую через таймер, хотя мне нужно чтобы цикл обрывался и по клавише 1 и по клавише 2, и не прокручивался до конца после нажатия, а сразу обрывался

2stealzy
reload это немного не то что мне нужно.

Re: AHK: Как прервать цикл?

null@example.com (KusochekDobra) — Wed, 21 Mar 2018 11:55:29 +0000

Поместите внутрь цикла условие, проверяя которое, произойдёт остановка, если оно содержит соответствующее значение. Например:


$1::
SetKeyDelay, 100
toggle := true
loop {
	if (toggle) {
		send {1}
		send {2}
		sleep 500
		send {3}
		sleep 200
		send {7}
		send {8}
		sleep 500
		send {9}
		sleep 200
	} else
		break
}
return
$2::
	toggle := false
return

Но лучше воспользоваться таймером, который будет циклично воспроизводить этот участок кода, пока включен:


SetKeyDelay, 100
toggle := false

$1::
	toggle := !toggle
	if (toggle)
		SetTimer, ToggleMe, 100
	else
		SetTimer, ToggleMe, Off
return

ToggleMe:
	send {1}
	send {2}
	sleep 500
	send {3}
	sleep 200
	send {7}
	send {8}
	sleep 500
	send {9}
	sleep 200
return

AHK: Как прервать цикл?

null@example.com (autokey) — Wed, 21 Mar 2018 10:51:55 +0000

Есть цикл который спамит с паузами 123789, как его прервать во время исполнения нажатием клавиши 1 или 2

+ открыть спойлер

$1::
SetKeyDelay, 100
loop
{
send {1}
send {2}
sleep 500
send {3}
sleep 200
send {7}
send {8}
sleep 500
send {9}
sleep 200
}
return