Серый форум — AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (Malcev) — Sat, 29 Sep 2018 23:46:34 +0000

teadrinker пишет:

Небольшое исправление:

HttpQueryInfo(URL, QueryInfoFlag=21, Proxy="", ProxyBypass="")
{
   hModule := DllCall("LoadLibrary", Str, "wininet.dll", Ptr)
   AccessType := Proxy = "" ? 1 : 3
   
   Loop 1
   {
      if !io_hInternet := DllCall("wininet\InternetOpen", Str, "", UInt, AccessType, Str, Proxy, Str, ProxyBypass, UInt, 0, Ptr) ;dwFlags
         break
      
      if !iou_hInternet := DllCall("wininet\InternetOpenUrl", Ptr, io_hInternet, Str, url, Str, "", UInt, 0, UInt, 0x80000000, UInt, 0)
         break
      
      VarSetCapacity(buffer_len, 4, 0) 
      Loop
      {         
         if A_Index = 3
            break 2
         
         VarSetCapacity(buffer, NumGet(buffer_len, "UInt"))
         hqi := DllCall("wininet\HttpQueryInfo", Ptr, iou_hInternet, UInt, QueryInfoFlag, Ptr, &buffer, Ptr, &buffer_len, UInt, 0)
      } Until hqi
      success := 1
   }
   
   DllCall("wininet\InternetCloseHandle",  Ptr, iou_hInternet)
   DllCall("wininet\InternetCloseHandle",  Ptr, io_hInternet)
   DllCall("FreeLibrary", Ptr, hModule)
   
   Return, success ? StrGet(&buffer) : -1
}

Один success вместо двух Error.

Тут ошибка:

link := "https://www.google.com/maps/vt/pb=!1m5!1m4!1i12!2i4645!3i2509!4i128!2m2!1e1!3i810!3m9!2sru!3slv!5e1105!12m1!1e4!12m1!1e47!12m1!1e3!4e0!5m1!1e0!23i4111425!23i1358757!23i1358902"
msgbox % HttpQueryInfo(link)


HttpQueryInfo(URL, QueryInfoFlag=21, Proxy="", ProxyBypass="")
{
   hModule := DllCall("LoadLibrary", Str, "wininet.dll", Ptr)
   AccessType := Proxy = "" ? 1 : 3
   
   Loop 1
   {
      if !io_hInternet := DllCall("wininet\InternetOpen", Str, "", UInt, AccessType, Str, Proxy, Str, ProxyBypass, UInt, 0, Ptr) ;dwFlags
         break
      
      if !iou_hInternet := DllCall("wininet\InternetOpenUrl", Ptr, io_hInternet, Str, url, Str, "", UInt, 0, UInt, 0x80000000, UInt, 0)
         break
      
      VarSetCapacity(buffer_len, 4, 0) 
      Loop
      {         
         if A_Index = 3
            break 2
         
         VarSetCapacity(buffer, NumGet(buffer_len, "UInt"))
         hqi := DllCall("wininet\HttpQueryInfo", Ptr, iou_hInternet, UInt, QueryInfoFlag, Ptr, &buffer, Ptr, &buffer_len, UInt, 0)
      } Until hqi
      success := 1
   }
   
   DllCall("wininet\InternetCloseHandle",  Ptr, iou_hInternet)
   DllCall("wininet\InternetCloseHandle",  Ptr, io_hInternet)
   DllCall("FreeLibrary", Ptr, hModule)
   
   Return, success ? StrGet(&buffer) : -1
}

Чтобы такого избежать нужно указывать lpszAgent в InternetOpen запросе и чтобы не писать на диск, отправлять INTERNET_FLAG_NO_CACHE_WRITE:

link := "https://www.google.com/maps/vt/pb=!1m5!1m4!1i12!2i4645!3i2509!4i128!2m2!1e1!3i810!3m9!2sru!3slv!5e1105!12m1!1e4!12m1!1e47!12m1!1e3!4e0!5m1!1e0!23i4111425!23i1358757!23i1358902"
msgbox % HttpQueryInfo(link)


HttpQueryInfo(URL, QueryInfoFlag=21, Proxy="", ProxyBypass="")
{
   static hModule := DllCall("LoadLibrary", Str, "wininet.dll", Ptr)
   AccessType := Proxy = "" ? 1 : 3
   
   Loop 1
   {
      if !io_hInternet := DllCall("wininet\InternetOpen", Str, "autohotkey", UInt, AccessType, Str, Proxy, Str, ProxyBypass, UInt, 0, Ptr) ;dwFlags
         break
      
      if !iou_hInternet := DllCall("wininet\InternetOpenUrl", Ptr, io_hInternet, Str, url, Str, "", UInt, 0, UInt, 0x84000000, UInt, 0)   ; INTERNET_FLAG_NO_CACHE_WRITE (0x04000000) + INTERNET_FLAG_RELOAD (0x80000000)
         break
      
      VarSetCapacity(buffer_len, 4, 0) 
      Loop
      {         
         if A_Index = 3
            break 2
         
         VarSetCapacity(buffer, NumGet(buffer_len, "UInt"))
         hqi := DllCall("wininet\HttpQueryInfo", Ptr, iou_hInternet, UInt, QueryInfoFlag, Ptr, &buffer, Ptr, &buffer_len, UInt, 0)
      } Until hqi
      success := 1
   }
   
   DllCall("wininet\InternetCloseHandle",  Ptr, iou_hInternet)
   DllCall("wininet\InternetCloseHandle",  Ptr, io_hInternet)
   DllCall("FreeLibrary", Ptr, hModule)
   
   Return, success ? StrGet(&buffer) : -1
}

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (Malcev) — Sun, 23 Sep 2018 19:58:52 +0000

Размер надёжней получать через MaxIndex().

url := "https://www.dropbox.com/sh/j1msw4e8dup2c5q/AAANYUWXcyBDgxVGkveU7AFla?dl=1"
;url := "https://raw.githubusercontent.com/f5devcentral/f5-irule-editor/master/iRuler/Templates/Blank.txt" ;1 byte
;url := "https://raw.githubusercontent.com/SparkPost/java-sparkpost/master/src/main/resources/empty.txt" ;0 bytes

req := ComObjCreate("WinHttp.WinHttpRequest.5.1")
req.Open("GET", url)
req.send()
msgbox % req.getallresponseheaders()
Body := req.ResponseBody
if IsObject(Body)
   length := Body.MaxIndex() + 1
else
   length := 0
msgbox % length

Скачать используя буфер (не напрямую в память) можно либо, с ком объектами WinHttpRequest, XMLHTTP с использованием Range, что не везде поддерживается,
либо через WinInet, что и делает UrlDownloadToFile:
https://docs.microsoft.com/en-us/window … etreadfile
либо WinHttp:
https://docs.microsoft.com/en-us/window … tpreaddata
либо Urlmon:
https://docs.microsoft.com/en-us/previo … v%3dvs.85)

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (Malcev) — Sat, 22 Sep 2018 22:48:03 +0000

HttpQueryInfo через com можно провернуть так:

url = https://github.com/szalony9szymek/large/releases/download/free/large
req := ComObjCreate("MSXML2.ServerXMLHTTP.6.0")
req.Open("GET", url, true)
req.send()
while req.readyState <2   ; HEADERS_RECEIVED
   sleep 10
ResponseHeaders := req.GetAllResponseHeaders()
req.abort()
msgbox % ResponseHeaders

С Microsoft.XMLHTTP, Msxml2.XMLHTTP, Msxml2.XMLHTTP.3.0, MSXML2.XMLHTTP.6.0, WinHttpRequest такого провернуть не всегда получится.
Ну и непонятно, почему мы считали, что после отправки запроса на сервер и после получения заголовков придется ждать получение тела ответа.

url = https://www.autohotkey.com/download/AutoHotkeyInstall.exe
req := ComObjCreate("WinHttp.WinHttpRequest.5.1")

a := a_tickcount
req.Open("GET", url)
req.send()
req.GetAllResponseHeaders()
msgbox % a_tickcount - a

a := a_tickcount
req.ResponseBody
msgbox % a_tickcount - a

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (YMP) — Mon, 09 Jun 2014 14:02:45 +0000

Разбираемся, как что работает, какие есть возможности.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (serzh82saratov) — Mon, 09 Jun 2014 13:46:31 +0000

Да всем устраивает, просто рассуждения о более коротком коде.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (Malcev) — Mon, 09 Jun 2014 12:57:04 +0000

А чем HttpQueryInfo не устраивает?
В чем его минусы?

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (YMP) — Mon, 09 Jun 2014 12:53:25 +0000

Насколько помню, в этих случаях оно качает файл целиком. Если речь про гет запрос, без возможности сервера отдавать диапазонами.

HttpQueryInfo вполне может и не качать. Как только скачались заголовки, функция может прекратить приём данных, т.к. ей больше ничего не нужно.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (serzh82saratov) — Mon, 09 Jun 2014 12:28:35 +0000

Хотя да, думаю, она может просто остановить приём данных после получения заголовков.

Насколько помню, в этих случаях оно качает файл целиком. Если речь про гет запрос, без возможности сервера отдавать диапазонами.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (serzh82saratov) — Mon, 09 Jun 2014 12:21:42 +0000

Апдейт мессаджа не видел. .Значит всё таки по вашему как...

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (serzh82saratov) — Mon, 09 Jun 2014 12:18:17 +0000

Кажется с github любой файл, уточнить с телефона не могу.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (YMP) — Mon, 09 Jun 2014 11:24:58 +0000

Вопрос в том, как HttpQueryInfo получает эти заголовки. Как ещё, если не отправляя какой-то запрос? А если так, то что мешает сделать то же объектом HTTP? Запрос HEAD, как мы видим, не годится. Может, она использует GET так же, как я. Надо бы найти сервер без поддержки диапазонов и проверить на нём работу HttpQueryInfo. Иначе откуда уверенность, что она там сработает?

Хотя да, думаю, она может просто остановить приём данных после получения заголовков.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (serzh82saratov) — Mon, 09 Jun 2014 11:08:31 +0000

И в таком случае опять же пользовать HttpQueryInfo? Тогда уже смысл этого метода теряется.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (YMP) — Mon, 09 Jun 2014 10:15:08 +0000

Диапазон можно обозначать и от конца файла. Вот так последний байт можно скачать:


HTTP.SetRequestHeader("Range", "bytes=-1")

Если сервер не поддерживает диапазоны, то, как я понимаю, в свойстве Status должен быть код ошибки. Но размер файла в таком случае остаётся неизвестным. Вряд ли в заголовках он будет обозначен.

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (serzh82saratov) — Mon, 09 Jun 2014 09:11:30 +0000

YMP
Чертовски любопытно!

Re: AHK: UrlDownloadToFile с таким же расширением, как и скачиваемый файл.

null@example.com (YMP) — Mon, 09 Jun 2014 09:05:31 +0000

Можно с помощью GET получить нужные заголовки, скачав 1 байт. Размер можно извлечь из Content-Range.


url = https://docs.google.com/uc?export=download&id=0B7FildjsrNkILWhYVHYwanJLS3c
HTTP := ComObjCreate("WinHTTP.WinHTTPRequest.5.1")
HTTP.Open("GET", url)
HTTP.SetRequestHeader("Range", "bytes=0-0")
HTTP.Send()
MsgBox, % HTTP.GetAllResponseHeaders()