Серый форум — AHK v2: список сайтов из txt в json для Amnezia

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-13T15:03:25Z

haridev пишет:

Узнал про \V+, про "вертикальный пробел"

Если что, \V — это как раз всё, кроме вертикального пробела, вертикальный пробел это \v.

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-13T08:26:26Z

Отлично! Узнал про \V+, про "вертикальный пробел".
Добавил кавычки для имени сайта:

if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := SubStr(sites, 1, -3) . 'json'
try FileDelete sitesJson
i := '`s`s'
s := Trim(FileRead(sites, '`n'), '`n`t`s')
s := RegExReplace(s, '\V+', i . '{`n' . i . i . '"hostname": "$0"`n' . i . '},')
s := '[`n' . RTrim(s, ',') . '`n]'
FileAppend s, sitesJson

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-13T00:20:17Z

Проще так:

if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := SubStr(sites, 1, -3) . 'json'
try FileDelete sitesJson
i := '`s`s'
s := Trim(FileRead(sites, '`n'), '`n`t`s')
s := RegExReplace(s, '\V+', i . '{`n' . i . i . '"hostname": $0`n' . i . '},')
s := '[`n' . RTrim(s, ',') . '`n]'
FileAppend s, sitesJson

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-12T09:58:45Z

Так, примерно?

; список сайтов из txt в json для Amnezia
if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := SubStr(sites, 1, -3) . 'json'
try	FileDelete sitesJson
indent := '`s`s', indent2 := indent . indent
s := RTrim(FileRead(sites, '`n'), '`n`s`t')
s := RegExReplace(s, '`n', '"`n' . indent . '},`n' . indent . '{`n' . indent2 . '"hostname": "')
s := ('[`n' . indent . '{`n' . indent2 . '"hostname": "') . s . ('"`n' . indent . '}`n]')
FileAppend s, sitesJson
ExitApp

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-12T09:08:00Z

Не следует много действий упаковывать в одну строку. Такое трудно читать и невозможно отлаживать.

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-12T07:25:45Z

Так, наверно

; список сайтов из txt в json для Amnezia
if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := SubStr(sites, 1, -3) . 'json'
try	FileDelete sitesJson
indent := '`s`s', indent2 := indent . indent
FileAppend '[`n' . indent . '{`n' . indent2 . '"hostname": "' . RegExReplace(RTrim(FileRead(sites, '`n'), '`n`s`t'), '`n', '"`n' . indent . '},`n' . indent . '{`n' . indent2 . '"hostname": "') . '"`n' . indent . '}`n]', sitesJson
ExitApp

или так

; список сайтов из txt в json для Amnezia
if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := SubStr(sites, 1, -3) . 'json'
try	FileDelete sitesJson
indent := '`s`s', indent2 := indent . indent
FileAppend '[`n' . indent . '{`n' . indent2 . '"hostname": "'
. RegExReplace(RTrim(FileRead(sites, '`n'), '`n`s`t')
	, '`n', '"`n' . indent . '},`n' . indent . '{`n' . indent2 . '"hostname": "') . '"`n' . indent . '}`n]'
, sitesJson
ExitApp

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-11T22:39:06Z

Явных ошибок нет, но построчное чтение файла здесь не оптимально. Лучше считать весь текст сразу и сделать изменения через регулярку в один проход. Библиотека LightJson в данном случае не нужна.

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-11T22:16:10Z

Особо вопроса нет. Думал, может кто ошибки укажет или предложит лучший вариант.
Вот ещё вариант

; список сайтов из txt в json для Amnezia
#Include 
if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
json := ''
Loop Read sites
	json .= (A_Index = 1 ? '[' : ',') . '{"hostname":"' . A_LoopReadLine . '"}'
json .= ']'
sitesJson := SubStr(sites, 1, -3) . 'json'
try	FileDelete sitesJson
FileAppend LightJson.Beautify(json, '    '), sitesJson
ExitApp

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-11T21:31:46Z

А в чём вопрос-то?

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-11T20:43:58Z

ещё поправил

; список сайтов из txt в json для Amnezia
if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := SubStr(sites, 1, -3) . 'json'
indent1 := '`s`s', indent2 := indent1 . indent1
try	FileDelete sitesJson
Loop Read sites, sitesJson
	FileAppend (A_Index = 1 ? '[`n' : ',`n') . indent1 . '{`n' . indent2 . '"hostname": "' . A_LoopReadLine . '"`n' . indent1 . '}'
FileAppend '`n]', sitesJson
ExitApp

Re: AHK v2: список сайтов из txt в json для Amnezia

2026-02-11T17:21:50Z

Подправил

; список сайтов из txt в json для Amnezia
if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := SubStr(sites, 1, -3) . 'json'
indent1 := A_Space . A_Space
indent2 := indent1 . indent1
if FileExist(sitesJson)
	FileDelete sitesJson
Loop Read sites, sitesJson
	FileAppend (A_Index = 1 ? '[`n' : ',`n') . indent1 . '{`n' . indent2 . '"hostname": "' . A_LoopReadLine . '"`n' . indent1 . '}'
FileAppend '`n]', sitesJson
ExitApp

AHK v2: список сайтов из txt в json для Amnezia

2026-02-11T15:31:21Z

; список сайтов из txt в json для Amnezia
if !sites := FileSelect(1,, 'Список сайтов', 'Documents (*.txt)')
	ExitApp
sitesJson := StrReplace(sites, '.txt', '.json',, &OutputVarCount)
if OutputVarCount != 1 {
	MsgBox 'Недопустимое имя входного файла'
	ExitApp
}
indent1 := A_Space . A_Space
indent2 := indent1 . indent1
FileDelete sitesJson
Loop Read sites, sitesJson
	FileAppend (A_Index = 1 ? '[`n' : ',`n') . indent1 . '{`n' . indent2 . '"hostname": "' . A_LoopReadLine . '"`n' . indent1 . '}'
FileAppend '`n]', sitesJson
ExitApp

Для замечаний.