Серый форум — CMD/BAT: Нахождение длины строки

Re: CMD/BAT: Нахождение длины строки

null@example.com (smaharbA) — Tue, 16 Apr 2013 15:30:52 +0000

а так можно ?

call :len "строка"                                 &:: "len" - Переменная куда вернуть значение
 echo Длина строки: %len%

Re: CMD/BAT: Нахождение длины строки

null@example.com (urahangka) — Wed, 10 Apr 2013 08:13:12 +0000

XGuest пишет:

Доброго времени суток
Быстрей не видел

К сожалению, тест показывает, что это самые долгие варианты функции. (1-й вариант более 24000 тиков, второй порядка 10000 тиков.)

Быстрее функции бинарного поиска, выложенного мной ранее, вариантов нету.

Re: CMD/BAT: Нахождение длины строки

null@example.com (XGuest) — Sun, 07 Apr 2013 19:37:36 +0000

Доброго времени суток

Быстрей не видел

@echo off
 call :len var "строка"                                 &:: "var" - Переменная куда вернуть значение
 echo Длина строки: %var%                      
goto :eof

:len
 set len=%~2
 if not "%len%"=="" set /a %1+=1 & call :len %1 "%len:~1%"
goto :eof

@echo off
set VAR=Очень длинная строка
set BAK=%TMP%\%RANDOM%
>%BAK% echo.%VAR%
for %%I in (%BAK%) do set /a len=%%~zI-2
echo Длина строки: %len%
goto :eof

С наилучшими пожеланиями
XGuest

Re: CMD/BAT: Нахождение длины строки

null@example.com (urahangka) — Wed, 03 Apr 2013 09:38:27 +0000

Скорость хорошая, практически идентичная скрипту, выложенному мной ранее(тест выдает порядка 370 тиков). Но мне не нравится двойная процедура, юзабилити не очень. Хотя, конечно, можно переделать...

Re: CMD/BAT: Нахождение длины строки

null@example.com (smaharbA) — Wed, 03 Apr 2013 07:27:37 +0000

за скорость не знаю


@echo off & call :%~1 "%~2" 2> nul

set me=%~0
echo %time%
for /l %%x in (1,1,100) do call :len "sdfsdf"
echo %ERRORLEVEL%
echo %time%
exit

:len (str) {
    if "%~1"=="" exit /b 0 else cmd /c ""%me%" length "%~1""
    exit /b %ERRORLEVEL%
}

:length (str) {
    set "str=%~1"
     setlocal ENABLEDELAYEDEXPANSION
    for /l %%x in (0,1,99999999999999999999) do (
        call set x=!x!%%str:~%%~x,1%%
        if "!x!"=="!str!" set /a x=%%~x+1 & exit !x!
    )
    exit 0
}

Re: CMD/BAT: Нахождение длины строки

null@example.com (urahangka) — Tue, 02 Apr 2013 08:45:19 +0000

Rumata пишет:

urahangka, ограничение в 4К вызвано чем - ограничением на длину строки в командной строке?

Если память не отшибло, то стандартное ограничение строки - 1023. Насколько я понимаю данный скрипт по тестам, он подсчитывает длину строки вплоть до 8189 символов, если строка длиннее - все равно показывает длину 8189 символов.

Re: CMD/BAT: Нахождение длины строки

null@example.com (Rumata) — Tue, 02 Apr 2013 08:26:40 +0000

urahangka, ограничение в 4К вызвано чем - ограничением на длину строки в командной строке?

Re: CMD/BAT: Нахождение длины строки

null@example.com (urahangka) — Tue, 02 Apr 2013 07:45:51 +0000

Кстати, нарыл где-то в недрах интернета функцию скрипта бинарного подсчета длины строки:


@echo off
set str=super-puper-stroka, izmeryaem dliny.
call :strlen4 str dlina
echo stroka=%str%
echo length=%dlina%
pause
exit /b

:strlen4  StrVar  RtnVar  --  be sure to check if the returned errorlevel is 0
(   setlocal enabledelayedexpansion & set /a "}=0"
    if "%~1" neq "" if defined %~1 (
        for %%# in (4096 2048 1024 512 256 128 64 32 16) do (
            if "!%~1:~%%#,1!" neq "" set "%~1=!%~1:~%%#!" & set /a "}+=%%#"
        )
        set "%~1=!%~1!0FEDCBA9876543211" & set /a "}+=0x!%~1:~32,1!!%~1:~16,1!"
    )
)
endlocal & set /a "%~2=%}%" & exit /b

З.Ы. Очень шустрый! Быстрее выложенного мной ранее где-то в 3 раза.

Лениво делать скриншоты, так что просто выложу результаты тестирования:
Исходные данные:
"деревянный" комп на winXP SP3 (Core 2 Duo 2Гц, 2 Гб оперы)
строка - длина 54 символа
цикл - 1000 раз
тики (сотые доли секунды) - перед циклом и после цикла. Результат - разница между тиками.

Вариант через временный файл: 9652 тика
Вариант, выложенный мной ранее: 1156 тика
Этот Вариант: 355 тиков.

Re: CMD/BAT: Нахождение длины строки

null@example.com (urahangka) — Tue, 02 Apr 2013 06:51:42 +0000

alexii пишет:

urahangka, приведите пример использования. У меня не выходит.


@echo off
set str=super-puper-stroka, izmeryaem dliny.
call :strLen str dlina
echo stroka=%str%
echo length=%dlina%
pause
exit /b

:strLen stroka length
(   SETLOCAL ENABLEDELAYEDEXPANSION
    set "str=A!%~1!"
    set "len=0"
    for /L %%A in (12,-1,0) do (
        set /a "len|=1<<%%A"
        for %%B in (!len!) do if "!str:~%%B,1!"=="" set /a "len&=~1<<%%A"
    )
)
( ENDLOCAL & REM RETURN VALUES
    IF "%~2" NEQ "" SET /a %~2=%len%
)
EXIT /b

Re: CMD/BAT: Нахождение длины строки

null@example.com (Rumata) — Mon, 01 Apr 2013 20:54:21 +0000

smaharbA пишет:

Вам еще учиться (без балды)

Очень интересное высказывание на критику неправильного кода. Никто не совершенен. А дополнительные знания никому еще были лишними.

Re: CMD/BAT: Нахождение длины строки

null@example.com (smaharbA) — Mon, 01 Apr 2013 20:13:39 +0000

Вам еще учиться (без балды)

Re: CMD/BAT: Нахождение длины строки

null@example.com (Rumata) — Mon, 01 Apr 2013 20:04:34 +0000

Хорошо. Проверил.

Вот слегка модифицированный код. В чем его смысл?


echo off
call :len "one"
:return
call echo %len%
exit /b

:len (str) {
    set out=%~0
    set out=%out:~1%
    set "str=%~1"
    setlocal ENABLEDELAYEDEXPANSION
    for /l %%x in (0,1,9) do (
        call set t=!t!%%str:~%%~x,1%%
        if !t!==!str! set %out%=%%x & call :return
    )
    exit /b
}

Вот результат его работы:


U:\tmp>echo off
2
3
4
5
6
7
8
9
ECHO is off.

Re: CMD/BAT: Нахождение длины строки

null@example.com (smaharbA) — Mon, 01 Apr 2013 19:55:42 +0000

попробуйте

Re: CMD/BAT: Нахождение длины строки

null@example.com (Rumata) — Mon, 01 Apr 2013 19:48:07 +0000

smaharbA пишет:


echo off
call :len "dfljgkdflgljkgsdfg"
:return
call echo %len%
exit

:len (str) {
...
call :return
...
    exit /b
}

очень странный способ выхода из подпрограммы. А если понадобятся два вызова? Как выполнить выход в таком случае?


call :len "one"
call echo %len%
call :len "two"
call echo %len%

Правильный код: вместо call :return написать goto :EOF или exit /b

Re: CMD/BAT: Нахождение длины строки

null@example.com (smaharbA) — Mon, 01 Apr 2013 18:33:27 +0000

скорость не знаю


echo off
call :len "dfljgkdflgljkgsdfg"
:return
call echo %len%
exit

:len (str) {
    set out=%~0
    set out=%out:~1%
    set "str=%~1"
    setlocal ENABLEDELAYEDEXPANSION
    for /l %%x in (0,1,99999999999999999999) do (
        call set t=!t!%%str:~%%~x,1%%
        if !t!==!str! set %out%=%%x & call :return
    )
    exit /b
}