предьявы
небыло
в предложеинии
самому довелось быть модератором
он сам нарушает правила модерирования
самосуд

Зачем в милицию? Сразу к прокурору.

завершая последнее предложение точкой - чувствуется эмоциональный окрас жесткости и безразличия, а опуская точку выражается некая нейтральность, желаниее продолжения диалога

Да, чувствуется, что трава у вас забористая...

__Михаил__, а стоит ли отвечать пользователю, который не соблюдает правила форума и игнорит замечания модератора?

Как только я прочел правила, на основании которых была притензия к моему стилю изложения, я сразу все исправил(можете проверить дату исправления). Но вот модератор свой минус из репутации не убрал. При том, что он сам нарушает правила модерирования, при указании на ошибку, необходимо ссылатся в этом же посте на пункт нарушеных правил, как делается на всех порядочных форумах(самому довелось быть модератором). А просто указами сыпать - это превышение своих полномочий и самосуд! 
И вас не чуть не смутило основание его предьявы, что у меня небыло точки в предложеинии, после которого не следовало следующего. Мне удобно иногда так поступать, потому что завершая последнее предложение точкой - чувствуется эмоциональный окрас жесткости и безразличия, а опуская точку выражается некая нейтральность, желаниее продолжения диалога. А этот докапался просто из-за того что я мол сделал что то не так, как в его манямирке принято. И не надо мне тыкать сводом правил русского языка, который обновлялся в последний раз в 1956 году, когда еще и форумов то небыло, язык развивается и меняется, как все вокруг.

MtZay

А строка вначале 'Hotkey % "Pause", % corr' вообще ничего не говорит?

Да говорит,  просто в оригенале смена происходит нажатием shift+pause, и раз stealzy не оговорил этот момент, значит всё осталось по дефолту.

Подскажите пожалуйста, где в коде pause связана с шифтом?

А строка вначале 'Hotkey % "Pause", % corr' вообще ничего не говорит?

MtZay, предложения должны начинаться с заглавной буквы и заканчиваться знаками препинания. Исправьте!
http://forum.script-coding.com/viewtopi … 15#p145715
http://forum.script-coding.com/viewtopi … 45#p141445
http://forum.script-coding.com/viewtopi … 94#p141394
http://forum.script-coding.com/viewtopi … 91#p141391
http://forum.script-coding.com/viewtopi … 41#p141341
http://forum.script-coding.com/viewtopi … 98#p143498
http://forum.script-coding.com/viewtopi … 93#p143493

Кому я опять что то должен? На каком основании, товарищ офицер? Предьявите статью занона о моём нарушении. Быстро!

Почти полностью переписал скрипт.

По заданной ГК исправляется последний набранный текст, таковым считается любой текст,
не прерывающийся нажатием клавиш:
мыши, навигации (←↑↓→Pg*, Home, End), модификаторов (Alt Ctrl Win), Enter, Esc, F[1-12].
Полный список прерывающих клавиш содержится в методе _GetInputText().
Можно добавить туда пробел - тогда будет исправлятся только последнее слово.
Можно исключить Enter - тогда можно исправлять абзацами .
После исправления текста переключается раскладка.
Если выделен текст, то исправлен будет он.
(Большинством символов в выделенном будет определена раскладка, символы из которой необходимо исправить.)

+ Тех. особенности:

• Использует команду Input для взятия последнего введенного текста,
если переменная последнего введенного текста пуста, то ^{Ins} и взятие из буфера обмена (выделенный текст)
(если использована одна из EndKeys клавиш, описанных в методе _GetInputText() или клик мышью, переменная последнего введенного текста обнуляется).
• Текст исправляется с помощью захардкоженного соответствия латинских и кириллических символов в стандартных раскладках (строки Lat:="~QWER... и Cyr:="ЁЙЦУК..., описанные в методе _GetTextInOppositeLayout()).
Направление исправления выбирается на основе тек.раскладки, для выделенного текста - на основе большинства символов в тексте.
• Использует BackSpace для стирания последнего введенного текста, и SendInput для ввода исправленного.

Ограничения: в одном скрипте с переключалкой нежелательно использовать горячие клавиши на клики мышью или клавиши модификаторы (переключалка устанавливает свои прозрачные ГК на мышь для запрета исправления введенного текста после клика мышью).

#SingleInstance, force
#NoEnv
; #NoTrayIcon
P := new Punto
corr := ObjBindMethod(P, "CorrectionEnteredText")
Hotkey % "Pause", % corr
; togg := ObjBindMethod(P, "ToggleLayout")
; Hotkey % "!" Format("vk{:02x}", GetKeyVK("R")), % corr
Return

Class Punto {
	__New() {
		; Workaround for include mouse button in Input EndKeys
			_InputFn := ObjBindMethod(this, "_Input")
			_InputModFn := ObjBindMethod(this, "_Input", keyModifier := true)
			Hotkey ~*LButton, % _InputFn
			Hotkey ~*RButton, % _InputFn
			Hotkey ~*MButton, % _InputFn
		; Workaround for run CorrectionEnteredText() from hotkey including modifier keys:
		; you can't put LAlt in EndKeys if you run correction method by hotkey contain Alt (!R).
			Hotkey ~*LControl, % _InputModFn
			Hotkey ~*RControl, % _InputModFn
			Hotkey ~*LAlt, % _InputModFn
			Hotkey ~*RAlt, % _InputModFn
			Hotkey ~*LWin, % _InputModFn
			Hotkey ~*RWin, % _InputModFn
		timer := ObjBindMethod(this, "_GetInputText")
		SetTimer % timer, -1
	}
	_Input(keyModifier:=false) {
		If keyModifier ; Workaround because bug with using Hotkey ~*LAlt Up,
			KeyWait, % LTrim(A_ThisHotkey, "~*")
		Input
	}
	_GetInputText() {
		Input text, i v, {Enter}{NumpadEnter}{Tab}{Backspace}{Escape}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{Capslock}{Numlock}{PrintScreen}{Pause}
		this.ReplaceAfter := this.ReplaceAfter ? this._ReplaceText(text) :
		timer := ObjBindMethod(this, "_GetInputText")
		SetTimer % timer, -1
	}

	CorrectionEnteredText() {
		this.ReplaceAfter:=true
		Input
	}

	_ReplaceText(text) {
		StringLen count, text
		if (count>0)	; если вводился текст
			SendInput {BS %count%}
		else { 				; если выделен текст (при выделении используются кнопки мыши или шифт с навигационными кл. => text="" => count=0)
			cliptmp:=Clipboard
			Clipboard =
			SendPlay ^{Ins}
			Send ^{vk43}
			ClipWait .7, 1
			clipNew:=Clipboard
			if (clipNew != "") {
				text:=Clipboard
				fromClip:=true
			} else {
				Tooltip Выделите текст для исправления, A_CaretX+20, A_CaretY-3
				SetTimer TToff, -1000
				Return

				TToff:
					ToolTip
					Return
			}
			Clipboard:=cliptmp
		}

		substituteText := this._GetTextInOppositeLayout(text, fromClip, LayoutNeedToggle)
		(!fromClip || LayoutNeedToggle)  ?  this.ToggleLayout()
		Sleep 50 ; без задержки появляются баги со знаками пунктуации
		SetKeyDelay 50, 50
		SendInput {Raw}%substituteText%
		Return
	}
	_GetTextInOppositeLayout(text, fromClip, ByRef LayoutNeedToggle) {
		static Lat:="~QWERTYUIOP{}ASDFGHJKL:""ZXCVBNM<>``qwertyuiop[]asdfghjkl;'zxcvbnm,./|?@#$^&"
		, Cyr:="ЁЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖЭЯЧСМИТЬБЮёйцукенгшщзхъфывапролджэячсмитьбю./,""№;:?"

		En := (this.GetInputHKL() = 0x04090409)
		If fromClip {
			; для выделенного текста определяем принадлежность большинства символов к той или иной раскладке
			u := 0
			Loop, parse, text
			{
				OutputDebug % (A_LoopField = "`n") " " (A_LoopField = "`r")
				LatSym := InStr(Lat, A_LoopField), CyrSym := InStr(Cyr, A_LoopField)
				if (LatSym && !CyrSym)
					++u
				else if (CyrSym && !LatSym)
					--u
			}

			failureLayout:= (u>0) ? Lat : Cyr
			correctLayout := (u>0) ? Cyr : Lat
			LayoutNeedToggle := En ^ (u<=0)
		}
		Else {
			; для простого переключения основываемся на тек. раскладке
			failureLayout:= En ? Lat : Cyr
			correctLayout := En ? Cyr : Lat
		}

		Loop, parse, text,, `r ; `r — hack for Send command, because it regards `r`n as separate \n
		{
			if (symbolNum := InStr(failureLayout, A_LoopField, CaseSensitive:=true))
				substituteText .= SubStr(correctLayout, symbolNum, 1)
			else
				substituteText .= A_LoopField
		}
		Return substituteText
	}
	ToggleLayout() {
		PostMessage, 0x50, 2,,, % (hWndOwn := DllCall("GetWindow", Ptr, hWnd:=WinActive("A"), UInt, GW_OWNER := 4, Ptr)) ? "ahk_id" hWndOwn : "ahk_id" hWnd
	}
	GetInputHKL() {
		hWnd := WinExist("A")
		WinGetClass, Class
		if (Class == "ConsoleWindowClass") {
				WinGet, consolePID, PID
				DllCall("AttachConsole", Ptr, consolePID)
				VarSetCapacity(buff, 16)
				DllCall("GetConsoleKeyboardLayoutName", Str, buff)
				DllCall("FreeConsole")
				HKL := "0x" . SubStr(buff, -3)
		} else
			HKL := DllCall("GetKeyboardLayout", Ptr, DllCall("GetWindowThreadProcessId", Ptr, hWnd, UInt, 0, Ptr), Ptr)
		return HKL
	}
}

Подскажите пожалуйста, где в коде можно поменять хоткей для смены раскладки введеного текста? Я увидел кнопку паузы, но у меня ее нет на клаве(укороченая), и хотел бы поменять на дабл шифт, как в пунте.

ww2
Спасибо за тестирование разнообразных вариаций! Если Вы хотите избежать головную боль с циклическим переключением 3+ языков, замените

PostMessage, 0x50, 2,,, % (hWndOwn := DllCall("GetWindow", Ptr, hWnd:=WinActive("A"), UInt, GW_OWNER := 4, Ptr)) ? "ahk_id" hWndOwn : "ahk_id" hWnd

на

    
    ru := DllCall("LoadKeyboardLayout", "Str", "00000419", "Int", 1)
    en := DllCall("LoadKeyboardLayout", "Str", "00000409", "Int", 1)
      
    w := DllCall("GetForegroundWindow")
    pid := DllCall("GetWindowThreadProcessId", "UInt", w, "Ptr", 0)
    l := DllCall("GetKeyboardLayout", "UInt", pid)
    if (l = en)
    {
        PostMessage 0x50, 0, %ru%,, A
    }
    else
    {
        PostMessage 0x50, 0, %en%,, A
    }

Credits: https://autohotkey.com/board/topic/7001 … y-layouts/

ButtonSwitchLocale:
StringCaseSense On
ControlFocus, Edit1, ahk_exe AutoHotkey.exe
Send ^{vk41}  ; "Ctrl+A"

   ;clipSave:=clipAnsi()
   send ^{Insert}
   sleep,50
StringReplace, Clipboard, Clipboard, zh , ж , All
StringReplace, Clipboard, Clipboard, kh , х , All
StringReplace, Clipboard, Clipboard, shh , щ , All
StringReplace, Clipboard, Clipboard, sch , щ , All
StringReplace, Clipboard, Clipboard, sh , ш , All
StringReplace, Clipboard, Clipboard, ju , ю , All
StringReplace, Clipboard, Clipboard, yu , ю , All
StringReplace, Clipboard, Clipboard, ja , я , All
StringReplace, Clipboard, Clipboard, ya , я , All
StringReplace, Clipboard, Clipboard, ts , ц , All
StringReplace, Clipboard, Clipboard, ch , ч , All
StringReplace, Clipboard, Clipboard, c , ц , All
StringReplace, Clipboard, Clipboard, h , х , All
StringReplace, Clipboard, Clipboard, j , й , All
StringReplace, Clipboard, Clipboard, Zh , Ж , All
StringReplace, Clipboard, Clipboard, Kh , Х , All
StringReplace, Clipboard, Clipboard, Shh , Щ , All
StringReplace, Clipboard, Clipboard, Ju , Ю , All
StringReplace, Clipboard, Clipboard, Yu , Ю , All
StringReplace, Clipboard, Clipboard, Ja , Я , All
StringReplace, Clipboard, Clipboard, Ya , Я , All
StringReplace, Clipboard, Clipboard, Ts , Ц , All
StringReplace, Clipboard, Clipboard, Ch , Ч , All
StringReplace, Clipboard, Clipboard, Sch , Щ , All
StringReplace, Clipboard, Clipboard, Sh , Ш , All
StringReplace, Clipboard, Clipboard, C , Ц , All
StringReplace, Clipboard, Clipboard, H , Х , All
StringReplace, Clipboard, Clipboard, a , а , All
StringReplace, Clipboard, Clipboard, b , б , All
StringReplace, Clipboard, Clipboard, v , в , All
StringReplace, Clipboard, Clipboard, w , в , All
StringReplace, Clipboard, Clipboard, g , г , All
StringReplace, Clipboard, Clipboard, d , д , All
StringReplace, Clipboard, Clipboard, e , е , All
StringReplace, Clipboard, Clipboard, z , з , All
StringReplace, Clipboard, Clipboard, i , и , All
StringReplace, Clipboard, Clipboard, k , к , All
StringReplace, Clipboard, Clipboard, l , л , All
StringReplace, Clipboard, Clipboard, m , м , All
StringReplace, Clipboard, Clipboard, n , н , All
StringReplace, Clipboard, Clipboard, o , о , All
StringReplace, Clipboard, Clipboard, p , п , All
StringReplace, Clipboard, Clipboard, r , р , All
StringReplace, Clipboard, Clipboard, s , с , All
StringReplace, Clipboard, Clipboard, t , т , All
StringReplace, Clipboard, Clipboard, u , у , All
StringReplace, Clipboard, Clipboard, f , ф , All
StringReplace, Clipboard, Clipboard, y , ы , All
StringReplace, Clipboard, Clipboard, ' , ь , All
StringReplace, Clipboard, Clipboard, A , А , All
StringReplace, Clipboard, Clipboard, B , Б , All
StringReplace, Clipboard, Clipboard, V , В , All
StringReplace, Clipboard, Clipboard, W , В , All
StringReplace, Clipboard, Clipboard, G , Г , All
StringReplace, Clipboard, Clipboard, D , Д , All
StringReplace, Clipboard, Clipboard, E , Е , All
StringReplace, Clipboard, Clipboard, Z , З , All
StringReplace, Clipboard, Clipboard, I , И , All
StringReplace, Clipboard, Clipboard, K , К , All
StringReplace, Clipboard, Clipboard, L , Л , All
StringReplace, Clipboard, Clipboard, M , М , All
StringReplace, Clipboard, Clipboard, N , Н , All
StringReplace, Clipboard, Clipboard, O , О , All
StringReplace, Clipboard, Clipboard, P , П , All
StringReplace, Clipboard, Clipboard, R , Р , All
StringReplace, Clipboard, Clipboard, S , С , All
StringReplace, Clipboard, Clipboard, T , Т , All
StringReplace, Clipboard, Clipboard, U , У , All
StringReplace, Clipboard, Clipboard, F , Ф , All
StringReplace, Clipboard, Clipboard, Y , Ы , All
   send +{Insert}

Return

Для "железобетонного" переключения желательно назначить на каждый язык сочетание клавиш для переключения.
Или вручную, или с помощью файла реестра. В скрипте для английской раскладки ожидается Ctrl+Shist+1, для русской - Ctrl+Shift+2.

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Control Panel\Input Method\Hot Keys\00000100]
"Virtual Key"=hex:31,00,00,00
"Key Modifiers"=hex:06,c0,00,00
"Target IME"=hex:09,04,09,04

[HKEY_CURRENT_USER\Control Panel\Input Method\Hot Keys\00000101]
"Virtual Key"=hex:32,00,00,00
"Key Modifiers"=hex:06,c0,00,00
"Target IME"=hex:19,04,19,04

Собственно моё изделие:

#InstallKeybdHook
#SingleInstance, force
#NoEnv
;#NoTrayIcon

SetNumLockState,    On
SetScrollLockState, AlwaysOff
SetCapsLockState,   AlwaysOff

MyPunto := new Punto

corr := ObjBindMethod(MyPunto, "CorrectionEnteredText")
togg := ObjBindMethod(MyPunto, "ToggleLayout")
tgEN := ObjBindMethod(MyPunto, "ToggleLayout", "ENG")
tgRU := ObjBindMethod(MyPunto, "ToggleLayout", "RUS")
;chck := ObjBindMethod(MyPunto, "_check_lang")

Hotkey Pause,      %corr%
Hotkey ScrollLock, %togg%
Hotkey CapsLock,   %tgEN%
Hotkey +CapsLock,  %tgRU%
Hotkey ^CapsLock,  %tgRU%
Hotkey #n,         AkelPad
Hotkey #c,         Command
;Hotkey F12,        %chck%
Return

AkelPad:
Run c:\totalcmd\PROGRAMS\AkelPad.exe
Return

Command:
Run cmd.exe
Return

Class Punto {
	__New()
	{
		; Workaround for include mouse button in Input EndKeys
		_InputFn    := ObjBindMethod(this, "_Input")
		_InputModFn := ObjBindMethod(this, "_Input", keyModifier := true)
		Hotkey ~*LButton,  %_InputFn%
		Hotkey ~*RButton,  %_InputFn%
		Hotkey ~*MButton,  %_InputFn%
		; Workaround for run CorrectionEnteredText() from hotkey including modifier keys:
		; you can't put LAlt in EndKeys if you run correction method by hotkey contain Alt (!R).
		Hotkey ~*LControl, %_InputModFn%
		Hotkey ~*RControl, %_InputModFn%
		Hotkey ~*LAlt,     %_InputModFn%
		Hotkey ~*RAlt,     %_InputModFn%
		Hotkey ~*LWin,     %_InputModFn%
		Hotkey ~*RWin,     %_InputModFn%
		timer := ObjBindMethod(this, "_GetInputText")
		SetTimer %timer%, -1
	}

	_Input(keyModifier:=false)
	{
		If keyModifier ; Workaround because bug with using Hotkey ~*LAlt Up,
			KeyWait, %LTrim%(A_ThisHotkey, "~*")
		Input
	}

	_GetInputText()
	{						
		Input text, i v, {Enter}{NumpadEnter}{Tab}{Backspace}{Escape}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{Capslock}{Numlock}{PrintScreen}{Pause}
		this.ReplaceAfter := this.ReplaceAfter ? this._ReplaceText(text) :
		timer := ObjBindMethod(this, "_GetInputText")
		SetTimer %timer%, -1
	}

	CorrectionEnteredText()
	{
		this.ReplaceAfter := true
		Input
	}

	_ReplaceText(text)
	{
		StringLen count, text
		if (count>0)	; если вводился текст
			SendInput {BS %count%}
		else 				; если выделен текст (при выделении используются кнопки мыши или шифт с навигационными кл. => text="" => count=0)
		{
			cliptmp := Clipboard
			Clipboard := ""
			Sleep 50
			SendEvent ^{Ins}
			ClipWait 1, 1
			clipNew := Clipboard
			Clipboard := cliptmp
			if StrLen(clipNew) != 0
				text := clipNew
			else
			{
				Tooltip Выделите текст для исправления, A_CaretX+20, A_CaretY-3
				SetTimer TToff, -2000
				Return
				TToff:
					ToolTip
					Return
			}
		}
		substituteText := this._GetTextInOppositeLayout(text)
		if this._check_lang() == "ENG"
			this.ToggleLayout("RUS")
		else
			this.ToggleLayout("ENG")
		Sleep 50 ; без задержки появляются баги со знаками пунктуации
		SetKeyDelay 50, 50
		SendInput {Raw}%substituteText%
		Return
	}

	_GetTextInOppositeLayout(text)
	{
		static str1 := "~QWERTYUIOP{}ASDFGHJKL:""ZXCVBNM<>``qwertyuiop[]asdfghjkl;'zxcvbnm,./|?@#$^&ЁЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖЭЯЧСМИТЬБЮёйцукенгшщзхъфывапролджэячсмитьбю./,""№;:?",
		       str2 := "ЁЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖЭЯЧСМИТЬБЮёйцукенгшщзхъфывапролджэячсмитьбю./,""№;:?~QWERTYUIOP{}ASDFGHJKL:""ZXCVBNM<>``qwertyuiop[]asdfghjkl;'zxcvbnm,./|?@#$^&"
		Loop, parse, text,, `r ; `r — hack for Send command, because it regards `r`n as separate \n
		{
			if (symbolNum := InStr(str1, A_LoopField, CaseSensitive:=true))
				outputText .= SubStr(str2, symbolNum, 1)
			else
				outputText .= A_LoopField
		}
		Return outputText
	}

	ToggleLayout(Layout := "")
	{
		WinGetClass, winClass, A
		SetKeyDelay -1, -1
		if (StrLen(Layout) == 0)  or (winClass == "ConsoleWindowClass") 
			SendEvent {Blind}{LAlt down}{LShift down}{LShift up}{LAlt up}
		else
		{
			CurrLang := this._check_lang()
			if (Layout == "ENG") and (CurrLang != "ENG")
			{
				SendEvent ^+1
				SendMessage, 0x50, 0, 0x04090409,, A
			}
			if (Layout == "RUS") and (CurrLang != "RUS")
			{
				SendEvent ^+2
				SendMessage, 0x50, 0, 0x04190419,, A
			}
		}
		Return
	}

	_check_lang_by_window_id(hWnd)
	{
		if !hWnd
			Return
		WinGetClass, winClass, A
		if (winClass != "ConsoleWindowClass") || (b := SubStr(A_OSVersion, 1, 2) = "10")
		{
			if b
			{
				WinGet, consolePID, PID
				childConhostPID := this._GetCmdChildConhostPID(consolePID)
				dhw_prev := A_DetectHiddenWindows
				DetectHiddenWindows, On
				hWnd := WinExist("ahk_pid " . childConhostPID)
				DetectHiddenWindows, %dhw_prev%
			}
			threadId := DllCall("GetWindowThreadProcessId", Ptr, hWnd, UInt, 0)
			lyt := DllCall("GetKeyboardLayout", Ptr, threadId, UInt)
			langID := Format("{:#x}", lyt)
		}
		else ; окно консольное в вин7
		{
			WinGet, dwProcessId, PID, A
			bResult := DllCall("AttachConsole", "uint", dwProcessId, "int")
			if(!bResult)
				langID := 
			else
			{
				VarSetCapacity(lyt, 16)
				DllCall("GetConsoleKeyboardLayoutName", Str, lyt)
				DllCall("FreeConsole")
				langID := "0x" . lyt
			}
		}
		if     (langID = 0x04090409) or (langID = 0x00000409) ; для английского
			Return "ENG"
		else if(langID = 0x04190419) or (langID = 0x00000419) ; для русского
			Return "RUS"
		else if(langID = 0xF0080419) or (langID = 0x00010419) ; русская машинопись
			Return "RUQ"
		else if(langID = 0xF0A80422) or (langID = 0x00020422) ; для украинского
			Return "UKR"
		else if(langID = 0x04230423) or (langID = 0x00000423) ; для белорусского
			Return "BEL"
		else if(langID = 0x043F043F) or (langID = 0x0000043F) ; для казахского
			Return "KAZ"
		else
			Return %langID%
	}

	_GetCmdChildConhostPID(CmdPID)
	{
		static TH32CS_SNAPPROCESS := 0x2, MAX_PATH := 260
		h := DllCall("CreateToolhelp32Snapshot", UInt, TH32CS_SNAPPROCESS, UInt, 0, Ptr)
		VarSetCapacity(PROCESSENTRY32, size := 4*7 + A_PtrSize*2 + (MAX_PATH << !!A_IsUnicode), 0)
		NumPut(size, PROCESSENTRY32, "UInt")
		res := DllCall("Process32First", Ptr, h, Ptr, &PROCESSENTRY32)
		while res
		{
			parentPid := NumGet(PROCESSENTRY32, 4*4 + A_PtrSize*2, "UInt")
			if (parentPid = CmdPID)
			{
				exeName := StrGet(&PROCESSENTRY32 + 4*7 + A_PtrSize*2, "CP0")
				if (exeName = "conhost.exe" && PID := NumGet(PROCESSENTRY32, 4*2, "UInt"))
					break
			}
			res := DllCall("Process32Next", Ptr, h, Ptr, &PROCESSENTRY32)
		}
		DllCall("CloseHandle", Ptr, h)
		Return PID
	}

	_check_lang()
	{
		SetFormat, Integer, H
		WinGet, WinID,, A
		CurLang := this._check_lang_by_window_id(WinID)
		;MsgBox, %CurLang%
		Return %CurLang%
	}

}