Серый форум — VBS: Подправить скрипт для создания ярлыка на панели задач

Re: VBS: Подправить скрипт для создания ярлыка на панели задач

2021-01-24T07:53:36Z

user7256, день добрый.

Я бы предложил заменить конструкцию с With


    With WScript.CreateObject("Shell.Application")
        With .Namespace(objFSO.GetParentFolderName(objFile))
            With .ParseName(objFSO.GetFileName(objFile))
                .InvokeVerb("{:}")
            End With
        End With
    End With

на

CreateObject("Shell.Application") _
	.Namespace(objFSO.GetParentFolderName(objFile)) _
	.ParseName(objFSO.GetFileName(objFile)) _
	.InvokeVerb("{:}")

With нужен только если в выделенных местах необходимо множественное обращение к свойствам и методам исходного объекта на текущем уровне вложенности:

With WScript.CreateObject("Shell.Application")
---->
With .Namespace(objFSO.GetParentFolderName(objFile))
---->
With .ParseName(objFSO.GetFileName(objFile))
.InvokeVerb("{:}")
End With
---->
End With
---->
End With

Re: VBS: Подправить скрипт для создания ярлыка на панели задач

2021-01-23T19:32:15Z

Этот вариант не сработал.
Но я понял, что я сам ошибся.
Решил свою проблему, установив Рабочую папку в свойствах изначального lnk-файла.
Если не было прописано там, то и на панели задач не будет прописано.
Мой lnk-файл создавался в другом скрипте, а там можно выстановить эту рабочую папку.

Вам отдельное спасибо за желание помочь и плюс в карму.

Re: VBS: Подправить скрипт для создания ярлыка на панели задач

2021-01-23T16:42:48Z

user7256
Мне не хочется экспериментировать с модификацией реестра на своём компьютере, поэтому попробую чисто теоретически предложить:

    
    With WScript.CreateObject("Shell.Application")
        With .Namespace(objFSO.GetParentFolderName(objFile))
            With .ParseName(objFSO.GetFileName(objFile))
                .InvokeVerb("{:}")
'''
                With .GetLink
                    .WorkingDirectory = objFSO.GetParentFolderName(objFile) ' или какая должна быть рабочая папка?
                    .Save
                End With
'''
            End With
        End With
    End With

Re: VBS: Подправить скрипт для создания ярлыка на панели задач

2021-01-23T10:25:50Z

Что-то пока не получается.
Не могу понять, как это впихнуть в многоуровневый With.

Re: VBS: Подправить скрипт для создания ярлыка на панели задач

2021-01-22T16:43:05Z

user7256

Вроде, можно так (пример взят из Automation.chm - пока некогда писать и проверять код):

Set objShellApp = CreateObject("Shell.Application")
Set objFolder=objShellApp.NameSpace("C:\").ParentFolder.ParentFolder 'рабочий стол
Set objFolderItem = objFolder.ParseName("Paint.lnk")
Set objSLO = objFolderItem.GetLink
MsgBox objSLO.WorkingDirectory
objSLO.WorkingDirectory = "C:\"
objSLO.Save
MsgBox objSLO.WorkingDirectory

VBS: Подправить скрипт для создания ярлыка на панели задач

2021-01-22T12:19:51Z

Есть такой скрипт


' origin: https://stackoverflow.com/questions/31720595/pin-program-to-taskbar-using-ps-in-windows-10


If WScript.Arguments.Count < 1 Then WScript.Quit
'----------------------------------------------------------------------
Set objFSO = CreateObject("Scripting.FileSystemObject")
objFile    = WScript.Arguments.Item(0)
sKey1      = "HKCU\Software\Classes\*\shell\{:}\\"
sKey2      = Replace(sKey1, "\\", "\ExplorerCommandHandler")
'----------------------------------------------------------------------
With WScript.CreateObject("WScript.Shell")
    KeyValue = .RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer" & _
        "\CommandStore\shell\Windows.taskbarpin\ExplorerCommandHandler")

    .RegWrite sKey2, KeyValue, "REG_SZ"

    With WScript.CreateObject("Shell.Application")
        With .Namespace(objFSO.GetParentFolderName(objFile))
            With .ParseName(objFSO.GetFileName(objFile))
                .InvokeVerb("{:}")
            End With
        End With
    End With

    .Run("Reg.exe delete """ & Replace(sKey1, "\\", "") & """ /F"), 0, True
End With
'----------------------------------------------------------------------

Я запускаю его из стороннего приложения, передаю аргументом - путь к lnk-файлу, который хочу прикрепить к панели задач.
Скрипт хорошо работает.
Единственный минус - в свойствах получившегося ярлыка не заполнено поле "Рабочая папка".
А без этого запускаемая программа некорректно работает.
Исправить ее не получится (third party app).

Как в этом скрипте записать еще и рабочую папку?