Оказывается консоль не дружит со спец-символами-буквами.

Как бы да, но как бы и нет.
Я не вникал в код в этой теме. Но в общем случае можно заметить следующее.

Во-первых, если в качестве шрифта консоли указан используемый по умолчанию Terninal, то в окне консоли многие символы не будут правильно отображаться по определению, особенно при переключении кодировки (на результат перенаправления в файл это не влияет). У меня, кстати, стоит Courier New:

REGEDIT4
[HKEY_CURRENT_USER\Console]
"FaceName"="Courier New"
"FontFamily"=dword:00000036
"FontWeight"=dword:00000190
"FontSize"=dword:00110000

Во-вторых, можно вспомнить про ключ /U у CMD и CSCRIPT (используется в сообщении 2019-01-10 21:38:13).

В третьих, UTF-8

chcp 65001

в более новых выпусках CMD свободно работает в командных файлах, в более старых (для Win XP) — с костылями.

В четвёртых, мне не понятно в чём преимущество вызова ещё одного процесса CMD.EXE (именно так и искажается кодировка):

for /f "tokens=* delims=" %%f in ('dir /b /s "%workdir%\*.cue"') do

вместо

for /r "%workdir%" %%f in ("*.cue") do

А что значат в консоли строчки "Системе не удаётся найти указанный путь", здесь вроде бы не в юникоде дело?

0</*! ::
@echo off

for /f "tokens=2 delims=:" %%c in ( 'chcp' ) do set "cp=%%~c"

chcp 1251
call :main %* > "%~dpn0.txt"
chcp %cp%

goto :EOF

:main
setlocal

set "workdir=%~1"
if not defined workdir set "workdir=."

for /f "tokens=* delims=" %%f in ( '
	dir /b /s "%workdir%\*.cue" ^| cscript //nologo //e:javascript "%~f0"
' ) do for /f "tokens=*" %%n in ( '
	dir /b /s "%%~ff\*.flac" "%%~ff\.ape" ^| find /v /c ""
' ) do if %%~n equ 1 echo:%%~ff

goto :EOF

*/0;

var seen = {};

while ( ! WScript.StdIn.AtEndOfStream ) {
	var dir = WScript.StdIn.ReadLine().replace(/\\[^\\]+$/, "");
	seen[dir] = 1;
}

for (var p in seen) {
	WScript.StdOut.WriteLine(p);
}

Алгоритм обработки несколько изменился:
1. для заданного каталога или текущего каталога выполняем поиск всех *.cue файлов, выделяем имена каталогов и удаляем дубликаты (используется jscript)
2. для каждого, найденного в п.1 файла в том же каталоге определяем количество *.flac/*.ape файлы
3. если значение, найденное в п.2 равно 1, вывести имя каталога

Возможные улучшения:
1. Решена прооблема множества *.cue файлов в одном каталоге
2. Возможно решена проблема кириллических символов

"Синтактическая ошибка в имени файла...", видимо проблема с именами в юникоде

Возможно. Возможно, что это проявления одной проблемы.

Полагаю, что коллеги по форуму подскажут решение это проблемы, например, выставить chcp 1251 непосредственно перед выводом в файл.

Это надо решить на этапе формирования списка. В юниксах есть хорошая команда uniq, которая удаляет дубликаты. В случае виндоуз -- надо решать с привлечением допролнительных средств, например jscript.

Хотя в консоли бывает "Синтактическая ошибка в имени файла...", видимо проблема с именами в юникоде, но не уверен, надо проверять. А когда в папке несколько CUE, то в выходном TXT, имя указывается несколько раз, может это можно подчищать после отработки?

V:\Jazz\(2001) Dave Douglas - Witness\
V:\Jazz\(2001) Dave Douglas - Witness\
V:\Jazz\(2001) Dave Douglas - Witness\
V:\Jazz\(2001) Dave Douglas - Witness\

Ещё заметил такую забавную проблему, оказывается некоторые папки имеют в названии кириллическую букву "С" вот так (СD 1) и в файле получается (‘D 1").

Хотя то, что успеваю увидеть, там всё правильно.

Откройте консоль в текущем каталоге и запустите скрипт. Ну если Вы убедились, что все работает правильно, вот Вам вариант с файлом -- рядом с батником создается одноименный текстовый файл (при каждом запуске перезаписывается). Отличия от предыдущей версии минимальны.

@echo off

call :main %* > "%~dpn0.txt"
goto :EOF

:main
setlocal

set "workdir=%~1"
if not defined workdir set "workdir=."

for /f "tokens=* delims=" %%f in ( '
	dir /b /s "%workdir%\*.cue"
' ) do for /f "tokens=*" %%n in ( '
	dir /b /s "%%~dpf\*.flac" "%%~dpf\.ape" ^| find /v /c ""
' ) do if %%~n equ 1 echo:%%~dpf

goto :EOF

А как работает этот код?

Я же дал описание. Как Вы читатете?

Zak
Нет, в файл не сохраняется, вывод производится только в консоль. Проверьте, убедитесь, что работает правильно.

@echo off

setlocal

set "workdir=%~1"
if not defined workdir set "workdir=."

for /f "tokens=* delims=" %%f in ( '
	dir /b /s "%workdir%\*.cue"
' ) do for /f "tokens=*" %%n in ( '
	dir /b /s "%%~dpf\*.flac" "%%~dpf\.ape" ^| find /v /c ""
' ) do if %%~n equ 1 echo:%%~dpf

Описание:
1. для заданного каталога или текущего каталога выполняем поиск всех *.cue файлов
2. для каждого, найденного в п.1 файла в том же каталоге определяем количество *.flac/*.ape файлы
3. если значение, найденное в п.2 равно 1, вывести имя каталога

Недостатки:
1. не детектируется случай множества *.cue файлов в одном каталоге
2. предполагается, что один каталог содержит файлы только одного формата либо *.flac, либо *.ape, но не оба формата одновременно
2. алгоритм не тестировался