Серый форум — VBS: Скрипт который мониторит процесс

Re: VBS: Скрипт который мониторит процесс

null@example.com (zcccz) — Wed, 31 Jan 2024 23:54:59 +0000

Xameleon пишет:

Отлично то что нужно большое спасибо .:)
Но есть маленький минус не получается сверху добавить другой скрипт например "On Error Resume Next".
А точнее хочется чтоб была защита от повторного запуска этого скрипта.
Так сказать сделать последний штрих .

Re: VBS: Скрипт который мониторит процесс

null@example.com (Xameleon) — Wed, 31 Jan 2024 22:05:38 +0000

...


Option Explicit
Dim arrProcessNames
Dim strProcessName
Dim strWqlQuery
Dim colEvents 
Dim objWshShell

arrProcessNames = Array("calc1.exe","calc2.exe","calc3.exe")
Set objWshShell = CreateObject("WScript.Shell")
strWqlQuery = "SELECT * FROM __InstanceOperationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process' AND (TargetInstance.Name = '" & Join(arrProcessNames, "' OR TargetInstance.Name = '") & "')"
Set colEvents = GetObject("winmgmts:\\.\Root\CIMV2").ExecNotificationQuery(strWqlQuery)

Do 
	With colEvents.NextEvent
		'если процесс запускается
		If .Path_.Class = "__InstanceCreationEvent" Then
			objWshShell.Run "taskkill /f /IM notepad.exe", 0
		'если процесс завершается
		ElseIf .Path_.Class = "__InstanceDeletionEvent" Then
			objWshShell.Run "notepad.exe"
		End If
	End With
Loop

Re: VBS: Скрипт который мониторит процесс

null@example.com (zcccz) — Wed, 31 Jan 2024 18:21:01 +0000

Xameleon пишет:

В примере моего кода это реализовано.

Ну первое черное окно которое показывает какой процесс открылся потом закрылся .Пробую WshShell.Run "taskkill /f /IM notepad.exe", 0 просит WshShell.Run и много какие моменты.
А тот код который дал он работает совершенно по другому .
Если вы сможете изменить код который я дал очень буду признателен .

Re: VBS: Скрипт который мониторит процесс

null@example.com (Xameleon) — Wed, 31 Jan 2024 14:47:46 +0000

zcccz, так а что вам мешает использовать тот код, который я привёл в примере ? Вы спросили:

можно ли сделать так чтоб срабатывало не только один "calc.exe" а несколько?

В примере моего кода это реализовано.

Re: VBS: Скрипт который мониторит процесс

null@example.com (zcccz) — Tue, 30 Jan 2024 00:41:31 +0000

Xameleon пишет:

zcccz, приветствую ! Да, без проблем.

Спасибо конечно но вы не тот код изменили .
Мне нужно именно этот изменить .

Set WSHShell = WScript.CreateObject("WScript.Shell")
Const ProcName = "calc.exe"
Set colEvents = GetObject("winmgmts:\\.\Root\CIMV2").ExecNotificationQuery( _
  "SELECT * FROM __InstanceOperationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process' " & _
  "AND TargetInstance.Name = '" & ProcName & "'")
Do 
 With colEvents.NextEvent
  'если процесс запускается
  If .Path_.Class = "__InstanceCreationEvent" Then
       WshShell.Run "taskkill /f /IM notepad.exe", 0
  'если процесс завершается
  ElseIf .Path_.Class = "__InstanceDeletionEvent" Then
     WshShell.Run "notepad.exe"
  End If
 End With
Loop

А ваш пробую и совершенно не то получается.

Re: VBS: Скрипт который мониторит процесс

null@example.com (Xameleon) — Mon, 29 Jan 2024 19:26:28 +0000

zcccz, приветствую ! Да, без проблем.


Option Explicit
Dim arrProcessNames
Dim strProcessName
Dim strWqlQuery
Dim colEvents 

RunInConsoleMode()

arrProcessNames = Array("calc.exe","calculator.exe","win32calc.exe","notepad.exe")
strWqlQuery = "SELECT * FROM __InstanceOperationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process' AND (TargetInstance.Name = '" & Join(arrProcessNames, "' OR TargetInstance.Name = '") & "')"
Set colEvents = GetObject("winmgmts:\\.\Root\CIMV2").ExecNotificationQuery(strWqlQuery)

Do 
	With colEvents.NextEvent
		'если процесс запускается
		If .Path_.Class = "__InstanceCreationEvent" Then
			Wsh.Echo "Process " &  .TargetInstance.Name & "[" & .TargetInstance.ProcessId & "] created"
		'если процесс завершается
		ElseIf .Path_.Class = "__InstanceDeletionEvent" Then
			Wsh.Echo "Process " &  .TargetInstance.Name & "[" & .TargetInstance.ProcessId & "] terminated"
		End If
	End With
Loop

Sub RunInConsoleMode()
	If InStr(1,WScript.FullName,"cscript.exe") < 1 Then
		CreateObject("WScript.Shell").Run("cscript //nologo """ & WScript.ScriptFullName & """")
		WScript.Quit
	End if
End Sub

Re: VBS: Скрипт который мониторит процесс

null@example.com (zcccz) — Fri, 26 Jan 2024 11:20:22 +0000

Xameleon
Здравствуйте мне очень понравился код но можно ли сделать так чтоб срабатывало не только один "calc.exe" а несколько?
Например "calc.exe","calc2.exe","calc3.exe".

Set WSHShell = WScript.CreateObject("WScript.Shell")
Const ProcName = "calc.exe"
Set colEvents = GetObject("winmgmts:\\.\Root\CIMV2").ExecNotificationQuery( _
  "SELECT * FROM __InstanceOperationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process' " & _
  "AND TargetInstance.Name = '" & ProcName & "'")
Do 
 With colEvents.NextEvent
  'если процесс запускается
  If .Path_.Class = "__InstanceCreationEvent" Then
       WshShell.Run "taskkill /f /IM notepad.exe", 0
  'если процесс завершается
  ElseIf .Path_.Class = "__InstanceDeletionEvent" Then
     WshShell.Run "notepad.exe"
  End If
 End With
Loop

Re: VBS: Скрипт который мониторит процесс

null@example.com (astra95) — Mon, 02 Apr 2018 06:04:55 +0000

Спасибо всем кто откликнулся, решил всетаки использовать свой первоначальный скрипт с ключем запуска //T: 35500 теперь все отрабатывает как надо !

Re: VBS: Скрипт который мониторит процесс

null@example.com (Xameleon) — Sun, 01 Apr 2018 17:39:57 +0000

svoboden, озадачился непонятным явлением. Запустил Ваш скрипт у себя на Win 10. Работает то нормально, то нестабильно. Периодически не реагирует на запуск калькулятора. Хотя всё написано просто и понятно и кода то пара строк. К сожалению, в будни времени изучить не было, решил в выходные разобраться. Оказалось на Win 10 при запуске calc.exe, попеременно стартует то процесс calc.exe, то calculator.exe, хотя на экране визуально запускается одно и тоже приложение. Вот же ж микрософтовцы намудрили.

Решил отладиться на таком коде и тут же увидел в чём дело.


EnableConsoleMode()

Set colEvents = GetObject("winmgmts:\\.\Root\CIMV2").ExecNotificationQuery( _
	"SELECT * FROM " & _
		"__InstanceCreationEvent WITHIN 1 " & _
	"WHERE " & _ 
		"TargetInstance ISA 'Win32_Process'")
Do
	With colEvents.NextEvent
		WScript.Echo .TargetInstance.Name
	End With
Loop
	
Sub EnableConsoleMode()
	If InStr(1,WScript.FullName,"cscript.exe") < 1 Then
		CreateObject("WScript.Shell").Run("cscript //nologo """ & WScript.ScriptFullName & """")
		WScript.Quit
	End if
End Sub

Re: VBS: Скрипт который мониторит процесс

null@example.com (svoboden) — Fri, 30 Mar 2018 14:47:25 +0000

astra95, изначальный запуск - это не самая большая проблема. Ваш вопрос изначально сложный, т.к. не понятно, как должен вести себя скрипт, если вы откроете, например, блокнот, когда запущен калькулятор.

astra95 пишет:

Все таки скрипт не отрабатывает как нужно при длительном простое

Если скрипт автоматически закрывается, то посмотрите, стоит ли галочка: "Остановить сценарий после указанного числа секунд" в параметрах сервера сценариев.

Re: VBS: Скрипт который мониторит процесс

null@example.com (astra95) — Thu, 29 Mar 2018 10:59:29 +0000

svoboden
Я понял какк он отробатывает, получаеться он отслеживает сам диспетчер задач. Попробую его приминить к своему процессу, спасибо.
Все отробатывает, но не хватает изначального запуска процесса хотелось бы сделать это в одном скрипте, если можете помогите пожалуйста !

Все таки скрипт не отрабатывает как нужно при длительном простое, при открытии calc.exe не закрываеться notepad.exe, за то ликвидируеться сам скрипт !

Re: VBS: Скрипт который мониторит процесс

null@example.com (astra95) — Thu, 29 Mar 2018 06:30:12 +0000

Xameleon
В том то и дел что мой вариант хоть и не полноценный запускает процесс, а этот вариант нет !

svoboden
Честно сказать я тоже интерпритировал работу скрипта так же как и Xameleon. Как же он тогда отрабатывает ?

Re: VBS: Скрипт который мониторит процесс

null@example.com (svoboden) — Wed, 28 Mar 2018 20:29:09 +0000

astra95 пишет:

но не запускает блокнот!

А он и не должен его запускать, если не закроется процесс calc.exe.

Re: VBS: Скрипт который мониторит процесс

null@example.com (Xameleon) — Wed, 28 Mar 2018 11:42:21 +0000

astra95, а приложение калькулятора [calc.exe] Вы при этом запустили ?

Такой вариант скрипта, как приведён выше, требует, чтобы calc.exe был запущен после запуска скрипта (Т.е если calc.exe был запущен до запуска скрипта, то уже условие не сработает, т.к скрипт мониторит именно появление новых процессов и игнорирует старые.)

Re: VBS: Скрипт который мониторит процесс

null@example.com (astra95) — Wed, 28 Mar 2018 07:47:09 +0000

svoboden
Спасибо за ответ, но не работает, решил попробовать ваш пример не меняя ничего, скрипт запускаеться без проблем но не запускает блокнот!