Серый форум — AHK : Два процесса в из одного файла?

Re: AHK : Два процесса в из одного файла?

2013-10-24T05:51:12Z


#SingleInstance off
OnMessage( DllCall("RegisterWindowMessage", "Str", "WM_HIGHLANDER"), "Receive_WM_HIGHLANDER")
OnExit Exit
Param = %1%
IsFunc(Param) ? %Param%() : (CloseAllSame(), proc1())

Return

proc1()  {  
    Run, %A_ScriptFullPath% proc2 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,111
}

proc2()  { 
    Menu, Tray, NoIcon 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,222 
} 

CloseAllSame()   {
    WM_HIGHLANDER := DllCall("RegisterWindowMessage", "Str", "WM_HIGHLANDER")
    PostMessage, WM_HIGHLANDER, 0, A_ScriptHWND,, ahk_id 0xFFFF 
 
}

Receive_WM_HIGHLANDER(wParam, lParam)   {
    If (lParam <> A_ScriptHWND)
        ExitApp
    return true
}

Exit:  
    If A_ExitReason = Menu
        CloseAllSame() 
    ExitApp
    
~Esc:: ExitApp

Вот получше решение.

Re: AHK : Два процесса в из одного файла?

2013-10-23T23:35:05Z

Проверил как сумел:

#SingleInstance off
 
Param = %1%
IsFunc(Param) ? %Param%() : proc1() 
Return
 
; \|/ \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/ 
 

proc1()  {  
   Run, %A_ScriptFullPath% proc2 
   ; содержимое odin.ahk
   loop,100
      {
      ToolTip, % A_MSec,700,700,1
      sleep, 777
      }
}

proc2()  { 
    ; содержимое dva.ahk
    loop,10000
      {
      ToolTip, % A_MSec,700,730,2      
      }
}

Отлично работает, независимо друг от друга. Два одноименный процесса. Спасибо!
Осталось разобраться с иконками и управлением через трей. Пока только один процесс убивается через "Exit".

Re: AHK : Два процесса в из одного файла?

2013-10-23T15:26:27Z

Irbis пишет:

This

And that

Re: AHK : Два процесса в из одного файла?

2013-10-23T15:19:05Z

Next пишет:

Что-то я пока не понял как должен работать код из 11. Из *.ahk запускается два скрипта, а после компиляции и запуска *.exe, в диспетчере только один процесс видно, да и тот потом исчезает.

Если так смущает иконка в трее, можно для второй и последующих запущенных "копий" скрыть иконку

proc2()
{
   Menu, Tray, NoIcon 
   ; ... dva.ahk
}

После компиляции скрипт из #11 работает так же точно, пока не закрыт ни один из MsgBox, будут оба процесса.

Re: AHK : Два процесса в из одного файла?

2013-10-23T13:18:17Z

Так, понятнее?



#SingleInstance off
 
Param = %1%
IsFunc(Param) ? %Param%() : proc1() 
Return
 
; \|/ \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/ 
 

proc1()  {  
    Run, %A_ScriptFullPath% proc2 
    ; содержимое odin.ahk
}

proc2()  { 
    ; содержимое dva.ahk
} 
 
 
; /|\ /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\

+ Если не понятно с функциями, можно также с метками:


#SingleInstance off
 
Param = %1% 
GoTo % IsLabel(Param) ? Param : "odin_ahk"

; \|/ \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/  \|/ 


odin_ahk:
    Run, "%A_ScriptFullPath%" dva_ahk
    MsgBox содержимое odin.ahk
    Return

dva_ahk:
    MsgBox содержимое dva.ahk
    Return
 
 
; /|\ /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\  /|\

Re: AHK : Два процесса в из одного файла?

2013-10-23T13:11:10Z

Я о "своих" двух речь веду. Ну вот создал я два скрипта. odin.ahk и dva.ahk. А потом беру один из ваших вариантов ... и?

Re: AHK : Два процесса в из одного файла?

2013-10-23T12:45:07Z

Это полный код скрипта. Их не надо объединять, это просто три варианта одного и того же.
Запускаешь один любой из них, и делаешь выводы.

Re: AHK : Два процесса в из одного файла?

2013-10-23T12:32:55Z

Где должен располагаться код двух вышеупомянутых скриптов?

Re: AHK : Два процесса в из одного файла?

2013-10-23T09:21:25Z

Next
Не понял вопрос.

Re: AHK : Два процесса в из одного файла?

2013-10-22T22:35:04Z

А лучше так:
Я правильно понимаю, что это "стартер" для двух других скриптов?

Re: AHK : Два процесса в из одного файла?

2013-10-22T19:23:33Z

У меня работает:



#SingleInstance off

Param = %1%
IsFunc(Param) ? %Param%() : proc1() 
Return

proc1()  {  
    Run, %A_ScriptFullPath% proc2 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,111
}

proc2()  {
    Run, %A_ScriptFullPath% proc3 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,222
}

proc3()  { 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,333
}

~Esc:: 
    ExitApp

+ Да и ещё при старте без параметра, надо наверное закрыть остальные:



#SingleInstance off

Param = %1%
IsFunc(Param) ? %Param%() : proc1() 
Return

proc1()  { 
    CloseAllSame()
    Run, %A_ScriptFullPath% proc2 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,111
}

proc2()  {
    Run, %A_ScriptFullPath% proc3 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,222
}

proc3()  { 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,333
}

CloseAllSame()  {   
    CurPID := DllCall("GetCurrentProcessId")
    WinGet, List, List, ahk_exe %A_ScriptFullPath%   ;  только для компилированного
    Loop % List
    {
        WinGet, PID, PID, % "ahk_id " List%A_Index%
        If (PID != CurPID) 
            Process, Close, %PID%
    }
}

~Esc:: 
    ExitApp

+ А лучше так:



#SingleInstance off

OnMessage( DllCall("RegisterWindowMessage", "Str", "WM_HIGHLANDER"), "Receive_WM_HIGHLANDER")
Param = %1%
IsFunc(Param) ? %Param%() : (CloseAllSame(), proc1())
Return

proc1()  {  
    Run, %A_ScriptFullPath% proc2 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,111
}

proc2()  {
    Run, %A_ScriptFullPath% proc3 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,222
}

proc3()  { 
    loop
        ToolTip % A_ThisFunc "`n" A_TickCount "`nProcessId = " DllCall("GetCurrentProcessId"),111,333
} 

CloseAllSame()   {
    WM_HIGHLANDER := DllCall("RegisterWindowMessage", "Str", "WM_HIGHLANDER")
    PostMessage, WM_HIGHLANDER, 0, A_ScriptHWND,, ahk_id 0xFFFF 
}

Receive_WM_HIGHLANDER(wParam, lParam)   {
    If (lParam <> A_ScriptHWND)
        ExitApp
    return true
}

~Esc:: 
    ExitApp

Re: AHK : Два процесса в из одного файла?

2013-10-22T19:15:09Z

Что-то я пока не понял как должен работать код из 11. Из *.ahk запускается два скрипта, а после компиляции и запуска *.exe, в диспетчере только один процесс видно, да и тот потом исчезает.

Re: AHK : Два процесса в из одного файла?

2013-10-22T18:26:33Z

Может запускать разные подпрограммы, в зависимости от параметров командной строки? Тогда число различных процессов, которые можно запустить из одного скомпилированного скрипта неограничено.

Re: AHK : Два процесса в из одного файла?

2013-10-22T18:19:16Z

В посте #9 указана подходящая методика

#SingleInstance off
if 1 = twice
   proc2()
else {
   Run, %A_ScriptFullPath% twice
   proc1()
}
Return

proc1()
{
   MsgBox Первый!
}

proc2()
{
   MsgBox Второй!
}

Re: AHK : Два процесса в из одного файла?

2013-10-22T17:50:06Z

ypppu пишет:

Нужно из одного файла запустить два независимых разных процесса или два независимых одинаковых процесса?

Разных.