Оболочка программы не нужна.
Необходимо с помощью скрипта:
1. Запустить конкретную программу (aaa.exe).
2. Получить ее ID.
3. Приостановить/поставить на паузу процесс.
4. Возобновить.
Увы, у меня не запустился скрипт: указывает на ошибку в строке 142.
Либо используйте AutoHotkey_L, либо напишите свою функцию StrGet, которая конвертирует null-terminate строку в формат ahk.
Оболочка программы не нужна.
Ну дык убери её //_-.
1. Запустить конкретную программу (aaa.exe).
2. Получить ее ID.
Пример использования функции Run был ранее в этой теме.
3. Приостановить/поставить на паузу процесс.
См. функцию Stop.
4. Возобновить.
См. функцию Start. Только вместо
ret := ResumeThread(hThread)нужно составить цикл, выполняющийся пока ret>1.
]]>
Оболочка программы не нужна.
Необходимо с помощью скрипта:
1. Запустить конкретную программу (aaa.exe).
2. Получить ее ID.
3. Приостановить/поставить на паузу процесс.
4. Возобновить.
Мне не понятно как поставить программу на паузу (вернее будет - приостановить/запустить потоки).
Пример программы на AHK:
Unicode := A_IsUnicode ? "W" : ""
TH32CS_SNAPPROCESS := 0x00000002
TH32CS_SNAPTHREAD := 0x00000004
CreateToolhelp32Snapshot(Flags, th32ProcessID)
{
return DllCall("CreateToolhelp32Snapshot", "int", Flags, "int", th32ProcessID)
}
Process32First(hSnapshot, pe)
{
global Unicode
return DllCall("Process32First" . Unicode, "int", hSnapshot, "int", pe)
}
Process32Next(hSnapshot, pe)
{
global Unicode
return DllCall("Process32Next" . Unicode, "int", hSnapshot, "int", pe)
}
Thread32First(hSnapshot, te)
{
return DllCall("Thread32First", "int", hSnapshot, "int", te)
}
Thread32Next(hSnapshot, te)
{
return DllCall("Thread32Next", "int", hSnapshot, "int", te)
}
THREAD_SUSPEND_RESUME := 0x0002
OpenThread(DesiredAccess, InheritHandle, ThreadId)
{
return DllCall("OpenThread" , "int", DesiredAccess, "int", InheritHandle, "int", ThreadId)
}
SuspendThread(hThread)
{
return DllCall("SuspendThread", "int", hThread)
}
ResumeThread(hThread)
{
return DllCall("ResumeThread", "int", hThread)
}
CloseHandle(Handle)
{
return DllCall("CloseHandle", "int", Handle)
}
Gui Add, Button, x10 y5 w75 gL_Update, Обновить
Gui Add, Button, x100 y5 w75 gL_Stop, Stop
Gui Add, Button, x200 y5 w75 gL_Start, Start
Gui Add, ListView, x10 y35 r20 w450 -Multi, PID|имя процесса|статус
LV_ModifyCol(1, 50)
LV_ModifyCol(2, 300)
LV_ModifyCol(3, 50)
Update()
Gui Show
return
L_Update:
Update()
return
L_Stop:
Stop()
return
L_Start:
Start()
return
Start()
{
global TH32CS_SNAPTHREAD, THREAD_SUSPEND_RESUME
row := LV_GetNext(0, "Focused")
LV_GetText(id, row)
hSnapshot := CreateToolhelp32Snapshot(TH32CS_SNAPTHREAD, id)
VarSetCapacity(te, 28)
NumPut(28, te, 0)
str := ""
test := Thread32First(hSnapshot, &te)
while test
{
if (id=NumGet(te, 12))
{
hThread := OpenThread(THREAD_SUSPEND_RESUME, 0, NumGet(te, 8))
if (hThread=0)
{
LV_Modify(row, "Col3" , "-1 (" . a_lasterror . ")")
CloseHandle(hSnapshot)
return
}
ret := ResumeThread(hThread)
CloseHandle(hThread)
}
test := Thread32Next(hSnapshot, &te)
}
CloseHandle(hSnapshot)
LV_Modify(row, "Col3" , ret=0 ? 0 : ret-1)
}
Stop()
{
global TH32CS_SNAPTHREAD, THREAD_SUSPEND_RESUME
row := LV_GetNext(0, "Focused")
LV_GetText(id, row)
hSnapshot := CreateToolhelp32Snapshot(TH32CS_SNAPTHREAD, id)
VarSetCapacity(te, 28)
NumPut(28, te, 0)
test := Thread32First(hSnapshot, &te)
while test
{
if (id=NumGet(te, 12))
{
hThread := OpenThread(THREAD_SUSPEND_RESUME, 0, NumGet(te, 8))
if (hThread=0)
{
LV_Modify(row, "Col3" , "-1 (" . a_lasterror . ")")
CloseHandle(hSnapshot)
return
}
ret := SuspendThread(hThread)
CloseHandle(hThread)
}
test := Thread32Next(hSnapshot, &te)
}
CloseHandle(hSnapshot)
LV_Modify(row, "Col3" , ret+1)
}
Update()
{
global TH32CS_SNAPPROCESS
LV_Delete()
hSnapshot := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0)
pesize := A_IsUnicode ? 556 : 296
VarSetCapacity(pe, pesize)
NumPut(pesize, pe, 0)
test := Process32First(hSnapshot, &pe)
while test
{
LV_Add("", NumGet(pe,8), StrGet(&pe+36),"?")
test := Process32Next(hSnapshot, &pe)
}
CloseHandle(hSnapshot)
}
GuiClose:
ExitApp
returnВ первом столбце PID процесса, во втором имя модуля и в третьем счётчик остановок. Если счётчик равен нулю, то процесс запущен, в противном случае он приостановлен. Изначально третий столбец не заполнен, т.к. я не знаю как получить значение счётчика не запуская/останавливая потоки. Если значение в третьем столбце равно -1, значит не удалось получить доступ к процессу, в скобках будет указан код ошибки(обычно 5, из-за нехватки прав). Остановка своего процесса не предусмотрена, хотя в принципе возможна.
В самой программе функция Update обновляет список процессов, Start уменьшает значение счётчика остановок на единицу, а Stop увеличивает его(счётчик всегда больше или равен нулю).
F1:: run notepad.exe,,,OutputVarPID
F2:: run pausep.exe %OutputVarPID% ,,hide
F3:: run pausep.exe %OutputVarPID% /r ,,hideКоличество нажатий f2 д.б. равно количеству нажатий f3.
]]>F1::Run, uTorrent.exe, C:\Program Files (x86)\uTorrent,, uTorrentID ; запуск программы
F2::Process, Close, %uTorrentID% ; закроет программу, а мне надо приостановить...Но, меня интересовала возможность сделать это посредством AHK.
Что именно не ясно- как получить список потоков или как останавливать/запускать потоки?
]]>pausep.exe — на WinXP работает.
Во многих программах реализована эта функция.
Но, меня интересовала возможность сделать это посредством AHK.
.]]>