Серый форум — AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

Re: AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-13T07:14:48Z

Qp
Спасибо, теперь я понял.

Re: AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-12T18:47:00Z

MycopOK пишет:

я не понимаю эту строчку

i := Mod(A_Index, bar)

Да правильно понимаете.

A_Index - номер итерации цикла, начиная с единицы.
Mod(делимое, делитель) возвращает остаток от деления. Поскольку числа целые, без плавающей точки, то остаток целочисленный. (Почему остаток от 1/3 и 2/3 равен 1 и 2, я не вникал.) Если разделилось без остатка, то возвращает ноль. Результат присваивается переменной i.

Выражение

if i

истинно, когда i не равно 0 - значит, есть остаток, и это количество раз печатаем |. Иначе остатка нет, значит, номер итерации цикла кратен переменной bar (в данном случае - 3), и нужно печатать | bar раз.

Re: AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-12T13:34:09Z

Может так лучше будет?

CoordMode, ToolTip, Screen

;Необходимый текст:
Text := "Outer Heaven ведёт набор, требования: 400 приведы для боевых, Био3-380 приведы, 3/4 онлайн на кв, Писать в ДС jlonji "
One := 0	; Запуск / Остановка через одну клавишу:  1: Включить, 0: Выключить.
Return


Numpad1::		; Запуск / Остановка спама.
KeyWait, % A_ThisHotkey, U	; Ожидать отжатия клавиши.
If (One = 1) && (SW > 0)	; Запрет на выключение.
 Return
ToolTip			; Выключить инфу.
SW := !SW, Bar := 0	; По умолчанию SW = 0 (Таймер выключен / отсчёта нет). Сброс 'Bar'.
SetTimer, Spammer, % (SW ? 1000 : "Off")
Return


Numpad2::	; Выключение спама.
SW := 0
ToolTip
SetTimer, Spammer, Off
Return

Spammer:
ToolTip, % M := Mod(SW++, 10), A_ScreenWidth, 0	; Отображение инфы.
If (M = 0){	; Каждое 10-е срабатывание:
 SendMessage, 0x50,, 0x4090409,, A	; Eng.
 B = |				; Добавочная строка.
 Loop, % Mod(Bar++, 3)
  B .= "|"			; Увел. кол-во.
 SendInput, {sc1C}	; Открыть чат.
 Sleep, 100
 SendInput, % Text B	; Напечатать текст +добавочный.
 SendInput, {Enter}
}
Return

Re: AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-12T12:09:04Z

Qp
Не очень понимаю.

if i
		Loop, %i%
			{
			SendInput, |
			}
	else
		Loop, %bar%
			{
			SendInput, |
			}

Если i
Повторить число i раз
Написать |
Иначе
Повторить число bar раз
Написать |

Вот так я это вижу, я так понимаю, это потому что я не понимаю эту строчку?

i := Mod(A_Index, bar)

Re: AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-12T08:01:13Z

Мне не давал покоя костыль с if-ами, переделал:

CoordMode, ToolTip, Screen
bar := 3
numpad1::
looping := true
SendMessage, 0x50,, 0x4090409,, A ; английская раскладка, так нужно!!!
while(looping = true)
	{
	SendInput, {sc1C}	; открыть чат
    Sleep, 100
    SendInput, Outer Heaven ведёт набор, требования: 400 приведы для боевых, Био3-380 приведы, 3/4 онлайн на кв, Писать в ДС jlonji{sc39}
	i := Mod(A_Index, bar)
	if i
		Loop, %i%
			{
			SendInput, |
			}
	else
		Loop, %bar%
			{
			SendInput, |
			}
	SendInput, {Enter}

	Loop, 10	; задержка 10 раз по 1 сек
		{
		sec := A_Index - 1	; прямой отсчёт 0, 1, 2... 9
	;	sec := 11 - A_Index	; обратный отсчёт 10, 9, 8... 1
		ToolTip, %sec%, 1920, 1	; координаты для разрешения 1920*1080
		Sleep, 1000
		}
    }
  return

numpad2::
  looping := false
  return

Re: AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-12T07:24:21Z

Qp
Да, спасибо за понятные описания и за то, что оптимизировали сам код.

Re: AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-12T06:45:08Z

Вы про это:

CoordMode, ToolTip, Screen
numpad1::
looping := true
SendMessage, 0x50,, 0x4090409,, A ; английская раскладка, так нужно!!!
while(looping = true)
	{
	if (Mod(A_Index, 3) = 1)
		bar := "|"
	else if (Mod(A_Index, 3) = 2)
		bar := "||"
	else if (Mod(A_Index, 3) = 0)
		bar := "|||"

	SendInput, {sc1C}	; открыть чат
    Sleep, 100
    SendInput, Outer Heaven ведёт набор, требования: 400 приведы для боевых, Био3-380 приведы, 3/4 онлайн на кв, Писать в ДС jlonji %bar%{Enter}

	Loop, 10	; задержка 10 раз по 1 сек
		{
		sec := A_Index - 1	; прямой отсчёт 0, 1, 2... 9
	;	sec := 11 - A_Index	; обратный отсчёт 10, 9, 8... 1
		ToolTip, %sec%, 1920, 1	; координаты для разрешения 1920*1080
		Sleep, 1000
		}
    }
  return

numpad2::
  looping := false
  return

AHK: Таймер с отсчётом в окне в определённой зоне поверх всех окон

2023-11-11T17:45:54Z

Необходим таймер на 10 секнунд, который был бы в правом верхнем углу, выскакивал бы поверх всех окон, не требовал бы закрывания для взаимодействия с другими окнами. Таймер нужен для этого скрипта:

numpad1::
looping := true
  while(looping = true)
    {
      SendMessage, 0x50,, 0x4090409,, A ; английская раскладка, так нужно!!!
      Send, {/} ; Нажать / и открыть чат, через Enter не робит
      Send, {Backspace} ; стереть /
      Sleep, 100
      SendInput, Outer Heaven ведёт набор, требования: 400 приведы для боевых, Био3-380 приведы, 3/4 онлайн на кв, Писать в ДС jlonji |{Enter}
      Sleep, 10000 ; задержка в 10 сек
      Send, {/} ; Нажать / и открыть чат, через Enter не робит
      Send, {Backspace} ; стереть /
      Sleep, 100
      SendInput, Outer Heaven ведёт набор, требования: 400 приведы для боевых, Био3-380 приведы, 3/4 онлайн на кв, Писать в ДС jlonji ||{Enter}
      Sleep, 10000 ; задержка в 10 сек
      Send, {/} ; Нажать / и открыть чат, через Enter не робит
      Send, {Backspace} ; стереть /
      Sleep, 100
      SendInput, Outer Heaven ведёт набор, требования: 400 приведы для боевых, Био3-380 приведы, 3/4 онлайн на кв, Писать в ДС jlonji |||{Enter}
      Sleep, 10000 ; задержка в 10 сек
    }
  return

numpad2::
  looping := false
  return