Серый форум — VBS: Определить размеры рабочего стола

Re: VBS: Определить размеры рабочего стола

2016-02-27T13:20:54Z

For Each I In GetObject("winmgmts:\\.\root\CIMV2").ExecQuery("SELECT ScreenWidth FROM Win32_DesktopMonitor") 
	With CreateObject("WScript.Shell")
    	If I.ScreenWidth < 1024 Then .Run "notepad" Else .Run "wordpad"
	End With 
Next

Re: VBS: Определить размеры рабочего стола

2016-02-27T13:08:55Z

DenisArK пишет:

Размер всего экрана можно определить так:

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_DesktopMonitor")
DeskHight = 0
DeskWidth = 0
For Each objItem in colItems
DeskHight = objItem.ScreenHeight
DeskWidth = objItem.ScreenWidth
Next

ВысотаНужнойЗоны= DeskHight - ВысотаПанелиЗадач

что нужно добавить в сей скрипт, чтобы в зависимости от разрешения экрана, запускались два разных приложения. В частности при разрешении менее 1024x768 запускалось одно, при равном или большем разрешении запускалось второе?

Re: VBS: Определить размеры рабочего стола

2010-11-17T14:04:19Z

без понятия, на моем компе что то странное творится....

Re: VBS: Определить размеры рабочего стола

2010-11-17T06:41:23Z

DenisArK, а что ж было?

Re: VBS: Определить размеры рабочего стола

2010-11-17T06:17:15Z

на других компах тоже все нормально
это мои локальные проблемы

Всем спасибо, очень помогли!

Re: VBS: Определить размеры рабочего стола

2010-11-16T15:45:56Z

У меня нормально; одинаково — сверху панель задач или снизу. Windows XP, пробовались темы классическая/Windows XP.

Option Explicit

Dim objHTMLDocument


Set objHTMLDocument = WScript.CreateObject("htmlfile")

With objHTMLDocument.parentWindow.screen
    WScript.Echo "Разрешение:        " & .width & "x" & .height
    WScript.Echo "Доступная область: " & .availWidth & "x" & .availHeight
End With

Set objHTMLDocument = Nothing

WScript.Quit 0

Разрешение:        1024x768
Доступная область: 1024x715

Re: VBS: Определить размеры рабочего стола

2010-11-16T15:20:47Z

Спасибо за ответы!
Попробовал.
Если панель задач внизу, скрипт дает размер зоны больше, чем в действительности, например,
.availHeight = 996, а в действительности примерно 974
в чем может быть проблема?

Re: VBS: Определить размеры рабочего стола

2010-07-06T08:14:59Z

Точно! Я забыл про него.

Re: VBS: Определить размеры рабочего стола

2010-07-06T07:42:32Z

Я бы порекомендовал вот так. Всё таки создание htmlfile меньше нагружает проц, чем создание целого IE.

Dim document, info
set document = CreateObject("htmlfile")
With document.parentWindow.screen
    info = "Разрешение:" & .width & "/" & .height & vbCrlf
    info = info & "Доступная область:" & .availWidth & "/" & .availHeight
    MsgBox info
End With

Re: VBS: Определить размеры рабочего стола

2010-07-04T16:12:03Z

я думал задача не решима...
однако...

Re: VBS: Определить размеры рабочего стола

2010-07-04T15:55:48Z

DenisArK пишет:

…как определить либо размер самой зоны…

Option Explicit

With WScript.CreateObject("InternetExplorer.Application")
    .Navigate "about:blank"
    
    Do
        WScript.Sleep 100
    Loop While .Busy
    
    With .Document.Script.Screen
        WScript.Echo .availWidth
        WScript.Echo .availHeight
    End With
    
    .Quit
End With

WScript.Quit 0

Re: VBS: Определить размеры рабочего стола

2010-07-02T09:47:10Z

DenisArK, на всякий случай замечу, что панель задач может располагаться и сбоку.

VBS: Определить размеры рабочего стола

2010-07-01T12:33:19Z

Добрый день!

Необходимо получить размеры зоны рабочего стола без панели задач.

Размер всего экрана можно определить так:

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_DesktopMonitor")
DeskHight = 0
DeskWidth = 0
For Each objItem in colItems
DeskHight = objItem.ScreenHeight
DeskWidth = objItem.ScreenWidth
Next

ВысотаНужнойЗоны= DeskHight - ВысотаПанелиЗадач

Используйте тэг «code»

Подскажите как определить либо размер самой зоны, либо как определить высоту панели задач?