Серый форум — AHK: Загрузка разных иконок для программы

Re: AHK: Загрузка разных иконок для программы

2014-11-13T18:31:02Z

Так можно.

Re: AHK: Загрузка разных иконок для программы

2014-11-13T18:27:35Z

А если сделать так, то наверное не будут получены новые дескрипторы иконок при повторном нажатии?

3::
if !hAssociatedGui2
{
   hIcon:= ExtractIcon("imageres.dll", 4, 16)
   hAssociatedGui2 := AddTrayIcon(hIcon)
}
return

4::
if !hAssociatedGui3
{
   hIcon:= ExtractIcon("imageres.dll", 8, 16)
   hAssociatedGui3 := AddTrayIcon(hIcon)
}
return

Re: AHK: Загрузка разных иконок для программы

2014-11-13T18:22:33Z

Память, вроде, не ест, судя по диспетчеру задач, но в коде есть ошибка: при повторном нажатии 3 и 4 будут получены новые дескрипторы иконок, которые нигде не удаляются, это тоже как-то расходует ресурсы системы. Тут я подробно не знаю, но знаю, что такие хендлы должны удаляться с помощью DllCall("DestroyIcon", Ptr, hIcon).

Re: AHK: Загрузка разных иконок для программы

2014-11-13T18:10:21Z

А такой код не будет есть память?

OnExit, RemoveIcon
Return

1::
hIcon:= ExtractIcon("imageres.dll", 77, 16)
if hAssociatedGui1
   ModifyTrayIcon(hIcon, hAssociatedGui1)
else
   hAssociatedGui1 := AddTrayIcon(hIcon)
return

2::
hIcon:= ExtractIcon("imageres.dll", 2, 16)
if hAssociatedGui1
   ModifyTrayIcon(hIcon, hAssociatedGui1)
else
   hAssociatedGui1 := AddTrayIcon(hIcon)
return

3::
hIcon:= ExtractIcon("imageres.dll", 4, 16)
if !hAssociatedGui2
   hAssociatedGui2 := AddTrayIcon(hIcon)
return

4::
hIcon:= ExtractIcon("imageres.dll", 8, 16)
if !hAssociatedGui3
   hAssociatedGui3 := AddTrayIcon(hIcon)
return
   
Esc:: ExitApp

RemoveIcon:
   RemoveTrayIcon(hAssociatedGui1), RemoveTrayIcon(hAssociatedGui2), RemoveTrayIcon(hAssociatedGui3)
   ExitApp

ExtractIcon(sFile, IconNumber, IconSize)
{
   coding := A_IsUnicode ? "W" : "A"

   SplitPath, sFile,,, ext
   (ext = "ico" && IconNumber := 0)

   if PrivateExtractIcons := DllCall("GetProcAddress"
                              , Ptr, DllCall("LoadLibrary", Str, "User32", Ptr)
                              , AStr, "PrivateExtractIcons" . coding, Ptr)
   {
      Result := DllCall(PrivateExtractIcons, Str, sFile, Int, IconNumber-1
                  , Int, IconSize, Int, IconSize, PtrP, hIcon, UIntP, 0, UInt, 1, UInt, 0)
      if !Result
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
      else if (Result = 0xFFFFFFFF || Result = -1)
         MsgBox, 16,, Файл "%sFile%" не найден!
   }

   else
   {
      if !DllCall("Shell32\ExtractIconEx" . coding, Str, sFile, Int, IconNumber-1, PtrP, hIconLarge, PtrP, hIconSmall, UInt, 1)
      {
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
         return
      }
      SysGet, SmallIconSize, % SM_CXSMICON := 49
      if (IconSize <= SmallIconSize)
         DllCall("DestroyIcon", Ptr, hIconLarge), hIcon := hIconSmall
      else
         DllCall("DestroyIcon", Ptr, hIconSmall), hIcon := hIconLarge

      hIcon := DllCall("CopyImage", Ptr, hIcon, UInt, IMAGE_ICON := 1
         , Int, IconSize, Int, IconSize, UInt, LR_COPYRETURNORG := 0x4|LR_COPYDELETEORG := 0x8, Ptr)
   }

   Return hIcon
}

AddTrayIcon(hIcon)
{
   static NIF_MESSAGE := 1, NIF_ICON := 2, GuiNumber := 99, NIM_ADD := 0, uID := 0x404
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   Gui, % GuiNumber-- ": +hwndhGui"
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_MESSAGE|NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(nMsg := 0x404, NOTIFYICONDATA, 2*A_PtrSize + 8, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   DllCall("shell32\Shell_NotifyIcon", UInt, NIM_ADD, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return hGui
}

ModifyTrayIcon(hIcon, hGui, uID = 0x404)
{
   static NIM_MODIFY := 1, NIF_ICON := 2
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   res := DllCall("shell32\Shell_NotifyIcon", UInt, NIM_MODIFY, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return res
}

RemoveTrayIcon(hWnd, uID=0x404)
{
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hWnd, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   Return DllCall("shell32\Shell_NotifyIcon", "UInt", NIM_DELETE := 2, Ptr, &NOTIFYICONDATA)
}

Re: AHK: Загрузка разных иконок для программы

2014-11-13T16:16:00Z

Malcev пишет:

Если нажимаю сразу "2", то иконка не появляется.
Если нажимаю 1, потом 2 и потом опять 1, то иконка остается 2.

Так задача была:

Malcev пишет:

Потом при нажатии 1, добавляет еще одну.
При нажатии 2 - меняет добавленную на вторую.

Malcev пишет:

А к каким последствиям может привести моя модификация скрипта?

Работать не будет правильно, с каждым нажатием память отъедать. Нужно понимать, как работают эти функции, там при каждом вызове AddTrayIcon() создаётся новое скрытое окно. Чтобы менялось туда-обратно, лучше так:

Menu, Tray, Icon, % A_AhkPath, 2
OnExit, RemoveIcon
Return

1::
2::
    hIcon:= ExtractIcon("imageres.dll", A_ThisHotkey = 1 ? 77 : 2, 16)
    hAssociatedGui ? ModifyTrayIcon(hIcon, hAssociatedGui) : hAssociatedGui := AddTrayIcon(hIcon)
    Return
   
Esc:: ExitApp

RemoveIcon:
   RemoveTrayIcon(hAssociatedGui)
   ExitApp

ExtractIcon(sFile, IconNumber, IconSize)
{
   coding := A_IsUnicode ? "W" : "A"

   SplitPath, sFile,,, ext
   (ext = "ico" && IconNumber := 0)

   if PrivateExtractIcons := DllCall("GetProcAddress"
                              , Ptr, DllCall("LoadLibrary", Str, "User32", Ptr)
                              , AStr, "PrivateExtractIcons" . coding, Ptr)
   {
      Result := DllCall(PrivateExtractIcons, Str, sFile, Int, IconNumber-1
                  , Int, IconSize, Int, IconSize, PtrP, hIcon, UIntP, 0, UInt, 1, UInt, 0)
      if !Result
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
      else if (Result = 0xFFFFFFFF || Result = -1)
         MsgBox, 16,, Файл "%sFile%" не найден!
   }

   else
   {
      if !DllCall("Shell32\ExtractIconEx" . coding, Str, sFile, Int, IconNumber-1, PtrP, hIconLarge, PtrP, hIconSmall, UInt, 1)
      {
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
         return
      }
      SysGet, SmallIconSize, % SM_CXSMICON := 49
      if (IconSize <= SmallIconSize)
         DllCall("DestroyIcon", Ptr, hIconLarge), hIcon := hIconSmall
      else
         DllCall("DestroyIcon", Ptr, hIconSmall), hIcon := hIconLarge

      hIcon := DllCall("CopyImage", Ptr, hIcon, UInt, IMAGE_ICON := 1
         , Int, IconSize, Int, IconSize, UInt, LR_COPYRETURNORG := 0x4|LR_COPYDELETEORG := 0x8, Ptr)
   }

   Return hIcon
}

AddTrayIcon(hIcon)
{
   static NIF_MESSAGE := 1, NIF_ICON := 2, GuiNumber := 99, NIM_ADD := 0, uID := 0x404
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   Gui, % GuiNumber-- ": +hwndhGui"
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_MESSAGE|NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(nMsg := 0x404, NOTIFYICONDATA, 2*A_PtrSize + 8, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   DllCall("shell32\Shell_NotifyIcon", UInt, NIM_ADD, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return hGui
}

ModifyTrayIcon(hIcon, hGui, uID = 0x404)
{
   static NIM_MODIFY := 1, NIF_ICON := 2
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   res := DllCall("shell32\Shell_NotifyIcon", UInt, NIM_MODIFY, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return res
}

RemoveTrayIcon(hWnd, uID=0x404)
{
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hWnd, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   Return DllCall("shell32\Shell_NotifyIcon", "UInt", NIM_DELETE := 2, Ptr, &NOTIFYICONDATA)
}

Нажимать можно в любом порядке.

Re: AHK: Загрузка разных иконок для программы

2014-11-13T15:38:29Z

Если нажимаю сразу "2", то иконка не появляется.
Если нажимаю 1, потом 2 и потом опять 1, то иконка остается 2.
А к каким последствиям может привести моя модификация скрипта?

Re: AHK: Загрузка разных иконок для программы

2014-11-13T15:30:04Z

Тогда так:

Menu, Tray, Icon, % A_AhkPath, 2
OnExit, RemoveIcon
Return

1:: (!hIcon1 && (hIcon1 := ExtractIcon("imageres.dll", 77, 16))
    && hAssociatedGui := AddTrayIcon(hIcon1))

2:: (!hIcon2 && (hIcon2 := ExtractIcon("imageres.dll", 2, 16))
    && ModifyTrayIcon(hIcon2, hAssociatedGui))
    
Esc:: ExitApp

RemoveIcon:
   RemoveTrayIcon(hAssociatedGui)
   ExitApp

ExtractIcon(sFile, IconNumber, IconSize)
{
   coding := A_IsUnicode ? "W" : "A"

   SplitPath, sFile,,, ext
   (ext = "ico" && IconNumber := 0)

   if PrivateExtractIcons := DllCall("GetProcAddress"
                              , Ptr, DllCall("LoadLibrary", Str, "User32", Ptr)
                              , AStr, "PrivateExtractIcons" . coding, Ptr)
   {
      Result := DllCall(PrivateExtractIcons, Str, sFile, Int, IconNumber-1
                  , Int, IconSize, Int, IconSize, PtrP, hIcon, UIntP, 0, UInt, 1, UInt, 0)
      if !Result
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
      else if (Result = 0xFFFFFFFF || Result = -1)
         MsgBox, 16,, Файл "%sFile%" не найден!
   }

   else
   {
      if !DllCall("Shell32\ExtractIconEx" . coding, Str, sFile, Int, IconNumber-1, PtrP, hIconLarge, PtrP, hIconSmall, UInt, 1)
      {
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
         return
      }
      SysGet, SmallIconSize, % SM_CXSMICON := 49
      if (IconSize <= SmallIconSize)
         DllCall("DestroyIcon", Ptr, hIconLarge), hIcon := hIconSmall
      else
         DllCall("DestroyIcon", Ptr, hIconSmall), hIcon := hIconLarge

      hIcon := DllCall("CopyImage", Ptr, hIcon, UInt, IMAGE_ICON := 1
         , Int, IconSize, Int, IconSize, UInt, LR_COPYRETURNORG := 0x4|LR_COPYDELETEORG := 0x8, Ptr)
   }

   Return hIcon
}

AddTrayIcon(hIcon)
{
   static NIF_MESSAGE := 1, NIF_ICON := 2, GuiNumber := 99, NIM_ADD := 0, uID := 0x404
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   Gui, % GuiNumber-- ": +hwndhGui"
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_MESSAGE|NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(nMsg := 0x404, NOTIFYICONDATA, 2*A_PtrSize + 8, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   DllCall("shell32\Shell_NotifyIcon", UInt, NIM_ADD, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return hGui
}

ModifyTrayIcon(hIcon, hGui, uID = 0x404)
{
   static NIM_MODIFY := 1, NIF_ICON := 2
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   res := DllCall("shell32\Shell_NotifyIcon", UInt, NIM_MODIFY, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return res
}

RemoveTrayIcon(hWnd, uID=0x404)
{
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hWnd, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   Return DllCall("shell32\Shell_NotifyIcon", "UInt", NIM_DELETE := 2, Ptr, &NOTIFYICONDATA)
}

Re: AHK: Загрузка разных иконок для программы

2014-11-13T14:31:07Z

Да. Изначально скрипт загружает только свою иконку.
Потом при нажатии 1, добавляет еще одну.
При нажатии 2 - меняет добавленную на вторую.

Re: AHK: Загрузка разных иконок для программы

2014-11-13T11:17:27Z

В смысле, «первая иконка» — это в дополнение к уже имеющейся иконке скрипта, или как?

Re: AHK: Загрузка разных иконок для программы

2014-11-13T07:25:24Z

Я хочу чтобы при нажатии "1" появлялась в трее первая иконка, а при нажатии "2" она менялась на вторую.

Re: AHK: Загрузка разных иконок для программы

2014-11-13T04:38:36Z

Нет, не так, а что именно ты хочешь сделать?

Re: AHK: Загрузка разных иконок для программы

2014-11-12T23:07:59Z

Правильно ли я понимаю, что для того, чтобы менять иконки шорткатами нужно делать так:

OnExit, Exit

1::
hIcon := ExtractIcon(A_AhkPath, 2, 16)
RemoveTrayIcon(hAssociatedGui1)
hAssociatedGui1 := AddTrayIcon(hIcon)  ; первая дополнительная иконка
return

2::
hIcon := ExtractIcon("Shell32.dll", 44, 16)
RemoveTrayIcon(hAssociatedGui1)
hAssociatedGui1 := AddTrayIcon(hIcon)  ; первая дополнительная иконка
return


CloseApp:
   ExitApp

Exit:
   RemoveTrayIcon(hAssociatedGui1)
   ExitApp

ExtractIcon(sFile, IconNumber, IconSize)
{
   coding := A_IsUnicode ? "W" : "A"

   SplitPath, sFile,,, ext
   (ext = "ico" && IconNumber := 0)

   if PrivateExtractIcons := DllCall("GetProcAddress"
                              , Ptr, DllCall("LoadLibrary", Str, "User32", Ptr)
                              , AStr, "PrivateExtractIcons" . coding, Ptr)
   {
      Result := DllCall(PrivateExtractIcons, Str, sFile, Int, IconNumber-1
                  , Int, IconSize, Int, IconSize, PtrP, hIcon, UIntP, 0, UInt, 1, UInt, 0)
      if !Result
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
      else if (Result = 0xFFFFFFFF || Result = -1)
         MsgBox, 16,, Файл "%sFile%" не найден!
   }

   else
   {
      if !DllCall("Shell32\ExtractIconEx" . coding, Str, sFile, Int, IconNumber-1, PtrP, hIconLarge, PtrP, hIconSmall, UInt, 1)
      {
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
         return
      }
      SysGet, SmallIconSize, % SM_CXSMICON := 49
      if (IconSize <= SmallIconSize)
         DllCall("DestroyIcon", Ptr, hIconLarge), hIcon := hIconSmall
      else
         DllCall("DestroyIcon", Ptr, hIconSmall), hIcon := hIconLarge

      hIcon := DllCall("CopyImage", Ptr, hIcon, UInt, IMAGE_ICON := 1
         , Int, IconSize, Int, IconSize, UInt, LR_COPYRETURNORG := 0x4|LR_COPYDELETEORG := 0x8, Ptr)
   }

   Return hIcon
}

AddTrayIcon(hIcon)
{
   static NIF_MESSAGE := 1, NIF_ICON := 2, GuiNumber := 99
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   Gui, % GuiNumber-- ": +hwndhGui"
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID := 0x404, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_MESSAGE|NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(nMsg := 0x404, NOTIFYICONDATA, 2*A_PtrSize + 8, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   DllCall("shell32\Shell_NotifyIcon", UInt, NIM_ADD := 0, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return hGui
}

RemoveTrayIcon(hWnd, uID=0x404)
{
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hWnd, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   DllCall("shell32\Shell_NotifyIcon", "UInt", NIM_DELETE := 2, Ptr, &NOTIFYICONDATA)
   Return
}

Re: AHK: Загрузка разных иконок для программы

2014-11-02T22:56:37Z

Так же.

Re: AHK: Загрузка разных иконок для программы

2014-11-02T22:50:13Z

А как в этом коде загрузить иконки не из dll или exe, а просто указать путь к ico?

if hIcon := ExtractIcon(A_AhkPath, 2, 16)
   hAssociatedGui1 := AddTrayIcon(hIcon)  ; первая дополнительная иконка

if hIcon := ExtractIcon("Shell32.dll", 44, 16)
   hAssociatedGui2 := AddTrayIcon(hIcon)  ; вторая дополнительная иконка
OnExit, Exit

; если нужно меню для иконок
OnMessage(0x404, "AHK_NOTIFYICON")
Menu, MyTrayMenu, Add, Завершение работы, CloseApp
Return

CloseApp:
   ExitApp

Exit:
   RemoveTrayIcon(hAssociatedGui1), RemoveTrayIcon(hAssociatedGui2)
   ExitApp

ExtractIcon(sFile, IconNumber, IconSize)
{
   coding := A_IsUnicode ? "W" : "A"

   SplitPath, sFile,,, ext
   (ext = "ico" && IconNumber := 0)

   if PrivateExtractIcons := DllCall("GetProcAddress"
                              , Ptr, DllCall("LoadLibrary", Str, "User32", Ptr)
                              , AStr, "PrivateExtractIcons" . coding, Ptr)
   {
      Result := DllCall(PrivateExtractIcons, Str, sFile, Int, IconNumber-1
                  , Int, IconSize, Int, IconSize, PtrP, hIcon, UIntP, 0, UInt, 1, UInt, 0)
      if !Result
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
      else if (Result = 0xFFFFFFFF || Result = -1)
         MsgBox, 16,, Файл "%sFile%" не найден!
   }

   else
   {
      if !DllCall("Shell32\ExtractIconEx" . coding, Str, sFile, Int, IconNumber-1, PtrP, hIconLarge, PtrP, hIconSmall, UInt, 1)
      {
         MsgBox, 16,, % "Не удалось извлечь иконку.`nОшибка " A_LastError
         return
      }
      SysGet, SmallIconSize, % SM_CXSMICON := 49
      if (IconSize <= SmallIconSize)
         DllCall("DestroyIcon", Ptr, hIconLarge), hIcon := hIconSmall
      else
         DllCall("DestroyIcon", Ptr, hIconSmall), hIcon := hIconLarge

      hIcon := DllCall("CopyImage", Ptr, hIcon, UInt, IMAGE_ICON := 1
         , Int, IconSize, Int, IconSize, UInt, LR_COPYRETURNORG := 0x4|LR_COPYDELETEORG := 0x8, Ptr)
   }

   Return hIcon
}

AddTrayIcon(hIcon)
{
   static NIF_MESSAGE := 1, NIF_ICON := 2, GuiNumber := 99
   
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   Gui, % GuiNumber-- ": +hwndhGui"
   NumPut(hGui, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID := 0x404, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   NumPut(NIF_MESSAGE|NIF_ICON, NOTIFYICONDATA, 2*A_PtrSize + 4, "UInt")
   NumPut(nMsg := 0x404, NOTIFYICONDATA, 2*A_PtrSize + 8, "UInt")
   NumPut(hIcon, NOTIFYICONDATA, 3*A_PtrSize+8)
   
   DllCall("shell32\Shell_NotifyIcon", UInt, NIM_ADD := 0, Ptr, &NOTIFYICONDATA)
   DllCall("DestroyIcon", Ptr, hIcon)
   Return hGui
}

RemoveTrayIcon(hWnd, uID=0x404)
{
   VarSetCapacity(NOTIFYICONDATA, size := A_PtrSize = 8 ? 848 : A_IsUnicode? 828 : 444, 0)
   NumPut(size, NOTIFYICONDATA, "UInt")
   NumPut(hWnd, NOTIFYICONDATA, A_PtrSize)
   NumPut(uID, NOTIFYICONDATA, 2*A_PtrSize, "UInt")
   DllCall("shell32\Shell_NotifyIcon", "UInt", NIM_DELETE := 2, Ptr, &NOTIFYICONDATA)
   Return
}

AHK_NOTIFYICON(wp, lp, msg, hwnd)   ; wp — uID, lp — Message
{
   global hAssociatedGui1, hAssociatedGui2
   static WM_RBUTTONUP := 0x205
   if (lp = WM_RBUTTONUP && (hwnd = hAssociatedGui1 || hwnd = hAssociatedGui2))
      Menu, MyTrayMenu, Show
}

Re: AHK: Загрузка разных иконок для программы

2014-11-02T17:01:17Z

Если нельзя, но очень хочется, то можно.