Серый форум — AHK: Загрузка файла из интернета

Re: AHK: Загрузка файла из интернета

null@example.com (EV) — Wed, 19 Apr 2023 09:32:42 +0000

UrlToFile := "https:?"
SaveFileAs := A_ScriptDir . "\1.Расширения файла"
Overwrite := True
If (FileExist(SaveFileAs)) {
    If (Overwrite)
        FileDelete, %SaveFileAs%
    Else
        Return
}

WinHttpObj := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WinHttpObj.Open("GET", UrlToFile)
WinHttpObj.SetRequestHeader("Cookie","bb_ssl=1; bb_session=?")
WinHttpObj.Send()
ADODBObj := ComObjCreate("ADODB.Stream")
ADODBObj.Type := 1
ADODBObj.Open()
ADODBObj.Write(WinHttpObj.ResponseBody)
ADODBObj.SaveToFile(SaveFileAs, Overwrite ? 2:1)
ADODBObj.Close()

Re: AHK: Загрузка файла из интернета

null@example.com (Malcev) — Tue, 18 Apr 2023 22:38:54 +0000

Если вы можете скачать файл через интернет эксплорер, то и UrlDownloadToFile теоретически должен работать (хотя не факт), так как autohotkey использует "AutoHotkey" как user-agent:
https://github.com/AutoHotkey/AutoHotke … .cpp#L1024

Re: AHK: Загрузка файла из интернета

null@example.com (john_dease) — Tue, 18 Apr 2023 21:39:02 +0000

У меня скачивается HTML-страница с расширением PDF, внутри которой есть ссылка на PDF:

https:\/\/psv4.userapi.com\/c235131\/u3260116\/docs\/d8\/36b926714245\/Beregis_shpionov_Sheynin_L.pdf?extra=ZWlUw7eqI5e-eFzWz71Ghbm7JHM-_SP_RuAu1JGs05AT0nWK25CcsQU_nGt19y7F2dAlimWVBWiath91EAHlB18cnRnn0zYaP_fuQgi_TW-vmVSK8TFDERANTbrdIrsX6E5c2jJE_ZM

Но сам файл не скачивается. Значит, UrlDownloadToFile не подходит для подобной загрузки?

Re: AHK: Загрузка файла из интернета

null@example.com (Malcev) — Tue, 18 Apr 2023 21:31:33 +0000

Всё прекрасно скачивается.
Может cкачивается не то, что вы хотели...
А почему такое происходит - додумайтесь сами.

Re: AHK: Загрузка файла из интернета

null@example.com (john_dease) — Tue, 18 Apr 2023 21:09:43 +0000

По какой причине не скачивается файл через UrlDownloadToFile, хотя в браузере открывается?

UrlDownloadToFile, https://vk.com/doc3260116_654218993?hash=9uXtHHpoQoROguesZgflOXaYZzBVGGFEygnUkQSzPPD, %a_scriptdir%\1111111111111.pdf

Re: AHK: Загрузка файла из интернета

null@example.com (Malcev) — Sun, 01 Mar 2020 13:44:16 +0000

С интернета.
Кстати автохоткивская команда urldownloadtofile использует эту же константу (INTERNET_FLAG_RELOAD) + INTERNET_FLAG_NO_CACHE_WRITE через wininet.

svoboden пишет:

И почему в Installer.ahk не использовать urldownloadtofile тогда, если отличия не большие

Как же небольшие - или каждый раз заново скачивается или берется с кеша.

Re: AHK: Загрузка файла из интернета

null@example.com (teadrinker) — Sun, 01 Mar 2020 10:58:44 +0000

Malcev пишет:

В UrlDownloadtoFile в отличии от URLDownloadToCacheFile не удастся прописать BINDF_GETNEWESTVERSION.

А откуда тут эта константа взялась?

HRESULT URLDownloadToCacheFile(
  _In_       LPUNKNOWN           lpUnkcaller,
  _In_       LPCSTR              szURL,
  _Out_      LPTSTR              szFileName,
  _In_       DWORD               cchFileName,
  _Reserved_ DWORD               dwReserved,
  _In_opt_   IBindStatusCallback *pBSC
);

Re: AHK: Загрузка файла из интернета

null@example.com (svoboden) — Sun, 01 Mar 2020 10:46:20 +0000

Значит URLDownloadToCacheFile лучше использовать? А насколько правильна функция выше, т.к. много функций из того файла пропущены. И почему в Installer.ahk не использовать urldownloadtofile тогда, если отличия не большие.

Re: AHK: Загрузка файла из интернета

null@example.com (Malcev) — Sun, 01 Mar 2020 10:36:17 +0000

В UrlDownloadtoFile в отличии от URLDownloadToCacheFile не удастся прописать BINDF_GETNEWESTVERSION.

DllCall("urlmon\URLDownloadToCacheFile", "ptr", 0, "str", url, "str", tn, "uint", 260, "uint", 0x10, "ptr*", &vt)

AHK: Загрузка файла из интернета

null@example.com (svoboden) — Sun, 01 Mar 2020 10:17:58 +0000

Удалось загрузить файл из гугл диска, используя функцию из файла Installer.ahk (оно же файл установки автохоткея):

url  := "https://drive.google.com/uc?id=свой id&authuser=0&export=download" ; свой запрос (в примере загружает exe) для разных типов файлов расширения разные.
file := "путь загрузки файла/Backup.exe"

Download(url, file)

Download(url, file)
{
    static vt
    if !VarSetCapacity(vt)
    {
        VarSetCapacity(vt, A_PtrSize*11), nPar := "31132253353"
        Loop Parse, nPar
            NumPut(RegisterCallback("DL_Progress", "F", A_LoopField, A_Index-1), vt, A_PtrSize*(A_Index-1))
    }
    global _cu
    SplitPath file, dFile
    SysGet m, MonitorWorkArea, 1
    scale := A_ScreenDPI ? A_ScreenDPI/96 : 1, y := mBottom-52*scale-2, x := mRight-330*scale-2
    , VarSetCapacity(_cu, 100), VarSetCapacity(tn, 520)
    , DllCall("shlwapi\PathCompactPathEx", "str", _cu, "str", url, "uint", 50, "uint", 0)
    Progress Hide CWFAFAF7 CT000020 CB445566 x%x% y%y% w330 h52 B1 FS8 WM700 WS700 FM8 ZH12 ZY3 C11,, %_cu%, AutoHotkeyProgress, Tahoma
    if (0 = DllCall("urlmon\URLDownloadToCacheFile", "ptr", 0, "str", url, "str", tn, "uint", 260, "uint", 0x10, "ptr*", &vt))
        FileCopy %tn%, %file%, 1
    else
        ErrorLevel := 1
    Progress Off
    return !ErrorLevel
}
DL_Progress( pthis, nP=0, nPMax=0, nSC=0, pST=0 )
{
    global _cu
    if A_EventInfo = 6
    {
        Progress Show
        Progress % P := 100*nP//nPMax, % "Downloading:     " Round(np/1024,1) " KB / " Round(npmax/1024) " KB    [ " P "`% ]", %_cu%
    }
    return 0
}

Вопрос такой: "нормальный ли это метод загрузки файлов из интернета? Или же лучше использовать UrlDownloadtoFile?
Вариант с wget и подобными утилитами не очень (часто выдавало ошибки). И как можно улучшить эту функции, т.к. много функций из файла мне непонятны. И вообще работает ли у вас этот способ загрузки файла?