+ и страждущим стдоут в скобках не всегда тот же, что за скобками

Согласен, и stderr тоже. Впрчем, это (для stdout) уже видно из

(pause>con)>tmp.txt

в примере со stderr скобки тоже стоят на своих местах, если убрать лишние останется

(echo 123>tmp.txt) 2>nul || echo Ошибка!

так что не ясно, о чём замечание.

О чём разговор?

(echo 123)>tmp.txt

очевидно, во втором случае, до момента «echo Ошибка!» всё то же самое, к тому же errorlevel представляет интерес именно в первом случае, во втором наличие ошибки обнаруживается и без него
(впрочем, скобки вокруг echo 123 в обоих случаях лишние, но без них всё то же самое).

echo %errorlevel%

Сейчас проверил для SET /P из несуществуещего файла — тоже 0, хотя, кажется, раньше был 1, может я что-то путаю или неправильно делаю.

(я просто не расписывал ветвь Else с сообщением об ошибке)

Кроме несуществования файла, возможны и другие ошибки при попытке доступа к нему, к тому же он может быть удалён другой программой сразу же после проверки его существования.
Поэтому, может быть, лучше проверять наличие ошибки после попытки выполнить действие:

((try)<file.txt) 2>nul
if errorlevel 1 (catch)

или

((try)<file.txt) 2>nul || (catch)

— второй способ мне представляется предпочтительнее, т.к. им обрабываются ошибки, при которых errorlevel равен 0.

В качестве примера такой ошибки (других я, правда, и не знаю) могу назвать попытку повторно открыть для записи файл.
Вот как её можно воспроизвести:
запускаем командную строку в двух окнах с одинаковым рабочим каталогом,
в одном выполняем команду

(pause>con)>tmp.txt

и не выходим из паузы,
пытаемся во втором окне выполнить

(echo 123)>tmp.txt

и получаем в ответ:

errorlevel при этом будет равен 0, так что по нему о существовании ошибки узнать нельзя.
Тем не менее второй подход

((echo 123)>tmp.txt) 2>nul || echo Ошибка!

ошибку видит.

Разве это

if exist "%sFile%" <"%sFile%" (
  set /p sUser=
  set /p sPass=
)

не работает?!

Это как раз работает. Очевидно, дело в том, что в данном случае ввод осуществляется как групповая операция. Мне почему-то ранее не приходило в голову испробовать такой подход. Будем знать.

Подавить-то можно. Но не следует (я просто не расписывал ветвь Else с сообщением об ошибке).

А как сделать так чтобы, содержимое первой строки передавалось переменной %sUser% а вторая строка в %sLogin%

Разве это

if exist "%sFile%" <"%sFile%" (
  set /p sUser=
  set /p sPass=
)

не работает?!

Насколько я могу судить, при перенапралении на вход файла, SET /P всё-таки позволяет читать последовательно строки. Другое дело, что при неизвестном числе строк не удасться узнать, достигнут ли конец файла. (Также трудности с чтением файла с помощью SET /P у меня возникали при переключении кодировок.)

Другое дело — перенаправление на вход SET /P вывода другой программы или команды. В этом случае возникают две трудности (наряду с тем, что нельзя определить, достигнут ли конец потока):

1) команда SET /P или содержащие ее составная команда или командный файл запускаются в новом процессе CMD.EXE с ключом /C, по отрабатыванию которого прочитанные строки теряются; но это еще не беда, главное — об этом помнить;

2) при достижении команды SET /P из всех успевших поступить на вход строк считывается самая первая — остальные теряются. Таким образом, гарантированно будет получена только первая строка из потока; может быть, удасться поймать невпопад ещё несколько, если только между выводами строк нет достаточной временной задержки.

User Name
My password

@echo off
setlocal

set sFile=0001.txt
set sTempFile=TempFile.tmp

if exist "%sFile%" (
    <"%sFile%" set /p sUser=>nul
    more +1 "%sFile%">"%sTempFile%"
    <"%sTempFile%" set /p sPass=>nul
    del "%sTempFile%"
)
if defined sUser echo %sUser%
if defined sPass echo %sPass%

endlocal
exit /b 0

Можно делать разбор,  по приведённому примеру — тоже не слишком красивый, например так:

@echo off
setlocal

set sFile=0001.txt

if exist "%sFile%" (
    for /f "usebackq delims=" %%i in ("%sFile%") do set sUser=%%i& goto :Skip
:Skip
    for /f "usebackq skip=1 delims=" %%i in ("%sFile%") do set sPass=%%i
)

if defined sUser echo %sUser%
if defined sPass echo %sPass%

endlocal
exit /b 0

Тут уж лучше сделать текстовый файл a-la *.ini, наподобие:
0001.txt

; My user name & password
user=User Name
password=My password

и пакетный файл к нему:

@echo off
setlocal

set sFile=0001.txt

if exist "%sFile%" (
    for /f "usebackq tokens=1,2 eol=; delims==" %%i in ("%sFile%") do set %%i=%%j
)

if defined User echo %User%
if defined Password echo %Password%

endlocal
exit /b 0