Серый форум — AHK: Picture

Re: AHK: Picture

null@example.com (serzh82saratov) — Mon, 12 May 2014 07:30:28 +0000

Всплыл более простой метод.
Например по префиксу в переменной контрола:

+ открыть спойлер


Gui, Add, Picture, vCl_Picture gClipboard Icon133, Shell32.dll 
Gui, Add, Text, gClipboard vCl_Text x+10 wp hp +0x201, Hello
Gui, Show
Clipboard = Test  
OnMessage(0x203, "WM_LBUTTONDBLCLK") 
Return

WM_LBUTTONDBLCLK()  {   
    If InStr(A_GuiControl, "Cl_")
        Return 0
}
  
Clipboard:
    ToolTip, % Clipboard
    Return

Или по классу:

+ открыть спойлер


Gui, Add, Picture, gClipboard Icon133, Shell32.dll 
Gui, Add, Text, gClipboard x+10 wp hp +0x201, Hello 
Gui, Show
Clipboard = Test    
OnMessage(0x203, "WM_LBUTTONDBLCLK") 
Return

WM_LBUTTONDBLCLK(wp, lp)  {  
    MouseGetPos,,,,class 
    IfInString, class, Static
        Return 0
}
  
Clipboard:
    ToolTip, % Clipboard
    Return

Re: AHK: Picture

null@example.com (serzh82saratov) — Mon, 21 Apr 2014 07:45:07 +0000

Да тут надо писать Биллу

Re: AHK: Picture

null@example.com (YMP) — Mon, 21 Apr 2014 07:41:58 +0000

Нет, в сторонних так не получится. Фича контрола Static, это стандартный контрол Windows, который может использовать любое приложение. Копировать там можно то, что копируется, т.е. текст. Да, юзер должен об этом знать, по идее, иначе бессмысленно. Но почему-то даже в описании этого контрола на MSDN об этой фиче ничего нет.

Re: AHK: Picture

null@example.com (serzh82saratov) — Mon, 21 Apr 2014 07:10:34 +0000

Можно вместо неё подставить свою процедуру и уже из неё вызывать стандартную. Т.е. вы можете какие-то сообщения обрабатывать по-другому, заменять их на другие или просто блокировать.

Ну это чертовски круто!
А возможно перехватывать в контролах сторонних приложений?


Run notepad,,,pid 
ControlGet, id, hwnd,,edit1, ahk_pid %pid% 
SubclassStatic(id) 
Return 

StaticWndProc(hWnd, uMsg, wParam, lParam, uIdSubclass, dwRefData) {
    static WM_CHAR = 0x102  
    if (uMsg = WM_CHAR)
        ToolTip WM_CHAR
    return DllCall("DefSubclassProc", "ptr", hWnd, "uint", uMsg, "ptr", wParam, "ptr", lParam)
}

SubclassStatic(arr*) {
    static pNewWndProc := 0
    if (pNewWndProc = 0)
        pNewWndProc := RegisterCallback("StaticWndProc")
    for k,hWnd in arr
        DllCall("SetWindowSubclass", "ptr", hWnd, "ptr", pNewWndProc, "ptr", 1, "ptr", 0)
}

По задумке эта фича, видимо, должна облегчить юзеру копирование текста из таких контролов.

Вообще я правильно понял что фича именно AutoHotkey?
И что там копировать? Если это в каком то случае надо по задумке, то это легко решить програмеру стандартными методами. А когда это не надо (чаще всего), то это не осознанное изменение пользователем буфера обмена, ничего не понимаю.ptr

Re: AHK: Picture

null@example.com (YMP) — Mon, 21 Apr 2014 04:46:59 +0000

По задумке эта фича, видимо, должна облегчить юзеру копирование текста из таких контролов.

Контрол класса Static — это окно, и у него есть оконная процедура, которая обрабатывает посылаемые ему сообщения. Можно вместо неё подставить свою процедуру и уже из неё вызывать стандартную. Т.е. вы можете какие-то сообщения обрабатывать по-другому, заменять их на другие или просто блокировать.


Gui, Add, Picture, HWNDhwndPic gClipboard Icon133, Shell32.dll
SubclassStatic(hwndPic)
Gui, Add, Text, gClipboard, Hello
Gui, Show, w200
Clipboard = Test
Return

Clipboard:
    ToolTip, % Clipboard
    Return

GuiClose:
    ExitApp

StaticWndProc(hWnd, uMsg, wParam, lParam, uIdSubclass, dwRefData)
{
    static WM_LBUTTONDBLCLK := 0x203,  WM_LBUTTONDOWN := 0x201
    static WM_NCLBUTTONDBLCLK := 0xA3, WM_NCLBUTTONDOWN := 0xA1

    if (uMsg = WM_LBUTTONDBLCLK)
        uMsg := WM_LBUTTONDOWN
    else if (uMsg = WM_NCLBUTTONDBLCLK)
        uMsg := WM_NCLBUTTONDOWN
    return DllCall("DefSubclassProc", "ptr", hWnd, "uint", uMsg, "ptr", wParam, "ptr", lParam)
}

SubclassStatic(hWnd)
{
    static pNewWndProc := 0
    if (pNewWndProc = 0)
        pNewWndProc := RegisterCallback("StaticWndProc")
    DllCall("SetWindowSubclass", "ptr", hWnd, "ptr", pNewWndProc, "ptr", 1, "ptr", 0)
}

Re: AHK: Picture

null@example.com (serzh82saratov) — Sun, 20 Apr 2014 17:47:55 +0000

Добавлять абсолютно ко всем Picture процедурам этот костыль:


Gui, -Caption +E0x08000000 -DPIScale +AlwaysOnTop
Gui, Add, Picture, Icon133 gBN3 border w111 h111, Shell32.dll     
Gui, Show, NA x111 y111 
Return 

BN3:       
    StClip(A_GuiControl)
    SendInput {Raw}%Clipboard%    
    Return 

StClip(v) {
    Static PrClip := Clipboard
    If Clipboard = %v%
        Clipboard := PrClip
    PrClip := Clipboard 
}

Обрабатывать как я думал в WM_LBUTTONDOWN по имени картинки не получается, без метки у Picture, A_GuiControl пустой, ну варианты тут конечно есть.


OnMessage(0x201, "WM_LBUTTONDOWN")
Gui, -Caption +E0x08000000 -DPIScale +AlwaysOnTop
Gui, Add, Picture, Icon133 vPicture border w111 h111, Shell32.dll
Gui, Show, NA x111 y111 
Return 

WM_LBUTTONDOWN(w, l)   {     
    ToolTip % w "`n" l "`n" A_GuiControl
}

Тут и GuiControlGet не хочет знать свой родной статик по имени:

WM_LBUTTONDOWN(w, l)   {     
    GuiControlGet, OutputVar, Name, %l% 
    ToolTip % w "`n" l "`n" OutputVar
}

Так что остаётся только очень неудобный массив хэндлов.

Ещё можно субклассировать контрол, т.е. подставить в него свою оконную процедуру и игнорировать сообщения о двойных кликах.

Потому и любопытно узнать что Вы имели ввиду.

Re: AHK: Picture

null@example.com (serzh82saratov) — Sun, 20 Apr 2014 17:37:39 +0000

Нет

Ну хоть просто объясните.

в чём именно вам эта фича мешает.

Ну например хочу кликать, и чтоб буфер печатался:


Gui, -Caption +E0x08000000 -DPIScale +AlwaysOnTop
Gui, Add, Picture, Icon133 gBN3 border w111 h111, Shell32.dll     
Gui, Show, NA x111 y111 
Return 

BN3:       
    SendInput {Raw}%Clipboard%    
    Return

Но чёрт бы с ним. Получается ведь, есть у меня окно с кучей картинок - кнопок. Кликаю я по ним по своим нуждам, а буфер попорчен. В чём же тут фича?

Re: AHK: Picture

null@example.com (YMP) — Sun, 20 Apr 2014 17:29:50 +0000

serzh82saratov пишет:

Или вы про это:
Буду юзать WM_LBUTTONDOWN.

Нет, т.к. в свою очередь не понял, что вы имеете в виду. Я не в курсе, в чём именно вам эта фича мешает.

Re: AHK: Picture

null@example.com (serzh82saratov) — Sun, 20 Apr 2014 16:44:40 +0000

начиная с Висты это фича контролов Static.

Чтобы сделать такую "фичу", надо иметь баг головного мозга.

Ещё можно субклассировать контрол, т.е. подставить в него свою оконную процедуру и игнорировать сообщения о двойных кликах.

А вот тут можно подробнее, если честно ни слова не понял.
Или вы про это:

Буду юзать WM_LBUTTONDOWN.

Re: AHK: Picture

null@example.com (YMP) — Sun, 20 Apr 2014 16:41:03 +0000

Да, начиная с Висты это фича контролов Static. Для картинки тоже этот класс используется, как я понял. Можно отключить стиль SS_NOTIFY, но тогда и связанные с контролами процедуры работать не будут. Ещё можно субклассировать контрол, т.е. подставить в него свою оконную процедуру и игнорировать сообщения о двойных кликах.

Re: AHK: Picture

null@example.com (serzh82saratov) — Sun, 20 Apr 2014 15:41:29 +0000

Написал у них на форуме:

Что то я там ответ не понял, это что - фича?

Re: AHK: Picture

null@example.com (serzh82saratov) — Sun, 20 Apr 2014 15:37:46 +0000

Буфер обмена изменяется при двойном клике по static.

Ну да, только на Picture есть ощущение, что двойной клик какой то более растянутый.


Gui, Add, Picture, Icon133 gL Border, Shell32.dll
Gui Show
return

L:
    ToolTip % A_GuiEvent "`n" Clipboard
    Clipboard := "Default clip"  
    Sleep 200
    return

Re: AHK: Picture

null@example.com (YMP) — Sun, 20 Apr 2014 12:11:47 +0000

Написал у них на форуме: Double-click on a Gui control modifies the clipboard.

Re: AHK: Picture

null@example.com (bWRmeA) — Sun, 20 Apr 2014 11:22:01 +0000

Gui Margin, 50, 20
Gui Add, text, gL, Placeholder
Gui Show
return

L:
    ToolTip % A_GuiEvent "`n" Clipboard
    Clipboard := "Default clip"
    return

GuiClose:
    ExitApp

Буфер обмена изменяется при двойном клике по static.

Re: AHK: Picture

null@example.com (serzh82saratov) — Sun, 20 Apr 2014 11:15:11 +0000

Да, что то Я и неподумал даже об этом. Буду юзать WM_LBUTTONDOWN.
Но о проблеме напишите, Вы же хорошо инглиш знаете.