Серый форум — CMD/BAT: патчер бинарных файлов

Re: CMD/BAT: патчер бинарных файлов

null@example.com (jite) — Sun, 14 Nov 2010 14:44:21 +0000

а) Как работает скрипт, написано в нем самом, в разделе :HELP. Скрипт специфичный. Вероятно те, кому он действительно нужен, без труда в нем разберутся.

б) Если же вам нужен просто патчер, то рекомендую воспользоваться xdelta.
Сделать файл различий diff между ver1.txt и ver2.txt

xdelta3.0t.x86-32.exe -f -e -s ver1.txt ver2.txt diff

После этого можно из ver1.txt и diff всегда сделать ver2.txt:

xdelta3.0t.x86-32.exe -f -d -s ver1.txt diff ver2.txt

Например, экономней скачать образ CD.iso и diff для превращения его в DVD.iso (CD.iso + доп. материалы), чем качать и то и другое.

upd
в) Ах, да, может быть я все усложняю, и вам просто нужно поправить в файле пару байт по известному смещению. Тогда вам нужен шестнадцатиричный редактор.

Re: CMD/BAT: патчер бинарных файлов

null@example.com (rapbit89) — Sun, 14 Nov 2010 10:15:25 +0000

Может кто-нибудь обьяснить как пользоваться этим скриптом??? создал pat4.bat и pat4.reg, скопировал батник в C:\windows внёс изменения в регистр, а дальше что?? открываю двоичный файл и всё так же...

Re: CMD/BAT: патчер бинарных файлов

null@example.com (kiber_punk) — Sun, 05 Apr 2009 09:08:09 +0000

UpDate
Ну вроде закончил. Pat4_v3
Подчистил лишние переходы, упаковал всё в удобную инсталляшку

Re: CMD/BAT: патчер бинарных файлов

null@example.com (kiber_punk) — Thu, 19 Mar 2009 11:27:20 +0000

Бета-Тест Чувствую что ещё что-то можно оптимизировать.

Re: CMD/BAT: патчер бинарных файлов

null@example.com (-red-) — Thu, 19 Mar 2009 07:51:35 +0000

Что в коллекцию то последнюю версию не отправил?

Re: CMD/BAT: патчер бинарных файлов

null@example.com (kiber_punk) — Tue, 10 Mar 2009 09:02:09 +0000

Спасибо
Очень интересные трюки на ресурсе по ссылке.
Теперь скрипт работает заметно быстрее.
__
UpDate

:: patcher v 2.1 by kiber_punk 
@echo off
CHCP 1251>nul
set a=
set data=
set ext=
if "%~1"=="/?" (GOTO HELP)
if "%~1"=="" (GOTO file)

set newname=%~s1
::ИМЕЕМ КОРОТКОЕ ИМЯ
:new
if "%2"=="" (GOTO address)
if "%3"=="" (GOTO byte)
if not "%3"=="" (GOTO go)

::ВВОД АДРЕСА
:address
set /p a=Offset address, default - BOF(00h):  
if "%a%"=="" (set a=00)
::ВВОД БАЙТА
:byte
set /p data=Input byte for include, default ^<00^>:  
if "%data%"=="" (set data=00)

:go
::переименовать чтобы исключить все возможные ошибки
ren %1 "~tmp.bin"
::задаём короткое имя в формате DOS
call :short "%~dp1~tmp.bin"
CALL :WORK "%newname%" %2 %a% %data% %3 %4 %5 %6 %7 %8 %9
::обратное переименование
ren "%~dp1~tmp.bin" "%~nx1"

::вывод информации
echo ...
echo Filename:    %~nx1
echo Address: %2 %a%
echo Byte:    %data% %3 %4 %5 %6 %7 %8 %9
echo ...
echo Press AnyKey...
pause>nul
exit 

::ИНТЕРАКТИВНОЕ ЗАДАНИЕ ИМЕНИ
:file
set /p file=Enter filename:  
if not exist %file% (Echo File not found!&goto file)
CALL :new %file%
exit /b

::РАБОЧАЯ ЧАСТЬ
:WORK
call :HEX %2
set pat4=%TMP%\patch.dbg
rem =================================
echo e %offset% %3 %4 %5 %6 %7 %8 %9>%pat4%
echo  %3 %4 %5 %6 %7 %8 %9>>%pat4%
echo w>>%pat4%
echo q>>%pat4%
rem =================================
chcp 866>nul
debug %~1 <%pat4%>nul
exit /b
::СПРАВКА
:HELP
    echo Used command line:  pat4 [^ [address [bytes]]] [/?]
    echo ...
    echo ^    - файл для обработки
    echo ^ - адрес смещения для внедряемых байтов ^(HEX^)
    echo ^    - байт^(ы^)  и(или) строки разделенные через пробел.
    echo           строки заключаются в одинарные кавычки.
    echo           Между байтом и строкой пробел необязателен: 04 20'string' 20 
    echo ..
    echo   Пример:
    echo ^ - записывает в начало файла
    echo                             последовательность байтов 01,02,3c
    echo ^       - записывает байт 07 по адресу 3C&echo ..
exit /b

:short
set newname=%~s1
exit /b

rem ==Преобразование адреса==
:HEX
setlocal enableextensions enabledelayedexpansion
    SET Adr=%1
    set /a plus100 = 0x%Adr% + 0x100
    call :Dec2HEX !plus100! Adr    
endlocal&set offset=%Hexstr%

exit /b 0
:Dec2HEX 
set /a Dec = %1
set HexString=
:Repeat
set /a Index = Dec %% 16 + 1
set /a     Dec  = Dec / 16

for /f "tokens=%Index%" %%h in ("0 1 2 3 4 5 6 7 8 9 A B C D E F") do (set HexString=%%h%HexString%)
if %Dec% GTR 0 goto :Repeat
set Hexstr=%HexString%

__
(ой, забыл раскомментировать вторую строку )

Re: CMD/BAT: патчер бинарных файлов

null@example.com (-red-) — Tue, 10 Mar 2009 06:39:56 +0000

OFF:

kiber_punk пишет:

как ты получаешь через этот код ну например число 3c?

Вот я лох то.
ЗЫ: Нехочешь перемигиваться - так и написал бы сразу что код не корректен, я ж тебе идею подать хотел и судя по всему подал (:

Re: CMD/BAT: патчер бинарных файлов

null@example.com (alexii) — Fri, 06 Mar 2009 20:27:25 +0000

2kiber_punk: а эту функцию можно использовать для добавления 0x100?

@echo off
setlocal enableextensions enabledelayedexpansion

set /a Decimal = 511
call :DecimalToHex %Decimal% Hex
echo Decimal [%Decimal%] == Hex [%Hex%]

endlocal
exit /b 0

rem ===============================================================
:DecimalToHex DecimalValueIn HexStringOut
rem ===============================================================
    setlocal enableextensions enabledelayedexpansion

    set /a DecimalValue = %1
    set HexString=
    
:Repeat
    set /a Index         = DecimalValue %% 16 + 1
    set /a DecimalValue  = DecimalValue / 16

    for /f "tokens=%Index%" %%h in ("0 1 2 3 4 5 6 7 8 9 A B C D E F") do set HexString=%%h%HexString%
    
    if %DecimalValue% GTR 0 goto :Repeat
    
    endlocal & set %2=%HexString%
exit /b 0
rem ===============================================================

Наподобие такого (на примере «set /p…» из оригинального скрипта):

@echo off
setlocal enableextensions enabledelayedexpansion

set /p Adress=Enter offset address, default - begin file: 
if "%Adress%"=="" (
    set Adress=100
) else (
    set /a DecimalAdress = 0x!Adress! + 0x100
    call :DecimalToHex !DecimalAdress! Adress
    rem echo Here Adress in hex = !Adress!
)
echo HexAdress [%Adress%]

endlocal
exit /b 0

rem ===============================================================
:DecimalToHex DecimalValueIn HexStringOut
rem ===============================================================
    setlocal enableextensions enabledelayedexpansion

    set /a DecimalValue = %1
    set HexString=
    
:Repeat
    set /a Index         = DecimalValue %% 16 + 1
    set /a DecimalValue  = DecimalValue / 16

    for /f "tokens=%Index%" %%h in ("0 1 2 3 4 5 6 7 8 9 A B C D E F") do set HexString=%%h%HexString%
    
    if %DecimalValue% GTR 0 goto :Repeat
    
    endlocal & set %2=%HexString%
exit /b 0
rem ===============================================================

alexii, извиняюсь, впредь больше такого не повторится

Ну, что Вы, это была просто просьба .

OFF: сделано на основе TSCMD032 FAQ: How can I convert a decimal number to binary, octal, hexadecimal? Assorted NT/2000/XP/.. CMD.EXE script tricks written by Timo Salmi. Много там, конечно, совершенно лишнего — я многое убрал, но вот использование:

call :LabelName %ArgIn% ArgOut

для вызова функции «:LabelName» и возврат значения «Variable» в вызывающий скрипт через параметры в виде:

endlocal & set %2=%Variable%

я встретил впервые. Самое интересное, что это работает. Как говорится, chapeau!

Re: CMD/BAT: патчер бинарных файлов

null@example.com (kiber_punk) — Fri, 06 Mar 2009 17:37:36 +0000

UpDate.
Ввод реального адреса смещения (без необходимости предварительного суммирования с 100h) и костылей в виде временных файлов.
Небольшие добавления в справке (инклуд строки).

:: patcher v 2.0.1 by kiber_punk 
@echo off
CHCP 1251>nul
set a=
set data=
set ext=

if "%~1"=="/?" (GOTO HELP)
if "%~1"=="" (GOTO file)

set newname=%~s1

::ИМЕЕМ КОРОТКОЕ ИМЯ
:new
if "%2"=="" (GOTO address)
if "%3"=="" (GOTO byte)
if not "%3"=="" (GOTO go)

::ВВОД АДРЕСА
:address
set /p a=Offset address, default - BOF(00h):  
if "%a%"=="" (set a=00)
::ВВОД БАЙТА
:byte
set /p data=Input byte for include, default ^<00^>:  
if "%data%"=="" (set data=00)

:go
::переименовать чтобы исключить все возможные ошибки
ren %1 "tmp.bin"
::задаём короткое имя в формате DOS
call :short "%~dp1tmp.bin"

CALL :WORK "%newname%" %2 %a% %data% %3 %4 %5 %6 %7 %8 %9

::обратное переименование
ren "%~dp1tmp.bin" "%~nx1"

::вывод информации
echo ...
echo Filename:    %~nx1
echo Address: %2 %a%
echo Byte:    %data% %3 %4 %5 %6 %7 %8 %9
echo ...
echo Press AnyKey...
pause>nul
exit /b

::ИНТЕРАКТИВНОЕ ЗАДАНИЕ ИМЕНИ
:file
set /p file=Enter filename:  
if not exist %file% (Echo File not found&goto file)
CALL :new %file%
exit /b

::РАБОЧАЯ ЧАСТЬ
:WORK
call mshta "javascript:var s=((parseInt(0x100))+(parseInt(0x%2)));function toHex(s){  return (enHex((0xf000 & s) >> 12) + enHex((0x0f00 & s) >>  8) + enHex((0x00f0 & s) >>  4) + enHex((0x000f & s) >>  0)) } ;function enHex(aDigit){  return("0123456789ABCDEF".substring(aDigit, aDigit+1))};new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(('E ')+((toHex(s))));close();" >patch.dbg
echo  %3 %4 %5 %6 %7 %8 %9>>patch.dbg
echo w>>patch.dbg
echo q>>patch.dbg
chcp 866>nul
debug %~1 < patch.dbg >nul
del patch.dbg
exit /b
::СПРАВКА
:HELP
    echo Used command line:  pat4 [^ [address [bytes]]] [/?]
    echo ...
    echo ^    - файл для обработки
    echo ^ - адрес смещения для ввода байтов ^(HEX^)
    echo ^    - байт^(ы^)  и(или) строки разделенные через пробел.
    echo           Между байтом и строкой пробел необязателен: 04 20'string' 20 
    echo ..
    echo   Пример:
    echo ^ - записывает в начало файла
    echo                             последовательность байтов 01,02,3c
    echo ^       - записывает байт 07 по адресу 3C&echo ..
exit /b

:short
set newname=%~s1

Код HEX-преобразования заимствован отсюда

Re: CMD/BAT: патчер бинарных файлов

null@example.com (kiber_punk) — Fri, 06 Mar 2009 14:57:49 +0000

-red- пишет:

Сразу видно что примерчик ты не запускал
ЗЫ: Костыли - это прибавлять 0х100 к требуему смещению

Мда..Клиника? (:
Примерчик то твой я пробывал, и немного запутался.. вот скажи, как ты получаешь через этот код ну например число 3c?
OFF: да и, давай не будем играть в перелядки-подмигивалки

Re: CMD/BAT: патчер бинарных файлов

null@example.com (kiber_punk) — Fri, 06 Mar 2009 14:20:05 +0000

alexii, извиняюсь, впреть больше такого не повторится

Re: CMD/BAT: патчер бинарных файлов

null@example.com (-red-) — Fri, 06 Mar 2009 05:27:47 +0000

kiber_punk пишет:

И? Это тоже самое что и SET /a. Функция parseInt возвращает число в десятичном формате, а нужен hex.

Сразу видно что примерчик ты не запускал
ЗЫ: Костыли - это прибавлять 0х100 к требуему смещению

Re: CMD/BAT: патчер бинарных файлов

null@example.com (alexii) — Fri, 06 Mar 2009 03:29:13 +0000

OFF: 2kiber_punk: прошу, при помещении чего-либо в Коллекцию, делать из ссылку из обсуждения на неё, например, так. Это облегчает жизнь.

Re: CMD/BAT: патчер бинарных файлов

null@example.com (kiber_punk) — Fri, 06 Mar 2009 00:04:50 +0000

-red- пишет:

А если прикрутить примерчик:
echo WScript.Quit( (parseInt(%1,16)+0x100).toString(16) ) > test.js
cscript //B //Nologo test.js
echo %ERRORLEVEL%
del test.js
kiber_punk, по крайней мере это не противоречит твоей подписи

И? Это тоже самое что и SET /a. Функция parseInt возвращает число в десятичном формате, а нужен hex.

Можно проделать трюк с vbs-функцией hex(), но это всё костыли.

Re: CMD/BAT: патчер бинарных файлов

null@example.com (The gray Cardinal) — Thu, 05 Mar 2009 09:34:44 +0000

kiber_punk пишет:

Пример с ярлыком тудаже или не стоит?

Пример с ярлыком там точно не помешает, спасибо.