Серый форум — AHK: Скролинг неактивного окна/Чем заменить PostMessage

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Sat, 02 Nov 2013 10:23:25 +0000

Видимо слишком большой у меня скрипт (2921 строка).

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (YMP) — Sat, 02 Nov 2013 10:20:42 +0000

Не знаю. Мои эксперименты этого не подтвердили.

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Sat, 02 Nov 2013 10:02:48 +0000

Как только убрал тот лишний "CoordMode", тот что в начале скрипта заработал. Значит все-таки отменяет.

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (YMP) — Sat, 02 Nov 2013 09:45:26 +0000

Не должна отменять. А процедуры хоткеев, пунктов меню, таймеров — это отдельные потоки и там эта команда только на сам поток действует. Функции выполняются в том потоке, из которого вызываются.

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Sat, 02 Nov 2013 09:01:27 +0000

Нашел, все-таки был еще 1 "CoordMode", но он был точно такой-же, т.е. привязка к экрану.

Значит использование "CoordMode" где-либо еще отменяет его в качестве дефолтного и приходится ставить его перед всеми "MouseGetPos".

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (YMP) — Sat, 02 Nov 2013 08:53:38 +0000

Не знаю. В справке написано, что поставленная в начало она меняет дефолтную настройку.

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Sat, 02 Nov 2013 08:35:09 +0000

Еще вопрос:
Почему в "большом" скрипте если не поставить "CoordMode" для мыши непосредственно перед "MouseGetPos" - скрипт отказывается работать?
Я пытался использовать "CoordMode" только в "голове" скрипта.
Хотя при этом в "большом" скрипте нигде больше не используется "CoordMode".

Структура моего скрипта:

Условия
Переменные
Основной цикл в виде таймера
Горячие клавиши
Окно настройки, меню, и сохранение/чтение даных
Подпрограммы для перехода по GoSub
Функции

Может есть предложения как лучше "отсортировать скрипт"?

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (YMP) — Sat, 02 Nov 2013 07:41:51 +0000

Да, придётся.

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Sat, 02 Nov 2013 07:10:24 +0000

Спасибо. Не знал как это делается.

А можно ли обойтись без "SetFormat", т.к. он изменяет представление всех переменных, или придется повторно его использовать для возврата к десятичным?

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (YMP) — Sat, 02 Nov 2013 07:06:06 +0000

А вы попросите у него 16-ричное.

SetFormat, Integer, H
a=0x0011
b=0x0022
c:=a|b
msgbox,%a%`n%b%`n"%c%"

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Sat, 02 Nov 2013 06:34:52 +0000

Спасибо за ответы.

YMP пишет:

А что мешает проверить?

Мешает то, что ahk выдает 10-ричное число на выходе.

a=0x0011
b=0x0022
c:=a|b
msgbox,%a%`n%b%`n"%c%"

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (YMP) — Sat, 02 Nov 2013 06:29:26 +0000

Ещё исправил и упростил. Перед WindowFromPoint mX урезается до 32 бит; перед SendMessage — до 16. Всё для того, чтобы корректно работали отрицательные значения Х. Возможно, нули в начале и не нужны, но я не знаю в подробностях, как AutoHotkey хранит и обрабатывает числа, и хотел бы как-то ему показать, какой разрядности число имею в виду.

1) Для чего здесь добавляется 16-ричный код?

Для отрезания верхних битов числа. У отрицательных чисел они заполнены единицами, соответственно, помещение туда Y оператором | (побитовое или) ничего не даст.

2) Какую функцию выполняет - | и &? В справке на этот счет мало информации.

Побитовое "или" и "и". В Википедии можно почитать, например.

3) Зачем Y умножать на 2 в степени 32?

Чтобы сдвинуть его в верхнюю половину 64-битного числа. WindowFromPoint принимает структуру POINT, состоящую из двух 32-битных чисел. Я её передаю в виде одного 64-битного числа. Но тут и возникают проблемы, если Х отрицательное.

И чему например будет равно выражение в итоге:

А что мешает проверить?

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Sat, 02 Nov 2013 05:38:38 +0000

Вот мой готовый вариант, который благодаря YMP'у может прокручивать что угодно, где угодно и без потери основных функций ролика в системе.


#SingleInstance,Force
#NoEnv
CoordMode,Mouse,Screen
DetectHiddenWindows,On
Menu,Tray,UseErrorLevel
SetBatchLines,-1
SetTitleMatchMode,2
SetWinDelay,-1
SetWorkingDir,%A_ScriptDir%
StringCaseSense,Off


scrollspeedup:=1


~*$WheelDown::
~*$WheelUp::
MouseGetPos,X,Y,mwin
WinGet,ActiveWin,id,A
stringtrimleft,Wheel,A_ThisHotkey,3
keywait,%Wheel%,L
if (whellwork=1)
  return
whellwork:=1
if !scrollspeedup
  scrollloop=1
else
{
  if A_TimeSincePriorHotkey<400
  {
    if (!speedup:=speedup>10 ? 0 : speedup="" ? 1 : speedup+1)
      scrollmulti++
  }
  if (A_TimeSincePriorHotkey>400 or A_ThisHotkey!=A_PriorHotkey)
  {
    scrollmulti=1
    speedup=
  }
  oldthishotkey:=a_thishotkey
  if scrollmulti>65
    scrollmulti=65
  if A_TimeSincePriorHotkey<17
    scrollloop=4
  else if A_TimeSincePriorHotkey<20
    scrollloop=3
  else if A_TimeSincePriorHotkey<30
    scrollloop=2
  else
    scrollloop=1
  scrollloop*=scrollmulti
}
if (A_OSVersion~="10.*?")
{
  if (scrollloop!=1)
  {
    if (Wheel="WheelUp")
      loop,% scrollloop
        mouseclick, WheelUp
    else
      loop,% scrollloop
        mouseclick, wheeldown
  }
}
else
{
  scroll:=Wheel="WheelUp" ? (120*scrollloop+1)<<16 : Wheel="WheelDown" ? -(120*scrollloop+1)<<16 : 0
  WheelWinID :=DllCall("WindowFromPoint","int64",(X&0x00000000FFFFFFFF)|(Y<<32),"ptr")
  WheelWinID2:=DllCall("WindowFromPoint","int64",(X&0x00000000FFFFFFFF)|((Y-20)<<32),"ptr")
  ControlGetFocus,focctrl,ahk_id %mwin%
  ControlGet,hfocctrl,Hwnd,,% focctrl,ahk_id %mwin%
  if (WheelWinID!=hfocctrl)
    ControlFocus,,ahk_id %WheelWinID%
  if (scroll!=0 and (scrollloop!=1 or ActiveWin!=mwin))
  {
    PoSTMessage,0x20A,Scroll,(X&0x0000FFFF)|(Y<<16),,ahk_id %WheelWinID%
    If (ErrorLevel or (WheelWinID!=WheelWinID2))
      PoSTMessage,0x20A,Scroll,(X&0x0000FFFF)|(Y<<16),,ahk_id %WheelWinID2%
  }
}
whellwork=0
return

Только нужно доработать режимы ускорения (сделать помягче).

Чуть не забыл. YMP, объясните пожалуйста что значит это выражение:

mX & 0x00000000FFFFFFFF | mY<<32

1) Для чего здесь добавляется 16-ричный код?
2) Какую функцию выполняет - | и &? В справке на этот счет мало информации.
3) Зачем Y умножать на 2 в степени 32?
И чему например будет равно выражение в итоге:

0x0011 | 0x0022

0x0033 или 0x1122 или 0x00110022?

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (YMP) — Sat, 02 Nov 2013 05:18:43 +0000

Немного исправил вычисление Point, чтобы корректно работало при отрицательных значениях Х. Насколько помню, они получаются, если Рабочий стол расширен на второй монитор, стоящий слева. К сожалению, нет сейчас возможности проверить. Отрицательные Y (если 2-й монитор сверху) проблем вызывать не должны.

Re: AHK: Скролинг неактивного окна/Чем заменить PostMessage

null@example.com (Alectric) — Fri, 01 Nov 2013 18:43:06 +0000

Да так работает.
Спасибо большое.