Серый форум — AHK: Подсветка окна по pid

Re: AHK: Подсветка окна по pid

null@example.com (Malcev) — Mon, 30 Mar 2020 03:19:39 +0000

teadrinker пишет:

kolotilov256 пишет:
Во! Сейчас работает.
Неужели 32-битные Windows 10 бывают?

У меня не работало на Win10 64bit, Ahk 32bit.

Re: AHK: Подсветка окна по pid

null@example.com (teadrinker) — Mon, 30 Mar 2020 00:54:23 +0000

FLASHW_TRAY и FLASHW_TIMERNOFG — это константы, им не надо другие значения присваивать.
Лучше так:

Gui, +hwndhGui
Gui, Font, s12 q5, Calibri
Gui, Add, Text,, Кнопка на панели задач мигнёт 3 раза`nпотом будет подсвечена`nпока не пройдёт 5 секунд`nили пока окно не станет активным
Gui, Show, NA w300 h200

FlashTaskBarButton(hGui, 3)
Sleep, 5000
FlashTaskBarButton(hGui,, 1)
Return

GuiClose:
   ExitApp

FlashTaskBarButton(hGui, count := 0, stop := 0)  {
   static FLASHW_TRAY := 0x2, FLASHW_TIMERNOFG := 0xC
   VarSetCapacity(FLASHWINFO, size := A_PtrSize*3 + 4*2, 0)
   NumPut(size, FLASHWINFO)
   NumPut(hGui, FLASHWINFO, A_PtrSize)
   NumPut(stop ? 0 : FLASHW_TRAY|(count ? 0 : FLASHW_TIMERNOFG), FLASHWINFO, A_PtrSize*2)
   NumPut(count, FLASHWINFO, A_PtrSize*2 + 4)
   DllCall("FlashWindowEx", Ptr, &FLASHWINFO)
}

Re: AHK: Подсветка окна по pid

null@example.com (kolotilov256) — Mon, 30 Mar 2020 00:51:51 +0000

Вот так удалось порешать.

FlashTaskBarButton(hGui)
sleep 3000
FlashTaskBarButton(hGui,0,0,0)
Return

FlashTaskBarButton(hGui, count := 0, FLASHW_TRAY := 0x2, FLASHW_TIMERNOFG := 0xC)  {

   VarSetCapacity(FLASHWINFO, size := A_PtrSize*3 + 4*2, 0)
   NumPut(count, NumPut(FLASHW_TRAY|(count ? 0 : FLASHW_TIMERNOFG), NumPut(hGui, NumPut(size, FLASHWINFO)), "UInt"))
   DllCall("FlashWindowEx", Ptr, &FLASHWINFO)
}

Re: AHK: Подсветка окна по pid

null@example.com (kolotilov256) — Mon, 30 Mar 2020 00:41:30 +0000

Malcev, конкретно в той ссылке нет информации, как это мигание останавливать.
Нашёл на вот этой странице https://docs.microsoft.com/ru-ru/window … flashwinfo
похожий на правду параметр. Только как его в коде то применить? Пробовал FLASHWINFO := 0 делать, не помогло.

Re: AHK: Подсветка окна по pid

null@example.com (teadrinker) — Mon, 30 Mar 2020 00:11:30 +0000

kolotilov256 пишет:

Во! Сейчас работает.

Неужели 32-битные Windows 10 бывают?

Re: AHK: Подсветка окна по pid

null@example.com (Malcev) — Sun, 29 Mar 2020 23:58:31 +0000

Ответ на свой вопрос получите, почитав ссылку из 10 поста.

Re: AHK: Подсветка окна по pid

null@example.com (kolotilov256) — Sun, 29 Mar 2020 23:50:02 +0000

Во! Сейчас работает. А резонный вопрос, какой манипуляцией кода можно остановить это мигание?))) (Кроме как переключиться к мигающему окну)

Re: AHK: Подсветка окна по pid

null@example.com (teadrinker) — Sun, 29 Mar 2020 23:36:54 +0000

Да, точно.

Re: AHK: Подсветка окна по pid

null@example.com (Malcev) — Sun, 29 Mar 2020 23:33:36 +0000

Тут ошибка:

VarSetCapacity(FLASHWINFO, size := A_PtrSize*2 + 4*4, 0)

Надо так:

VarSetCapacity(FLASHWINFO, size := A_PtrSize*3 + 4*2, 0)

Re: AHK: Подсветка окна по pid

null@example.com (teadrinker) — Sun, 29 Mar 2020 23:32:31 +0000

А сама кнопка на панели задач появляется? И не мигает?

Re: AHK: Подсветка окна по pid

null@example.com (kolotilov256) — Sun, 29 Mar 2020 23:27:23 +0000

teadrinker, окно то появляется. Только при этом ничего не мигает.
Cделал вот ещё код для проверки, будут ли мигать текущие открытые окна или нет. Также ничего не мигало...

#SingleInstance Force
#Persistent
#NoEnv

text := ""
WinGet, id, list,,, Program Manager
Loop % id
{
	this_id := id%A_Index%
	WinGetClass, this_class, ahk_id %this_id%
	WinGet, pid, PID, ahk_id %this_id%
	text .= this_class "`n" pid "`n" this_id "`n`n"
	FlashTaskBarButton(this_id)
}
msgbox % text
Return

FlashTaskBarButton(hGui, count := 0)  {
   static FLASHW_TRAY := 0x2, FLASHW_TIMERNOFG := 0xC
   VarSetCapacity(FLASHWINFO, size := A_PtrSize*2 + 4*4, 0)
   NumPut(count, NumPut(FLASHW_TRAY|(count ? 0 : FLASHW_TIMERNOFG), NumPut(hGui, NumPut(size, FLASHWINFO)), "UInt"))
   DllCall("FlashWindowEx", Ptr, &FLASHWINFO)
}

Re: AHK: Подсветка окна по pid

null@example.com (teadrinker) — Sun, 29 Mar 2020 23:25:23 +0000

В смысле, ничего не происходит? Окно появляется?

Re: AHK: Подсветка окна по pid

null@example.com (kolotilov256) — Sun, 29 Mar 2020 22:57:35 +0000

Malcev, ну хорошо, обращается. Обычно при обращении выходит какой-то ответ. При запуске же этого кода ничего не происходит.

Re: AHK: Подсветка окна по pid

null@example.com (Malcev) — Sun, 29 Mar 2020 20:34:12 +0000

kolotilov256 пишет:

а что делает этот код?

Обращается к WinAPI:
https://docs.microsoft.com/en-us/window … shwindowex

Re: AHK: Подсветка окна по pid

null@example.com (kolotilov256) — Sun, 29 Mar 2020 20:31:49 +0000

ypppu, мне нужно под windows 10. Мигать должны не только окна autohotkey скриптов, но и окна любого другого запущенного процесса (В моём случае процесса игры gta samp)