Серый форум — AHK: Рандом без повторений

Re: AHK: Рандом без повторений

null@example.com (teadrinker) — Fri, 18 Apr 2014 15:47:21 +0000

С кодами напутал. Там коды не нужны, там карты вместо букв прорисованы, как в моём скрипте.

FontFile := "D:\Downloads\CARDS.TTF"  ; указать путь к файлу со шрифтом
FontName := "Playing Cards"           ; указать имя шрифта из файла

if !DllCall("AddFontResourceEx", Str, FontFile, UInt, FR_PRIVATE := 0x10, Ptr, 0)
{
   MsgBox, % "Не удалось установить шрифт. Ошибка " . A_LastError
   return
}

SendMessage, WM_FONTCHANGE := 0x1D, 0, 0,, % "ahk_id" HWND_BROADCAST := 0xFFFF

Gui, -Caption +ToolWindow +LastFound +AlwaysOnTop
Gui, Color, 0x0000FD
Gui, Font, s80 q3, % FontName
Gui, Add, Text, cRed, F  ; шестёрка бубей
WinSet, TransColor, 0x0000FD
Gui, Show
Return

Esc::ExitApp

Шестёрка бубей — F. Её код 0x46.

Re: AHK: Рандом без повторений

null@example.com (serzh82saratov) — Fri, 18 Apr 2014 15:16:06 +0000

FontFile := "D:\Downloads\CARDS.TTF"  ; указать путь к файлу со шрифтом
FontName := "Playing Cards"           ; указать имя шрифта из файла

if !DllCall("AddFontResourceEx", Str, FontFile, UInt, FR_PRIVATE := 0x10, Ptr, 0)
{
   MsgBox, % "Не удалось установить шрифт. Ошибка " . A_LastError
   return
}

SendMessage, WM_FONTCHANGE := 0x1D, 0, 0,, % "ahk_id" HWND_BROADCAST := 0xFFFF

Блин почему то не меняет шрифт, но и ошибки не выдаёт.

А вообще свой шрифт удобно, можно по порядку как надо раскидать.
В аттаче шрифт можете проверить, у меня не отображается 6 бубей код 0x26, хотя в таблице символов её видно.


Loop % mi := 52
    deck .= 0x20+A_Index "|"
 
size := 122, i := 0, deck := RTrim(deck,"|") 

Gui, -DPIScale
Gui, Font, s40, Playing Cards 
Gui, Add, Text, h%size% w%size% +0x201 Border vcard1 g1 
Gui, Add, Text, hp wp x+5 +0x201 Border vcard2 g2
Gui, Add, Text, hp wp x+5 +0x201 Border vcard3 g3
Gui, Font, s16, Arial
Gui, Add, Text, % "xs y+5 h" size / 3 " w" size * 3 + 10 " Border +0x201 vText gBegin" 
Gui, Show   

Begin:
    Sort, deck, Random D|  
    Global arr := StrSplit(deck, "|"), i := 0, cards := [], mi
    GuiControl,, Text, Полная колода
    Loop 3
        GuiControl,, card%A_Index% 
    Return
    
1:: 
2::
3:: next(A_ThisLabel), cards := []
4:: GoTo Begin

next(count)  {    
    Loop % i + count > mi ? mi - i : count
        cards[A_Index] := arr[++i] 
    Loop 3
    { 
        GuiControl, % cards[A_Index] > 0x003a ? "+cBlack" : "+cRed", card%A_Index% 
        GuiControl,, card%A_Index%, % Chr(cards[A_Index])
        GuiControl, +Redraw, card%A_Index% 
    }
    GuiControl,, Text, % i = mi ? "Пустая колода" : "Осталось " mi - i " карт(ы)" 
}

Re: AHK: Рандом без повторений

null@example.com (YMP) — Fri, 18 Apr 2014 14:41:43 +0000

Тут дело даже не в привлекательности, а в том, что их только по букве Q опознать можно. А так лысый мужик какой-то.

Re: AHK: Рандом без повторений

null@example.com (teadrinker) — Fri, 18 Apr 2014 14:14:27 +0000

Хм, я их в плане привлекательности как-то не догадался оценить.

Re: AHK: Рандом без повторений

null@example.com (YMP) — Fri, 18 Apr 2014 12:59:20 +0000

teadrinker пишет:

Playing Cards

Какие-то дамы лысые в этом шрифте. Скорее на мужиков смахивают.

Re: AHK: Рандом без повторений

null@example.com (teadrinker) — Fri, 18 Apr 2014 11:24:49 +0000

Playing Cards

FontFile := "D:\Downloads\CARDS.TTF"  ; указать путь к файлу со шрифтом
FontName := "Playing Cards"           ; указать имя шрифта из файла

if !DllCall("AddFontResourceEx", Str, FontFile, UInt, FR_PRIVATE := 0x10, Ptr, 0)
{
   MsgBox, % "Не удалось установить шрифт. Ошибка " . A_LastError
   return
}

SendMessage, WM_FONTCHANGE := 0x1D, 0, 0,, % "ahk_id" HWND_BROADCAST := 0xFFFF

Gui, -Caption +ToolWindow +LastFound +AlwaysOnTop
Gui, Color, 0x0000FD
Gui, Font, s80 q3, % FontName
Gui, Add, Text, cRed, K
Gui, Add, Text, x+1 cRed, Y
Gui, Add, Text, x+1 cBlack, m
Gui, Add, Text, x+1 cBlack, n
WinSet, TransColor, 0x0000FD
Gui, Show
Return

Esc::ExitApp

Re: AHK: Рандом без повторений

null@example.com (serzh82saratov) — Fri, 18 Apr 2014 10:44:44 +0000

О, Спасибо. А Я на русском найти не мог .
Кстати, а как использовать в ГУИ шрифт файла, который не установлен в системе? Помнится где то видел решение.

Re: AHK: Рандом без повторений

null@example.com (YMP) — Fri, 18 Apr 2014 10:33:12 +0000

А так не пробовали: http://yandex.ru/yandsearch?text=playin … &lr=53?

Re: AHK: Рандом без повторений

null@example.com (serzh82saratov) — Fri, 18 Apr 2014 09:23:47 +0000

Так в том и вопрос, какой шрифт искать, где скачать?

Re: AHK: Рандом без повторений

null@example.com (YMP) — Fri, 18 Apr 2014 09:20:55 +0000

Шрифт, наверно, скачать и установить.

Re: AHK: Рандом без повторений

null@example.com (serzh82saratov) — Fri, 18 Apr 2014 06:43:43 +0000

В смысле, что скачать, чтобы хоть в "Таблица символов" увидеть.

Re: AHK: Рандом без повторений

null@example.com (teadrinker) — Thu, 17 Apr 2014 18:51:44 +0000

В смысле, AHK v1, похоже, вообще не поддерживает utf-32:

VarSetCapacity(sim, 4, 0)
NumPut(0x1f0a0, sim, "Int")
MsgBox, % StrLen(StrGet(&sim, 1, "CP12000"))   ; 12000 — utf-32

Re: AHK: Рандом без повторений

null@example.com (bWRmeA) — Thu, 17 Apr 2014 17:59:48 +0000

Кроме того chr поддерживает utf-32 только в v2

MsgBox % StrLen(Chr(0x12345))

Re: AHK: Рандом без повторений

null@example.com (teadrinker) — Thu, 17 Apr 2014 17:42:17 +0000

Нужно найти и использовать шрифт, в котором есть эти символы.

Re: AHK: Рандом без повторений

null@example.com (serzh82saratov) — Thu, 17 Apr 2014 14:57:14 +0000

Кстати вопрос по анк, есть ведь 6-ти значные Unicode (Для самих карт есть специальный диапазон от U+01F0A0 до U+01F0FF), как их отобразить в гуи?