Серый форум — AHK: Создание новой папки двойным кликом ЛКМ

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T03:03:19Z

Malcev
Ура! Работает. Ну Вы просто волшебник, честное слово, спасибо Вам еще раз.

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T02:40:20Z

~LButton::
If (A_TimeSincePriorHotkey<400) and (A_ThisHotkey=A_PriorHotkey)
{
  SetBatchLines, -1
   WinGet, ID,, A
   WinGetClass, Class, A
   if !(Class ~= "(Cabinet|Explore)WClass")
      Return
   ControlGet, sel, List, Count Selected, SysListView321, A
   if (sel != 0)
      Return

   oShell := ComObjCreate("Shell.Application")
   Loop
   {
      oIE := oShell.Windows.Item(A_Index - 1)
      Sleep, 10
   } Until oIE.HWND = ID   ; получаем объект InternetExplorer для активного окна
 
   oShellFolderView := oIE.Document
   oFolder := oShellFolderView.Folder
   if !(oFolder.Self.IsFileSystem)   ; если родительская папка не является частью файловой системы
   {
      MsgBox, % "Папка """ oFolder.Self.Name """ не является частью файловой системы`
            ,`nсоздание новой папки в ней невозможно!"
      oShell := oIE := oShellFolderView := oFolder := ""
      Return
   }
 
   Loop   ; определяем имя новой папки в зависимости
   {      ; от существования других объектов с названием "Новая папка (i)"
      Sleep, 10
      FolderName := "Новая папка" . (A_Index = 1 ? "" : " (" . A_Index . ")")
   } Until !IsObject(oFolder.ParseName(FolderName))

   Count := oFolder.Items.Count    ; перед созданием новой папки определяем количество видимых объектов
   oFolder.NewFolder(FolderName)   ; создаём новую папку
   While (Count = oFolder.Items.Count)    ; ждём, пока новая папка не станет видимой
      Sleep, 50                           ; и общее количество объектов не изменится

   oShellFolderView.SelectItem(oFolder.ParseName(FolderName), 1|3|4|8)
   oShell := oIE := oShellFolderView := oFolder := ""   ; удаляем объекты из памяти
   Return
}

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T01:46:59Z

Malcev
Сейчас только заметил, папка создается при двойном клике по любому файлу а не только на свободном пространстве, как из первого поста, как то можно их срастить, исправить?

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T01:29:18Z

Malcev
Да, я уже догадался, все работает, спасибо Вам большое.

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T01:27:01Z

Значит надо поставить актуальную версию автохотки.

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T01:22:09Z

Malcev
При запуске выскакивает такое окно
http://s017.radikal.ru/i433/1302/31/83d09f3f7565.jpg

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T01:16:41Z

Лучше использовать код teadrinker, только заменив горячую кнопку на двойное нажатие.

~LButton::
If (A_TimeSincePriorHotkey<400) and (A_ThisHotkey=A_PriorHotkey)
{
  SetBatchLines, -1
   WinGet, ID,, A
   WinGetClass, Class, A
   if !(Class ~= "(Cabinet|Explore)WClass")
      Return

   oShell := ComObjCreate("Shell.Application")
   Loop
   {
      oIE := oShell.Windows.Item(A_Index - 1)
      Sleep, 10
   } Until oIE.HWND = ID   ; получаем объект InternetExplorer для активного окна
 
   oShellFolderView := oIE.Document
   oFolder := oShellFolderView.Folder
   if !(oFolder.Self.IsFileSystem)   ; если родительская папка не является частью файловой системы
   {
      MsgBox, % "Папка """ oFolder.Self.Name """ не является частью файловой системы`
            ,`nсоздание новой папки в ней невозможно!"
      oShell := oIE := oShellFolderView := oFolder := ""
      Return
   }
 
   Loop   ; определяем имя новой папки в зависимости
   {      ; от существования других объектов с названием "Новая папка (i)"
      Sleep, 10
      FolderName := "Новая папка" . (A_Index = 1 ? "" : " (" . A_Index . ")")
   } Until !IsObject(oFolder.ParseName(FolderName))

   Count := oFolder.Items.Count    ; перед созданием новой папки определяем количество видимых объектов
   oFolder.NewFolder(FolderName)   ; создаём новую папку
   While (Count = oFolder.Items.Count)    ; ждём, пока новая папка не станет видимой
      Sleep, 50                           ; и общее количество объектов не изменится

   oShellFolderView.SelectItem(oFolder.ParseName(FolderName), 1|3|4|8)
   oShell := oIE := oShellFolderView := oFolder := ""   ; удаляем объекты из памяти
   Return
}

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:42:13Z

teadrinker
Ни разу не программист, включать нечего, или тут форум только для продвинутых.

Malcev
Заменил в верхнем коде, стало создаваться по двойному клику, но после удаления или переименования папки самопроизвольно опять создается новая папка. А можно еще на клик прикрутить такое же всплывающее окошко для переименования папки. Для WinXP Спасибо.

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:40:04Z

Ну да, а если уж хочется кликом мыши — то там специальная кнопочка имеется.

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:37:22Z

Ну да. Но оно очень сложное (для меня так точно).
А для семерки самое легкое послать шоркат CTRL+Shift+N

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:30:19Z

Malcev пишет:

Тогда для Xp можно так

А смысл? В последнем варианте по ссылке универсальное решение.

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:22:55Z

Тогда для Xp можно так

#IfWinActive, ahk_class CabinetWClass
F7::
ControlGetText, path, Edit1, ahk_class CabinetWClass
inputbox:
InputBox, FolderName, Create New Folder, Введите имя директории
if ErrorLevel
   return
IfExist %path%\%FolderName%
{
   msgbox, Такая директория существует
   GoTo, inputbox
}
FileCreateDir, %path%\%FolderName%
Return

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:07:56Z

Malcev пишет:

ControlGetText, path, Edit1, ahk_class CabinetWClass
FileCreateDir, %path%\New Folder

А если уже есть папка с таким именем?
Потом, например, в Win 7 нужный контрол называется по-другому — DirectUIHWND.

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:06:58Z

villla777 пишет:

как самому переделать я без понятия

Ну, для участников форума иногда включать мозги полезно!

Re: AHK: Создание новой папки двойным кликом ЛКМ

2013-02-07T00:03:34Z

Замени

SendEvent, !fwf

на

ControlGetText, path, Edit1, ahk_class CabinetWClass
FileCreateDir, %path%\New Folder