Серый форум — AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (teadrinker) — Tue, 11 Aug 2020 14:03:52 +0000

Vitalkerrain пишет:

Куда копать?

Один раз в начале все окна создать, по нажатию на кнопку только показывать.

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Vitalkerrain) — Tue, 11 Aug 2020 14:01:25 +0000

teadrinker пишет:

Сама идея неправильная.

Почему же? Всё я вижу, просто съезжает. Куда копать? Вот так выглядит. Я так понимаю должен быть скелет размеров и от него уже отталкиваться? или..?

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (teadrinker) — Tue, 11 Aug 2020 12:36:33 +0000

Сама идея неправильная. У вас при каждом запуске метки в окно новая кнопка добавляется, вы их не видите из-за того, что размер окна маленький.

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Vitalkerrain) — Tue, 11 Aug 2020 11:00:36 +0000

Поскольку тема максимально близкая напишу сюда. Есть код

Xb := 20
Yb := 20
Yb2 := 50
Yb3 := 80
w :=100
Gui, +hwndGlavnoe ToolWindow +AlwaysOnTop
Gui, Add, Button, x%Xb% y%Yb% w70 gLabel1, Первый
Gui, Add, Button, x%Xb% y%Yb2% w70 , Второй
Gui, Add, Button, x%Xb% y%Yb3% w70, Третий
Gui, Show, w%w% h150 
return

Label1:
   WinGetPos, X, Y, W, %Glavnoe% 
      Gui, 2: +hwndhGui2 -Caption +AlwaysOnTop
Gui,2:Add, Button, x20 y+20 w70 gLabel11, Из первого
      Gui, 2:Show, %  (a := !a) ? "x" (x2 := x + W-2.5) "y" Y2 := Y + 50 " w" 150 " h" 50 " NA" : " hide"
   return

      Label11:
   WinGetPos, X, Y, W,, ahk_id %hGui2%
      Gui, 3: +hwndhGui4 -Caption +AlwaysOnTop 
Gui,3:Add, Button, x20 y+20 w70, Из Второго
      Gui, 3:Show, %  (i := !i) ? "x" (x3 := x + W-2.5) "y" Y3 := Y + 50 " w" 150 " h" 50 " NA" : " hide"
   return
   
      GuiClose:
   ExitApp

Хочу сделать выпадающие пункты по высоте кнопки которая вызывает, но не могу разобраться со скелетом, вроде всё тоже самое делаю, но размеры получаются другие, может кто сталкивался с таким уже? И подскажите пожалуйста, как сделать так, если я закрываю первую вкладку, то чтобы закрывалась и её дочерняя?

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (teadrinker) — Wed, 29 Aug 2018 20:08:41 +0000

Gui, +hwndhGui1
Gui, Add, Button, x10 y40 w70 gButton vButton, % Chr(0x2190)
Gui, Show, w200 h70

Gui, 2:+hwndhGui2 +owner1 -Caption +Border
Gui, 2:Add, Text,, Здесь какая-то информация
Gui, 2:Show, Hide
VarSetCapacity(WI, 60)
DllCall("GetWindowInfo", Ptr, hGui2, Ptr, &WI)
gui2width := NumGet(WI, 12, "UInt") - NumGet(WI, 4, "UInt")

OnMessage(0x3, "WM_MOVE")
OnMessage(0x112, "WM_MOVE")   ; WM_SYSCOMMAND = 0x112
return

Button:
   if i := !i  {
      DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
      Gui, 2:Show, % "x" NumGet(WI, 4, "UInt") - gui2width " y" NumGet(WI, 24, "UInt") 
                  . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " hide"
   }
   DllCall("AnimateWindow", Ptr, hGui2, UInt, 400, UInt, 0x40000|(i ? 2 : 0x10001))
   GuiControl,, Button, % Chr(0x2190|(i ? 2 : 0))
   return
   
GuiClose:
   ExitApp
   
WM_MOVE(wp, lp, msg, hwnd)
{
   global hGui1, WI, i, gui2width
   static k
   if (msg = 0x112)
   {
      if (wp = 0xF020 && k := 1)   ; SC_MINIMIZE = 0xF020
         Gui, 2:Show, Hide
      
      if (wp = 0xF120 && !(k := 0) && i)   ; SC_RESTORE = 0xF120
         Gui, 2:Show
   }
   
   if (!i || hwnd != hGui1 || k = 1)
      return
   
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   Gui, 2:Show, % "x" NumGet(WI, 4, "UInt") - gui2width " y" NumGet(WI, 24, "UInt") 
               . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " NA"
}

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Vitalkerrain) — Wed, 29 Aug 2018 19:35:50 +0000

Ребят, подскажите, как сделать чтобы это окно с левой стороны выдвигалось\задвигалось? Что я только не пробовал, куда только X не ставил и отрицательные значения даже. Не могу найти справки по этому поводу.

Gui, +hwndhGui1
Gui, Add, Button, x125 y40 w70 gButton vButton, % Chr(0x2192)
Gui, Show, w200 h70

Gui, 2:+hwndhGui2 +owner1 -Caption +Border
Gui, 2:Add, Text,, Здесь какая-то информация
VarSetCapacity(WI, 60)

OnMessage(0x3, "WM_MOVE")
OnMessage(0x112, "WM_MOVE")   ; WM_SYSCOMMAND = 0x112
return

Button:
  DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   if i := !i
      Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
                  . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " hide"
   DllCall("AnimateWindow", Ptr, hGui2, UInt, 400, UInt, 0x40000|(i ? 1 : 0x10002))
   GuiControl,, Button, % Chr(0x2190|(i ? 0 : 2))
   return
   
GuiClose:
   ExitApp
   
WM_MOVE(wp, lp, msg, hwnd)
{
   global hGui1, WI, i
   static k
   if (msg = 0x112)
   {
      if (wp = 0xF020 && k := 1)   ; SC_MINIMIZE = 0xF020
         Gui, 2:Show, Hide
      
      if (wp = 0xF120 && !(k := 0) && i)   ; SC_RESTORE = 0xF120
         Gui, 2:Show
   }
   
   if (!i || hwnd != hGui1 || k = 1)
      return
   
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
               . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " NA"
}

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Vicoriyan) — Wed, 25 Apr 2018 08:50:08 +0000

Как сделать, чтоб в одном окне было 2 и больше кнопок со своим содержанием информации? Пробовал ковырять пример с вкладками, но так ничего и не вышло.

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (teadrinker) — Thu, 15 Dec 2016 17:48:04 +0000

Тогда так:

Tabs := [ "1 вкладка"
        , "2 вкладка"
        , "3 вкладка"
        , "4 вкладка" ]

Texts := [ "Информация для первой вкладки"
         , "Информация для второй вкладки"
         , "Информация для третьей вкладки"
         , "Информация для четвёртой вкладки" ]

Gui, +hwndhGui1
Gui, Add, Tab2, gButton vTab, % Tabs[1] "|" Tabs[2] "|" Tabs[3] "|" Tabs[4]
Loop 4  {
   Gui, Tab, % A_Index
   Gui, Add, Button, x175 y40 w70 gButton vButton%A_Index%, % Chr(0x2192)
}

Gui, 2:+hwndhGui2 +owner1 -Caption +Border
Gui, 2:Add, Text, vInfo Center, % "    " Texts[1] "    "
VarSetCapacity(WI, 60)

OnMessage(0x3, "WM_MOVE")
OnMessage(0x112, "WM_MOVE")   ; WM_SYSCOMMAND = 0x112
return

$F1::
   Gui, 1: Show, % (a := !a) ? "h70" : "Hide"
   if !i
      Return
   i := false

Button:
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   ((InStr(A_GuiControl, "Button") || (A_GuiControl = "Tab" && i)) && i := !i)
   Loop 4
      GuiControl,, Button%A_Index%, % Chr(0x2190|(i ? 0 : 2))
   
   if i
      Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
                  . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " hide"
   DllCall("AnimateWindow", Ptr, hGui2, UInt, 400, UInt, 0x40000|(i ? 1 : 0x10002))
   
   if (A_GuiControl = "Tab")  {  ; если меняется вкладка, меняем информацию в окне
      GuiControlGet, Tab
      for k, v in Tabs
         if (Tab = v)
            break
      GuiControl, 2:, Info, % Texts[k]
   }
   return
   
GuiClose:
   ExitApp
   
WM_MOVE(wp, lp, msg, hwnd)
{
   global hGui1, WI, i
   static k
   if (msg = 0x112)
   {
      if (wp = 0xF020 && k := 1)   ; SC_MINIMIZE = 0xF020
         Gui, 2:Show, Hide
      
      if (wp = 0xF120 && !(k := 0) && i)   ; SC_RESTORE = 0xF120
         Gui, 2:Show
   }
   
   if (!i || hwnd != hGui1 || k = 1)
      return
   
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
               . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " NA"
}

По F1 показывается/скрывается.

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Sgy-x2) — Thu, 15 Dec 2016 17:42:20 +0000

Нет.

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (teadrinker) — Thu, 15 Dec 2016 12:04:15 +0000

А если слайдер открыт, при закрытии/открытии основного окна он должен оставаться открытым, или нет?

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Sgy-x2) — Wed, 14 Dec 2016 17:14:55 +0000

teadrinker пишет:

Не понял, что за метод.

Просто я знаю, что вы (в смысле разработчики) способны придумать на столько сложные способы активации окон, что мне потребуется очень много времени на то, что бы понять как это работает.

F1::
a1 := !a1
	if !a1
	{
		Gui, Destroy
		return
	}

Gui, Add, text,, text
Gui, Show, h70
return

teadrinker пишет:

A_Index

Это там не нужно, забыл удалить.

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (teadrinker) — Wed, 14 Dec 2016 16:31:09 +0000

Sgy-x2 пишет:

Важно. Такой метод активации окна для меня важен

Не понял, что за метод.

if (A_Index != 1)

A_Index только в цикле может быть, что он там делает?

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Sgy-x2) — Wed, 14 Dec 2016 04:48:18 +0000

Возникла ещё одна небольшая проблема. У меня основное окно открывается и закрывается как в коде ниже. Если основное окно закрыть с активным слайдером, то при следующей активации основного окна слайдер будет формально активен, но не выдвинут (не знаю как объяснить) и выдвигаться он не будет. В таком состоянии он будет пока его не задвинуть его кнопкой. После того как его задвинул, то при следующей активации основного окна он будет работать нормально, пока опять не закрыть основное окно с активным слайдером.
Единственное что я понял, это связано как-то с отслеживанием перемещения окна.

F1::
a1 := !a1
	if !a1
	{
		if (A_Index != 1)
		Gui, Destroy
		;Важно. Такой метод активации окна для меня важен, т.к. тут расположены несколько меток перехода.
		return
	}
Tabs := [ "1 вкладка"
        , "2 вкладка"
        , "3 вкладка"
        , "4 вкладка" ]

Texts := [ "Информация для первой вкладки"
         , "Информация для второй вкладки"
         , "Информация для третьей вкладки"
         , "Информация для четвёртой вкладки" ]

Gui, +hwndhGui1
Gui, Add, Tab2, gButton vTab, % Tabs[1] "|" Tabs[2] "|" Tabs[3] "|" Tabs[4]
Loop 4  {
   Gui, Tab, % A_Index
   Gui, Add, Button, x175 y40 w70 gButton vButton%A_Index%, % Chr(0x2192)
}
Gui, Show, h70

Gui, 2:+hwndhGui2 +owner1 -Caption +Border
Gui, 2:Add, Text, vInfo Center, % "    " Texts[1] "    "
VarSetCapacity(WI, 60)

OnMessage(0x3, "WM_MOVE")
OnMessage(0x112, "WM_MOVE")   ; WM_SYSCOMMAND = 0x112
return

Button:
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   ((InStr(A_GuiControl, "Button") || (A_GuiControl = "Tab" && i)) && i := !i)
   
   Loop 4
      GuiControl,, Button%A_Index%, % Chr(0x2190|(i ? 0 : 2))
   
   if i
      Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
                  . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " hide"
   DllCall("AnimateWindow", Ptr, hGui2, UInt, 400, UInt, 0x40000|(i ? 1 : 0x10002))
   
   if (A_GuiControl = "Tab")  {  ; если меняется вкладка, меняем информацию в окне
      GuiControlGet, Tab
      for k, v in Tabs
         if (Tab = v)
            break
      GuiControl, 2:, Info, % Texts[k]
   }
   return

WM_MOVE(wp, lp, msg, hwnd)
{
   global hGui1, WI, i
   static k
   if (msg = 0x112)
   {
      if (wp = 0xF020 && k := 1)   ; SC_MINIMIZE = 0xF020
         Gui, 2:Show, Hide
      
      if (wp = 0xF120 && !(k := 0) && i)   ; SC_RESTORE = 0xF120
         Gui, 2:Show
   }
   
   if (!i || hwnd != hGui1 || k = 1)
      return

   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
               . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " NA"
}
return

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (teadrinker) — Tue, 13 Dec 2016 18:51:49 +0000

Tabs := [ "1 вкладка"
        , "2 вкладка"
        , "3 вкладка"
        , "4 вкладка" ]

Texts := [ "Информация для первой вкладки"
         , "Информация для второй вкладки"
         , "Информация для третьей вкладки"
         , "Информация для четвёртой вкладки" ]

Gui, +hwndhGui1
Gui, Add, Tab2, gButton vTab, % Tabs[1] "|" Tabs[2] "|" Tabs[3] "|" Tabs[4]
Loop 4  {
   Gui, Tab, % A_Index
   Gui, Add, Button, x175 y40 w70 gButton vButton%A_Index%, % Chr(0x2192)
}
Gui, Show, h70

Gui, 2:+hwndhGui2 +owner1 -Caption +Border
Gui, 2:Add, Text, vInfo Center, % "    " Texts[1] "    "
VarSetCapacity(WI, 60)

OnMessage(0x3, "WM_MOVE")
OnMessage(0x112, "WM_MOVE")   ; WM_SYSCOMMAND = 0x112
return

Button:
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   ((InStr(A_GuiControl, "Button") || (A_GuiControl = "Tab" && i)) && i := !i)
   
   Loop 4
      GuiControl,, Button%A_Index%, % Chr(0x2190|(i ? 0 : 2))
   
   if i
      Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
                  . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " hide"
   DllCall("AnimateWindow", Ptr, hGui2, UInt, 400, UInt, 0x40000|(i ? 1 : 0x10002))
   
   if (A_GuiControl = "Tab")  {  ; если меняется вкладка, меняем информацию в окне
      GuiControlGet, Tab
      for k, v in Tabs
         if (Tab = v)
            break
      GuiControl, 2:, Info, % Texts[k]
   }
   return
   
GuiClose:
   ExitApp
   
WM_MOVE(wp, lp, msg, hwnd)
{
   global hGui1, WI, i
   static k
   if (msg = 0x112)
   {
      if (wp = 0xF020 && k := 1)   ; SC_MINIMIZE = 0xF020
         Gui, 2:Show, Hide
      
      if (wp = 0xF120 && !(k := 0) && i)   ; SC_RESTORE = 0xF120
         Gui, 2:Show
   }
   
   if (!i || hwnd != hGui1 || k = 1)
      return
   
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
               . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " NA"
}

Re: AHK: Открытие окна Gui,2: как слайдер от основного Gui. Возможно ли?

null@example.com (Sgy-x2) — Mon, 12 Dec 2016 23:19:05 +0000

Спасибо, но я не понял как адаптировать эту строчку для более 2х вкладок:

GuiControl, 2:, Info, % Tab = "2 вкладка" ? Info1 : Info2

Пытался по разному, вот так получилось, но работает как-то криво, информация во вкладках отображается в разнобой.

Info1 := "Информация для 1 вкладки"
Info2 := "Информация для 2 вкладки"
Info3 := "Информация для 3 вкладки"
Info4 := "Информация для 4 вкладки"

Gui, +hwndhGui1
Gui, Add, Tab2, gButton vTab, 1 вкладка|2 вкладка|3 вкладка|4 вкладка
Loop 4  {
   Gui, Tab, % A_Index
   Gui, Add, Button, x125 y40 w70 gButton vButton%A_Index%, % Chr(0x2192)
}
Gui, Show, h70

Gui, 2:+hwndhGui2 +owner1 -Caption +Border
Gui, 2:Add, Text, vInfo w200, % Info
VarSetCapacity(WI, 60)

OnMessage(0x3, "WM_MOVE")
OnMessage(0x112, "WM_MOVE")   ; WM_SYSCOMMAND = 0x112
return

Button:
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   ((InStr(A_GuiControl, "Button") || (A_GuiControl = "Tab" && i)) && i := !i)
   
   Loop 4
      GuiControl,, Button%A_Index%, % Chr(0x2190|(i ? 0 : 2))
   
   if i
      Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
                  . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " hide"
   DllCall("AnimateWindow", Ptr, hGui2, UInt, 400, UInt, 0x40000|(i ? 1 : 0x10002))
   
   if (A_GuiControl = "Tab")  ; если меняется вкладка, меняем информацию в окне
   if tab = 1 вкладка
      GuiControl, 2:, Info, % Info1
   if tab = 2 вкладка
      GuiControl, 2:, Info, % Info2
   if tab = 3 вкладка
      GuiControl, 2:, Info, % Info3
   if tab = 4 вкладка
      GuiControl, 2:, Info, % Info4
	msgbox % tab
   
WM_MOVE(wp, lp, msg, hwnd)
{
   global hGui1, WI, i
   static k
   if (msg = 0x112)
   {
      if (wp = 0xF020 && k := 1)   ; SC_MINIMIZE = 0xF020
         Gui, 2:Show, Hide
      
      if (wp = 0xF120 && !(k := 0) && i)   ; SC_RESTORE = 0xF120
         Gui, 2:Show
   }
   
   if (!i || hwnd != hGui1 || k = 1)
      return
   
   DllCall("GetWindowInfo", Ptr, hGui1, Ptr, &WI)
   Gui, 2:Show, % "x" NumGet(WI, 12, "UInt") " y" NumGet(WI, 24, "UInt") 
               . " h" NumGet(WI, 32, "UInt") - NumGet(WI, 24, "UInt") " NA"
}