Серый форум — AHK: Считывание клика мыши только в определенных координатах

Re: AHK: Считывание клика мыши только в определенных координатах

null@example.com (teadrinker) — Thu, 08 Dec 2022 21:36:44 +0000

will пишет:

но теперь сама кнопка не нажимается в игре

Темы по играм должны быть в соответствующей ветке, переношу. Если нужно, чтобы LButton в области сохраняла свою функцию, добавьте тильду к горячей клавише:

~LButton::

Re: AHK: Считывание клика мыши только в определенных координатах

null@example.com (will) — Thu, 08 Dec 2022 20:58:06 +0000

will пишет:

teadrinker
Спасибо большое. Оно нажимает и считывает действие, но теперь сама кнопка не нажимается в игре даже когда рисовал квадратик он не хотел рисоваться.
https://imgur.com/a/z7Zf2Zh

В общем: Просто добавил действие клик по координатам MouseGetPos.
Спасибо огромное!

Re: AHK: Считывание клика мыши только в определенных координатах

null@example.com (will) — Thu, 08 Dec 2022 20:48:37 +0000

teadrinker
Спасибо большое. Оно нажимает и считывает действие, но теперь сама кнопка не нажимается в игре даже когда рисовал квадратик он не хотел рисоваться.
https://imgur.com/a/z7Zf2Zh

Re: AHK: Считывание клика мыши только в определенных координатах

null@example.com (teadrinker) — Thu, 08 Dec 2022 17:51:05 +0000

Или так:

area1 := {left: 0, top: 0, right: 300, bottom: 300}
area2 := {left: A_ScreenWidth - 300, top: 0, right: A_ScreenWidth, bottom: 300}

#If area := MouseInArea(area1, area2)
LButton::
   Switch area {
      case 1:
         MsgBox, Действия для зоны №1
      case 2:
         MsgBox, Действия для зоны №2
   }
Return

MouseInArea(areas*) {
   CoordMode, Mouse
   MouseGetPos, x, y
   for k, area in areas {
      if (x >= area.left && x <= area.right && y >= area.top && y <= area.bottom)
         Return k
   }
}

Re: AHK: Считывание клика мыши только в определенных координатах

null@example.com (teadrinker) — Thu, 08 Dec 2022 17:45:28 +0000

Пример:

area1 := {left: 0, top: 0, right: 300, bottom: 300}
area2 := {left: A_ScreenWidth - 300, top: 0, right: A_ScreenWidth, bottom: 300}

#If area := MouseInArea(area1, area2)
LButton::
   if (area = 1) {
      MsgBox, Действия для зоны №1
   }
   if (area = 2) {
      MsgBox, Действия для зоны №2
   }
Return

MouseInArea(areas*) {
   CoordMode, Mouse
   MouseGetPos, x, y
   for k, area in areas {
      if (x >= area.left && x <= area.right && y >= area.top && y <= area.bottom)
         Return k
   }
}

Первая область — квадрат 300х300 в левом верхнем углу экрана, вторая — квадрат 300х300 в правом верхнем углу экрана.

AHK: Считывание клика мыши только в определенных координатах

null@example.com (will) — Thu, 08 Dec 2022 00:24:04 +0000

Всем доброго времени суток. Как сделать чтоб при действие выполнялось после того как вы нажмете ЛКМ в определенной зоне ?