Серый форум — AHK: Поиск последней строки в .txt

Re: AHK: Поиск последней строки в .txt

null@example.com (serzh82saratov) — Sun, 08 Jul 2018 20:21:10 +0000

Можно, но такой ерундой никто не будет заниматся.
Вы хотите простое сделать сложным. Лучше поясните что имеется, и что нужно в итоге.

Re: AHK: Поиск последней строки в .txt

null@example.com (MirchikAhtung) — Sun, 08 Jul 2018 10:03:35 +0000

serzh82saratov Маленькое продолжение темы.


varX := NeedLine(A_ScriptFullPath, -4)
varY := NeedLine(A_ScriptFullPath, -6)

Gui, Show, x%varX% y%varY%

NeedLine(FilePath, Line) {
	FileRead, Text, usa.txt
	Text := StrReplace(StrReplace(Text, "`r`n", "`n"), "`r", "`n") "`n"
	s := InStr(Text, "`n", 0, (Line > 0), Abs(Line - 1)) + 1 
	Return SubStr(Text, s, InStr(Text, "`n", 0, (Line > 0), Abs(Line)) - s)
}

Такое вообще возможно сделать, чтобы функция NeedLine читала текст не с текстового документа, а с Gui, и Text, в котором и присутствуют строки (которые будут читаться функцией) будет выводиться как координаты в Gui, Show.
p.s Старался как можно внятней изложить мою мысль.

Re: AHK: Поиск последней строки в .txt

null@example.com (teadrinker) — Sat, 07 Jul 2018 13:12:36 +0000

alexii, спасибо, гляну.

Re: AHK: Поиск последней строки в .txt

null@example.com (alexii) — Sat, 07 Jul 2018 13:10:52 +0000

OFF:

teadrinker пишет:

OFF: Если файл очень большой, и нужно прочитать определённую строчку с конца, то наиболее экономичным способом будет что-то вроде этого:

А не хотите OLE DB опробовать, как здесь: VBScript: работа с большими текстовыми файлами? AHK ж уже давно научился в Automation. Конечно, файлы должны быть реально большими, бо с нынешними гигабайтами оперативной памяти и ReadAll не слишком медленно будет.

Re: AHK: Поиск последней строки в .txt

null@example.com (teadrinker) — Sat, 07 Jul 2018 13:00:48 +0000

OFF: Если файл очень большой, и нужно прочитать определённую строчку с конца, то наиболее экономичным способом будет что-то вроде этого:

FileReadLineFromEnd(filePath, nLineFromEnd)  {
   oFile := FileOpen(filePath, "r")
   oFile.Pos := oFile.Length
   (!(enc := oFile.Encoding) && enc := "cp0")
   charLen := enc = "UTF-16" ? 2 : 1
   i := 0
   Loop  {
      oFile.Pos -= charLen, prevPos := oFile.Pos
      if (oFile.Pos < 0 && notFound := true)
         break
      char := oFile[ "Read" . (enc = "UTF-16" ? "UShort" : "UChar") ]()
      if (char = 10 || char = 13)  {
         if ( prevChar = (char = 10 ? 13 : 10) )
            prevChar := ""
         else
            i++, prevChar := char
      }
      if (i = nLineFromEnd)
         break
      oFile.Pos := prevPos
   }
   ( !notFound && str := oFile.ReadLine() ), oFile.Close()
   Return RTrim(str, "`r`n")
}

Re: AHK: Поиск последней строки в .txt

null@example.com (serzh82saratov) — Sat, 07 Jul 2018 11:27:30 +0000

Если пробел поставить, то должно работать.

x%varX%y%varY%


varX := NeedLine(A_ScriptFullPath, -4)
varY := NeedLine(A_ScriptFullPath, -6)
MsgBox % varX "`n" varY

Gui, Add, Button, x%varX% y%varY%, Button

NeedLine(FilePath, Line) {
	FileRead, Text, %FilePath%
	Text := StrReplace(StrReplace(Text, "`r`n", "`n"), "`r", "`n") "`n"
	s := InStr(Text, "`n", 0, (Line > 0), Abs(Line - 1)) + 1 
	Return SubStr(Text, s, InStr(Text, "`n", 0, (Line > 0), Abs(Line)) - s)
}

Re: AHK: Поиск последней строки в .txt

null@example.com (serzh82saratov) — Sat, 07 Jul 2018 10:47:22 +0000

Так зачем так читать, если есть IniRead. И почему A_ScriptFullPath, если тогда в самом скрипте они могут быть прописаны как переменные.
Как же сильно я промахнулся с предположением про лог файл.)

Re: AHK: Поиск последней строки в .txt

null@example.com (MirchikAhtung) — Sat, 07 Jul 2018 10:43:05 +0000

serzh82saratov Функция считывает с конца файла 2 строки, в которых указаны 2-е координат.
.

varX := % NeedLine(A_ScriptFullPath, 4)

varY := % NeedLine(A_ScriptFullPath, 6)

Координаты кнопке устанавливаем как

Gui, Add, Button, x%varX%y%varY%, Button

Но так - не выходит.

Re: AHK: Поиск последней строки в .txt

null@example.com (serzh82saratov) — Sat, 07 Jul 2018 10:39:01 +0000

Не понял.

Re: AHK: Поиск последней строки в .txt

null@example.com (MirchikAhtung) — Sat, 07 Jul 2018 10:37:29 +0000

serzh82saratov А эту функцию можно засунуть под

var := % NeedLine(A_ScriptFullPath, -1)

; например??

Re: AHK: Поиск последней строки в .txt

null@example.com (serzh82saratov) — Sat, 07 Jul 2018 10:30:00 +0000

Я просто добавил чтобы было понятно как определять если запрос превышает кол-во строк.

teadrinker пишет:

Или так:

Я тоже сразу подумал про StrSplit, но загонять в массив например 5000 строк ради вывода одной, кажется избыточным.
Наверняка ТС читает какой нибудь лог, и он со временем разрастается. Когда речь про какие нибудь последние строки в файле, это похоже на поиск новой инфо в логе, тогда проще так.

Re: AHK: Поиск последней строки в .txt

null@example.com (YMP) — Sat, 07 Jul 2018 02:52:23 +0000

serzh82saratov пишет:

И добавить если указанная строка больше кол-ва строк в тексте, то при запросе назад показать первую строку, при запросе вперед показать последнюю строку.

Но ведь это не отвечает запросу.

Re: AHK: Поиск последней строки в .txt

null@example.com (teadrinker) — Fri, 06 Jul 2018 22:23:51 +0000

Я с такими файлами не сталкивался.

Re: AHK: Поиск последней строки в .txt

null@example.com (Malcev) — Fri, 06 Jul 2018 22:22:17 +0000

teadrinker, так не получается:

TestFile=1`r2`r3
FileDelete, TestFile.txt
FileAppend, %TestFile%, TestFile.txt
MsgBox, % FileReadLineFromEnd("TestFile.txt", 2)

FileReadLineFromEnd(filePath, nLineFromEnd)  {
   FileRead, text, % filePath
   arr := StrSplit(text, "`n", "`r")
   Return arr[ObjMaxIndex(arr) - nLineFromEnd + 1]
}

Re: AHK: Поиск последней строки в .txt

null@example.com (teadrinker) — Fri, 06 Jul 2018 21:56:17 +0000

Или так:

filePath := "D:\Downloads\test.txt"
MsgBox, % FileReadLineFromEnd(filePath, 2)

FileReadLineFromEnd(filePath, nLineFromEnd)  {
   FileRead, text, % filePath
   arr := StrSplit(text, "`n", "`r")
   Return arr[ObjMaxIndex(arr) - nLineFromEnd + 1]
}