Серый форум — VBS: Определить размеры рабочего стола

Re: VBS: Определить размеры рабочего стола

null@example.com (Flasher) — Sat, 27 Feb 2016 13:20:54 +0000

For Each I In GetObject("winmgmts:\\.\root\CIMV2").ExecQuery("SELECT ScreenWidth FROM Win32_DesktopMonitor") 
	With CreateObject("WScript.Shell")
    	If I.ScreenWidth < 1024 Then .Run "notepad" Else .Run "wordpad"
	End With 
Next

Re: VBS: Определить размеры рабочего стола

null@example.com (onatra) — Sat, 27 Feb 2016 13:08:55 +0000

DenisArK пишет:

Размер всего экрана можно определить так:

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_DesktopMonitor")
DeskHight = 0
DeskWidth = 0
For Each objItem in colItems
DeskHight = objItem.ScreenHeight
DeskWidth = objItem.ScreenWidth
Next

ВысотаНужнойЗоны= DeskHight - ВысотаПанелиЗадач

что нужно добавить в сей скрипт, чтобы в зависимости от разрешения экрана, запускались два разных приложения. В частности при разрешении менее 1024x768 запускалось одно, при равном или большем разрешении запускалось второе?

Re: VBS: Определить размеры рабочего стола

null@example.com (DenisArK) — Wed, 17 Nov 2010 14:04:19 +0000

без понятия, на моем компе что то странное творится....

Re: VBS: Определить размеры рабочего стола

null@example.com (alexii) — Wed, 17 Nov 2010 06:41:23 +0000

DenisArK, а что ж было?

Re: VBS: Определить размеры рабочего стола

null@example.com (DenisArK) — Wed, 17 Nov 2010 06:17:15 +0000

на других компах тоже все нормально
это мои локальные проблемы

Всем спасибо, очень помогли!

Re: VBS: Определить размеры рабочего стола

null@example.com (alexii) — Tue, 16 Nov 2010 15:45:56 +0000

У меня нормально; одинаково — сверху панель задач или снизу. Windows XP, пробовались темы классическая/Windows XP.

Option Explicit

Dim objHTMLDocument


Set objHTMLDocument = WScript.CreateObject("htmlfile")

With objHTMLDocument.parentWindow.screen
    WScript.Echo "Разрешение:        " & .width & "x" & .height
    WScript.Echo "Доступная область: " & .availWidth & "x" & .availHeight
End With

Set objHTMLDocument = Nothing

WScript.Quit 0

Разрешение:        1024x768
Доступная область: 1024x715

Re: VBS: Определить размеры рабочего стола

null@example.com (DenisArK) — Tue, 16 Nov 2010 15:20:47 +0000

Спасибо за ответы!
Попробовал.
Если панель задач внизу, скрипт дает размер зоны больше, чем в действительности, например,
.availHeight = 996, а в действительности примерно 974
в чем может быть проблема?

Re: VBS: Определить размеры рабочего стола

null@example.com (alexii) — Tue, 06 Jul 2010 08:14:59 +0000

Точно! Я забыл про него.

Re: VBS: Определить размеры рабочего стола

null@example.com (Xameleon) — Tue, 06 Jul 2010 07:42:32 +0000

Я бы порекомендовал вот так. Всё таки создание htmlfile меньше нагружает проц, чем создание целого IE.

Dim document, info
set document = CreateObject("htmlfile")
With document.parentWindow.screen
    info = "Разрешение:" & .width & "/" & .height & vbCrlf
    info = info & "Доступная область:" & .availWidth & "/" & .availHeight
    MsgBox info
End With

Re: VBS: Определить размеры рабочего стола

null@example.com (Евген) — Sun, 04 Jul 2010 16:12:03 +0000

я думал задача не решима...
однако...

Re: VBS: Определить размеры рабочего стола

null@example.com (alexii) — Sun, 04 Jul 2010 15:55:48 +0000

DenisArK пишет:

…как определить либо размер самой зоны…

Option Explicit

With WScript.CreateObject("InternetExplorer.Application")
    .Navigate "about:blank"
    
    Do
        WScript.Sleep 100
    Loop While .Busy
    
    With .Document.Script.Screen
        WScript.Echo .availWidth
        WScript.Echo .availHeight
    End With
    
    .Quit
End With

WScript.Quit 0

Re: VBS: Определить размеры рабочего стола

null@example.com (Dmitrii) — Fri, 02 Jul 2010 09:47:10 +0000

DenisArK, на всякий случай замечу, что панель задач может располагаться и сбоку.

VBS: Определить размеры рабочего стола

null@example.com (DenisArK) — Thu, 01 Jul 2010 12:33:19 +0000

Добрый день!

Необходимо получить размеры зоны рабочего стола без панели задач.

Размер всего экрана можно определить так:

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_DesktopMonitor")
DeskHight = 0
DeskWidth = 0
For Each objItem in colItems
DeskHight = objItem.ScreenHeight
DeskWidth = objItem.ScreenWidth
Next

ВысотаНужнойЗоны= DeskHight - ВысотаПанелиЗадач

Используйте тэг «code»

Подскажите как определить либо размер самой зоны, либо как определить высоту панели задач?