Серый форум — AHK: Получение значения адресной строки в фаерфоксе через UIA

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (Malcev) — Tue, 13 Apr 2021 13:28:55 +0000

Точно.

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Tue, 13 Apr 2021 10:39:32 +0000

Понял, что было с SafeArray не так, нужно было флаг F_OWNVALUE удалить:

setbatchlines -1
IUIAutomation := ComObjCreate(CLSID_CUIAutomation := "{ff48dba4-60ef-4201-aa87-54103eef594e}", IID_IUIAutomation := "{30cbe57d-d9d0-452a-ab13-7ac5ac4825ee}")
oStates := [focusable_haspopup := 0x40100000, collapsed_focusable_haspopup := 0x40100400, expanded_focusable_haspopup := 0x40100200, focused_focusable_haspopup := 0x40100004, focused_collapsed_focusable_haspopup := 0x40100404, focused_expanded_focusable_haspopup := 0x40100204]

SafeArray := ComObjArray(VT_UNKNOWN := 13, oStates.Count())
ComObjFlags(SafeArray, -1)               ; Remove F_OWNVALUE
pSafeArray := ComObjValue(SafeArray)

loop % oStates.Count()
{
   VarSetCapacity(variant, 8+A_PtrSize*2, 0)
   NumPut(VT_I4 := 3, variant, 0, "ushort")
   NumPut(oStates[A_Index], variant, 8, "int")
   if (A_PtrSize = 4)
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "int64", NumGet(variant, 0, "int64"), "int64", NumGet(variant, 8, "int64"), "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   else
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "ptr", &variant, "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   NumPut(condition, NumGet(pSafeArray + 8 + A_PtrSize) + A_PtrSize*(A_Index - 1))
}
DllCall(NumGet(NumGet(IUIAutomation+0)+29*A_PtrSize), "ptr", IUIAutomation, "ptr", pSafeArray, "ptr*", condition1)   ; IUIAutomation::CreateOrConditionFromArray
NumPut(VT_I4 := 3, variant, 0, "ushort")
NumPut(UIA_EditControlTypeId := 50004, variant, 8, "int")
if (A_PtrSize = 4)
   DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_ControlTypePropertyId := 30003, "int64", NumGet(variant, 0, "int64"), "int64", NumGet(variant, 8, "int64"), "ptr*", condition2)   ; IUIAutomation::CreatePropertyCondition
else
   DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_ControlTypePropertyId := 30003, "ptr", &variant, "ptr*", condition2)   ; IUIAutomation::CreatePropertyCondition
DllCall(NumGet(NumGet(IUIAutomation+0)+25*A_PtrSize), "ptr", IUIAutomation, "ptr", condition1, "ptr", condition2, "ptr*", conditions)   ; IUIAutomation::CreateAndCondition
ObjRelease(condition1)
ObjRelease(condition2)
DllCall("oleaut32\SafeArrayDestroy", "ptr", pSafeArray)
return

f11::
DllCall(NumGet(NumGet(IUIAutomation+0)+6*A_PtrSize), "ptr", IUIAutomation, "ptr", WinExist("A"), "ptr*", ElementFromHandle)   ; IUIAutomation::ElementFromHandle
DllCall(NumGet(NumGet(ElementFromHandle+0)+5*A_PtrSize), "ptr", ElementFromHandle, "int", TreeScope_Descendants := 0x4, "ptr", conditions, "ptr*", element) ; IUIAutomationElement::FindFirst
VarSetCapacity(variant, 8+A_PtrSize*2, 0)
DllCall(NumGet(NumGet(element+0)+10*A_PtrSize), "ptr", element, "int", UIA_ValueValuePropertyId := 30045, "ptr", &variant)   ; IUIAutomationElement::GetCurrentPropertyValue
ObjRelease(element)
ObjRelease(ElementFromHandle)
msgbox % StrGet(NumGet(variant, 8, "ptr"), "utf-16")
return

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Thu, 01 Apr 2021 22:19:06 +0000

Ещё так можно:

SafeArray := DllCall("oleaut32\SafeArrayCreateVector", "uint", VT_UNKNOWN := 13, "uint", 0, "uint", oStates.Count())
loop % oStates.Count()
{
   VarSetCapacity(variant, 8+A_PtrSize*2, 0)
   NumPut(VT_I4 := 3, variant, 0, "ushort")
   NumPut(oStates[A_Index], variant, 8, "int")
   if (A_PtrSize = 4)
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "int64", NumGet(variant, 0, "int64"), "int64", NumGet(variant, 8, "int64"), "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   else
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "ptr", &variant, "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   NumPut(condition, NumGet(SafeArray + 8 + A_PtrSize) + A_PtrSize*(A_Index - 1))
}
DllCall(NumGet(NumGet(IUIAutomation+0)+29*A_PtrSize), "ptr", IUIAutomation, "ptr", SafeArray, "ptr*", condition1)   ; IUIAutomation::CreateOrConditionFromArray

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Thu, 01 Apr 2021 18:18:33 +0000

teadrinker пишет:

ComObjValue(SafeArrayConditions) — это сам SafeArray и есть.

Я имею в виду, что можно так:

DllCall(NumGet(NumGet(IUIAutomation+0)+29*A_PtrSize), "ptr", IUIAutomation, "ptr", SafeArray, "ptr*", condition1)

Malcev пишет:

Вначале я его создавал так

Да, я стал смотреть и тоже подумал, что так должно работать, но почему-то не выходит.

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (Malcev) — Thu, 01 Apr 2021 18:12:14 +0000

Вначале я его создавал так

SafeArray := ComObjArray(VT_UNKNOWN := 13, oStates.Count())

Сейчас так:

SafeArray := DllCall("oleaut32\SafeArrayCreateVector", "uint", VT_UNKNOWN := 13, "uint", 0, "uint", oStates.Count())

Я думал это одно и тоже, а похоже, что нет.

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Thu, 01 Apr 2021 18:06:03 +0000

Угу, работает. ComObjValue(SafeArrayConditions) — это сам SafeArray и есть.

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (Malcev) — Thu, 01 Apr 2021 17:26:09 +0000

Спасибо.
Изменил создание SafeArray.

setbatchlines -1
IUIAutomation := ComObjCreate(CLSID_CUIAutomation := "{ff48dba4-60ef-4201-aa87-54103eef594e}", IID_IUIAutomation := "{30cbe57d-d9d0-452a-ab13-7ac5ac4825ee}")
oStates := [focusable_haspopup := 0x40100000, collapsed_focusable_haspopup := 0x40100400, expanded_focusable_haspopup := 0x40100200, focused_focusable_haspopup := 0x40100004, focused_collapsed_focusable_haspopup := 0x40100404, focused_expanded_focusable_haspopup := 0x40100204]
SafeArray := DllCall("oleaut32\SafeArrayCreateVector", "uint", VT_UNKNOWN := 13, "uint", 0, "uint", oStates.Count())
if (A_PtrSize = 4)
   SafeArrayConditions := ComObject(0x2000|3, SafeArray, 1)
else
   SafeArrayConditions := ComObject(0x2000|0x14, SafeArray, 1)
loop % oStates.Count()
{
   VarSetCapacity(variant, 8+A_PtrSize*2, 0)
   NumPut(VT_I4 := 3, variant, 0, "ushort")
   NumPut(oStates[A_Index], variant, 8, "int")
   if (A_PtrSize = 4)
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "int64", NumGet(variant, 0, "int64"), "int64", NumGet(variant, 8, "int64"), "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   else
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "ptr", &variant, "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   SafeArrayConditions[A_Index-1] := condition
}
DllCall(NumGet(NumGet(IUIAutomation+0)+29*A_PtrSize), "ptr", IUIAutomation, "ptr", ComObjValue(SafeArrayConditions), "ptr*", condition1)   ; IUIAutomation::CreateOrConditionFromArray
VarSetCapacity(variant, 8+A_PtrSize*2, 0)
NumPut(VT_I4 := 3, variant, 0, "ushort")
NumPut(UIA_EditControlTypeId := 50004, variant, 8, "int")
if (A_PtrSize = 4)
   DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_ControlTypePropertyId := 30003, "int64", NumGet(variant, 0, "int64"), "int64", NumGet(variant, 8, "int64"), "ptr*", condition2)   ; IUIAutomation::CreatePropertyCondition
else
   DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_ControlTypePropertyId := 30003, "ptr", &variant, "ptr*", condition2)   ; IUIAutomation::CreatePropertyCondition
DllCall(NumGet(NumGet(IUIAutomation+0)+25*A_PtrSize), "ptr", IUIAutomation, "ptr", condition1, "ptr", condition2, "ptr*", conditions)   ; IUIAutomation::CreateAndCondition
ObjRelease(condition1)
ObjRelease(condition2)
DllCall("oleaut32\SafeArrayDestroy", "ptr", SafeArray)
return

f11::
DllCall(NumGet(NumGet(IUIAutomation+0)+6*A_PtrSize), "ptr", IUIAutomation, "ptr", WinExist("A"), "ptr*", ElementFromHandle)   ; IUIAutomation::ElementFromHandle
DllCall(NumGet(NumGet(ElementFromHandle+0)+5*A_PtrSize), "ptr", ElementFromHandle, "int", TreeScope_Descendants := 0x4, "ptr", conditions, "ptr*", element) ; IUIAutomationElement::FindFirst
VarSetCapacity(variant, 8+A_PtrSize*2, 0)
DllCall(NumGet(NumGet(element+0)+10*A_PtrSize), "ptr", element, "int", UIA_ValueValuePropertyId := 30045, "ptr", &variant)   ; IUIAutomationElement::GetCurrentPropertyValue
ObjRelease(element)
ObjRelease(ElementFromHandle)
msgbox % StrGet(NumGet(variant, 8, "ptr"), "utf-16")
return

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Thu, 01 Apr 2021 16:15:40 +0000

Последний код завершается с ошибкой.

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Thu, 01 Apr 2021 15:04:32 +0000

Да, это должно ускорить, надо поизучать.

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (Malcev) — Thu, 01 Apr 2021 14:40:20 +0000

В скорости поиска.
У IAccessible нет встроенных методов, а тут есть.
Например IUIAutomationElement::FindFirst.

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Thu, 01 Apr 2021 14:38:01 +0000

Так работает. А какое здесь преимущество перед IAccessible?

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (Malcev) — Thu, 01 Apr 2021 03:08:01 +0000

Можно так попробовать.

setbatchlines -1
IUIAutomation := ComObjCreate(CLSID_CUIAutomation := "{ff48dba4-60ef-4201-aa87-54103eef594e}", IID_IUIAutomation := "{30cbe57d-d9d0-452a-ab13-7ac5ac4825ee}")
oStates := [collapsed_focusable_haspopup := 0x40100400, expanded_focusable_haspopup := 0x40100200, focused_collapsed_focusable_haspopup := 0x40100404, focused_expanded_focusable_haspopup := 0x40100204]
SafeArray := ComObjArray(VT_UNKNOWN := 13, oStates.Count())
if (A_PtrSize = 4)
   SafeArrayConditions := ComObject(0x2000|3, ComObjValue(SafeArray), 1)
else
   SafeArrayConditions := ComObject(0x2000|0x14, ComObjValue(SafeArray), 1)
loop % oStates.Count()
{
   VarSetCapacity(variant, 8+A_PtrSize*2, 0)
   NumPut(VT_I4 := 3, variant, 0, "ushort")
   NumPut(oStates[A_Index], variant, 8, "int")
   if (A_PtrSize = 4)
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "int64", NumGet(variant, 0, "int64"), "int64", NumGet(variant, 8, "int64"), "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   else
      DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_LegacyIAccessibleStatePropertyId := 30096, "ptr", &variant, "ptr*", condition)   ; IUIAutomation::CreatePropertyCondition
   SafeArrayConditions[A_Index-1] := condition
}
DllCall(NumGet(NumGet(IUIAutomation+0)+29*A_PtrSize), "ptr", IUIAutomation, "ptr", ComObjValue(SafeArrayConditions), "ptr*", condition1)   ; IUIAutomation::CreateOrConditionFromArray
VarSetCapacity(variant, 8+A_PtrSize*2, 0)
NumPut(VT_I4 := 3, variant, 0, "ushort")
NumPut(UIA_EditControlTypeId := 50004, variant, 8, "int")
if (A_PtrSize = 4)
   DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_ControlTypePropertyId := 30003, "int64", NumGet(variant, 0, "int64"), "int64", NumGet(variant, 8, "int64"), "ptr*", condition2)   ; IUIAutomation::CreatePropertyCondition
else
   DllCall(NumGet(NumGet(IUIAutomation+0)+23*A_PtrSize), "ptr", IUIAutomation, "int", UIA_ControlTypePropertyId := 30003, "ptr", &variant, "ptr*", condition2)   ; IUIAutomation::CreatePropertyCondition
DllCall(NumGet(NumGet(IUIAutomation+0)+25*A_PtrSize), "ptr", IUIAutomation, "ptr", condition1, "ptr", condition2, "ptr*", conditions)   ; IUIAutomation::CreateAndCondition
ObjRelease(condition1)
ObjRelease(condition2)
loop % oStates.Count()
   ObjRelease(SafeArrayConditions[A_Index-1])
return

f11::
DllCall(NumGet(NumGet(IUIAutomation+0)+6*A_PtrSize), "ptr", IUIAutomation, "ptr", WinExist("A"), "ptr*", ElementFromHandle)   ; IUIAutomation::ElementFromHandle
DllCall(NumGet(NumGet(ElementFromHandle+0)+5*A_PtrSize), "ptr", ElementFromHandle, "int", TreeScope_Descendants := 0x4, "ptr", conditions, "ptr*", element) ; IUIAutomationElement::FindFirst
VarSetCapacity(variant, 8+A_PtrSize*2, 0)
DllCall(NumGet(NumGet(element+0)+10*A_PtrSize), "ptr", element, "int", UIA_ValueValuePropertyId := 30045, "ptr", &variant)   ; IUIAutomationElement::GetCurrentPropertyValue
ObjRelease(element)
ObjRelease(ElementFromHandle)
msgbox % StrGet(NumGet(variant, 8, "ptr"), "utf-16")
return

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Wed, 31 Mar 2021 21:29:22 +0000

А независимого от языка нет варианта?

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (Malcev) — Wed, 31 Mar 2021 21:23:52 +0000

Возможно дело в названии адресной строки.
У меня называется "Search with Google or enter address".

Re: AHK: Получение значения адресной строки в фаерфоксе через UIA

null@example.com (teadrinker) — Wed, 31 Mar 2021 21:16:57 +0000

Но у меня не срабатывает, сейчас на десятке проверяю.