Серый форум — AHK: Активировать приложения на панели задач при наведении курсора.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-09T21:57:29Z

serzh82saratov
Удивительно конечно, Вы всё-таки смогли это сделать, думал это невозможно. Спасибо большое.

В новой версии еще и решена назойливая проблема первого варианта, т.к. я использовал SendInput {LButton}, при быстром наведении он добавочно кликал за пределами панели задач и, например, выделял текст в браузере.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-09T12:21:16Z

Оптимизировано:


#SingleInstance Force
#Persistent  
#NoEnv 
 
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, % "ahk_id" hShellTray
DllCall("LoadLibrary","Str","oleacc","Ptr")
SetTimer, Reload, 1800000

Check:
    If (DllCall("WindowFromPoint", "int64", 0*DllCall("GetCursorPos", "Int64*" ,pt) + pt, "Ptr") != hTaskbar)
        prID := 0
    Else If ((ID := AccNeedInfo(pt, active, several)) && ID != prID && (prID := ID)) && (!active || several)
    {
        BlockInput On
        WinGetPos, wX, wY,,, ahk_id %hTaskbar%
        poi := ((pt & 0xFFFF) - wX) & 0xFFFF | ((pt >> 32) - wY) & 0xFFFF << 16     
        PostMessage, 0x201, 0x8 | 0x1, poi,, ahk_id %hTaskbar% 
        Sleep 10
        PostMessage, 0x202, 0x8, poi,, ahk_id %hTaskbar%
        Sleep 10
        BlockInput Off
    }
    Else If !ID
        prID := 0
    SetTimer, Check, -20
    Return

AccNeedInfo(pt, byref active, byref several)   {
    If DllCall("oleacc\AccessibleObjectFromPoint"
        , "Int64", pt, "Ptr*", pacc
        , "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild) != 0 
        || !(Child := NumGet(varChild,8,"UInt"))
        Return
    Acc := ComObjEnwrap(9, pacc, 1)
    Acc.accLocation(ComObj(0x4003,&x:=0), ComObj(0x4003,&y:=0), 0, 0, Child)    
    active := ((s := Acc.accState(Child)) = 1073741960 || s = 1074790540) ? 1 : 0
    several := Acc.accRole(Child) = 57 ? 1 : 0
    Return NumGet(x,0,"int") "x" NumGet(y,0,"int")
}

Reload:
    Reload

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T23:26:44Z

Ого, пока не ломается

Значит когда

1074790532 (приложение свернуто)

всё таки надо кликать.

я хотел, кстати, по этому поводу спросить в теме по OSD, можно ли ее сделать TopMost даже над таскбаром.

В той теме.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T23:06:21Z

serzh82saratov

Ну так если оно свёрнуто то клик должен быть, и он есть.

Но при этом оно и сворачивает, чего быть не должно.

Попробуйте так

Ого, пока не ломается, в Tooltip-е задетектил новые коды 1074790408 и 1073741832, но все работает.

#SingleInstance Force
#Persistent  
#NoEnv
ListLines Off  
SetBatchLines -1 
 
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, % "ahk_id" hShellTray
DllCall("LoadLibrary","Str","oleacc","Ptr") 
SetTimer, Reload, 1800000
 
MouseGet:
    MouseGetPos, ,  , , hCtrl, 2 
    If (hCtrl != hTaskbar)
        prID := 0
    Else If ((ID := AccChildPos(mX, mY, active)) && ID != prID && (prID := ID) && !active)
    {     
        BlockInput On 
        WinGetPos, wX, wY,,, ahk_id %hTaskbar%
        poi := (mX - wX) & 0xFFFF | ((mY - wY) & 0xFFFF) << 16    
        PostMessage, 0x201, 0x8 | 0x1, poi,, ahk_id %hTaskbar% 
        Sleep 1
        PostMessage, 0x202, 0x8, poi,, ahk_id %hTaskbar%
        BlockInput Off
    }
    Else If !ID
        prID := 0
    SetTimer, MouseGet, -20
    Return
    
AccChildPos(byref mX, byref mY, byref active)   { 
    If DllCall("oleacc\AccessibleObjectFromPoint"
        , "Int64", 0*DllCall("GetCursorPos","Int64*",pt)+pt, "Ptr*", pacc
        , "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild) != 0  
        Return
    If !(Child := NumGet(varChild,8,"UInt"))
        Return
    Acc := ComObjEnwrap(9, pacc, 1)
    Acc.accLocation(ComObj(0x4003,&x:=0), ComObj(0x4003,&y:=0), 0, 0, Child) 
    mX := pt & 0xFFFF, mY := pt >> 32
    s := Acc.accState(Child)
    ToolTip % s, 1, 1
    active := (s = 1073741960 || s = 1074790540) ? 1 : 0
    Return NumGet(x,0,"int") "x" NumGet(y,0,"int")
}

Reload:
    Reload

Не понял.

Поставьте OSD над панелью задач и кликните по ней, OSD окажется за ней, я хотел, кстати, по этому поводу спросить в теме по OSD, можно ли ее сделать TopMost даже над таскбаром.

В 7+ Taskbar Tweaker даже есть опция Disable_TopMost.

By default, the taskbar is always on top. This option allows you to change this behavior.
0 - Always on top (default)
1 - Not always on top, but not overlapped by maximized windows
2 - Not always on top, and overlapped by maximized windows

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T22:47:52Z

я про: запустил браузер и просто свернул, а не закрыл. Да, сворачивает и разворачивает, т.е. все как обычно.

Ну так если оно свёрнуто то клик должен быть, и он есть.

Ту все еще интересней

Попробуйте так

s := Acc.accState(Child)
ToolTip % s, 1, 1
active := (s = 1073741960 || s = 1074790540) ? 1 : 0

AhkSpy тут для отладки ненужен. После замены приведите здесь полный код.

OSD оказывается за ней, ощущение, что ломает клик по панели задач за иконками.

Не понял.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T22:34:19Z

serzh82saratov

Вы уверены что окно именно свёрнуто и при этом активно? Если это даже так, то "ненужный" клик ведь разворачивает окно?

Не совсем понимаю, что имеется ввиду под активно, я про: запустил браузер и просто свернул, а не закрыл. Да, сворачивает и разворачивает, т.е. все как обычно.

Он может сломатся, а потом правильно заработать?

Нет, только после перезагрузки вручную.

попробуйте заменить строку

Ту все еще интересней, я просто навожу курсор на 4 приложения, т.е. переключаю, и ломается, но уже полностью, т.е. наведением курсора не разворачивается, но не запущенные запускаются. И стоит кликнуть вручную по свернутому, как опять работает.

В этот раз удалось задетектить причину с помощью OSD, когда происходит поломка, панель задач становится TopMost, т.е. OSD оказывается за ней, ощущение, что ломает клик по панели задач за иконками.

Ahk Spy показывает 532 у всех окон и свернутых и развернутых, но 540 у окна которое стоит первым за самим Ahk Spy. Ну и 960 когда все работает, но при запущенном Ahk Spy ломается очень быстро.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T21:55:11Z

Да, работает, но свернуто.

Вы уверены что окно именно свёрнуто и при этом активно? Если это даже так, то "ненужный" клик ведь разворачивает окно?

он может так-же сломаться, но позже

Он может сломатся, а потом правильно заработать?

Когда работает все правильно, в обоих состояниях код 1073741960.

попробуйте заменить строку

active := Acc.accState(Child) = 1073741960 ? 1 : 0

на

s := Acc.accState(Child)
active := (s = 1073741960 || s = 1074790540 || s = 1074790532) ? 1 : 0

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T21:37:50Z

Приложение развернуто и активно, и при повторном наведении всё же происходит клик?

Да, скрипт как-бы ломается после чего-то и начинает вести себя как вчерашний из 37 поста, т.е. без WinActivate.

В смысле свернуто и активно?

Да, работает, но свернуто.

Что значит не повторяется?

Имеется ввиду, что скрипт может сломаться от открытия нового приложения, но повторить это не удается, он может так-же сломаться, но позже. Пытался выяснить причину, думал курсор наезжает на промежуток между ярлыками, или попадает в самый низ, но пока не получилось. Когда работает все правильно, в обоих состояниях код 1073741960.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T20:36:58Z

1074790540 (приложение развернуто)

Приложение развернуто и активно, и при повторном наведении всё же происходит клик?

1074790532 (приложение свернуто)

В смысле свернуто и активно?

Поломка происходила как и простот при вызове приложения кликом, так и при комбинации Win+цифра, но не повторяется

Что значит не повторяется?

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T18:20:40Z

serzh82saratov
Ок, попробую задетектить.

Просто, когда не знал про AHK, эти фичи стали откровением.

State code до поломки:
1073741960
State code после поломки:
1074790540 (приложение развернуто)
1074790532 (приложение свернуто)

Поломка происходила как и простот при вызове приложения кликом, так и при комбинации Win+цифра, но не повторяется.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T18:14:24Z

8.1 x64, происходит без закономерностей

У меня 7. Если глюк появится, и начнётся постоянный отказ фичи, то запусти AhkSpy, и смотри что в AccInfo - State - code, наведя мышь на кнопку.

http://habrahabr.ru/post/174593/

Для себя не нашёл ничего нужного.

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T18:01:56Z

serzh82saratov
8.1 x64, происходит без закономерностей, т.е. без повторов от того же действия. Нужно потестировать.

7+ Taskbar Tweaker это маст хэв твик для панели задач Windows, попробуйте, что называется "палю годноту". Можно убрать группировку по ID приложений, можно каждый ярлык настроить отдельно, где показывать label, можно скрыть эскиз, громкость/сворачивание колесом мыши и т.д. Кстати, разработчик русскоговорящий.

http://habrahabr.ru/post/174593/
http://rammichael.com/7-taskbar-tweaker

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T17:32:37Z

Обнаружилась проблема, бывает отваливается эта возможность

Ни разу у себя не заметил. У вас винда какая?

Вы пользуетесь 7+ Taskbar Tweaker?

А что это?

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T14:47:38Z

serzh82saratov
Огого, ну Вы мастер, и правда работает. О_о Он даже не кликает повторно по уже открытому и окно не мелькает, как в первоначальном варианте.

Обнаружилась проблема, бывает отваливается эта возможность, т.е. опять начинает сворачивать, после перезагрузки скрипта все норм. Надо посмотреть как на практике будет, может перезагрузка каждые 5 мин решит проблему.

Вы пользуетесь 7+ Taskbar Tweaker?

Re: AHK: Активировать приложения на панели задач при наведении курсора.

2015-01-08T14:12:34Z

Esc пишет:

приложение по повторному клику сворачивается, в чем как раз смысл WinActivate.

Вроде придумал:


#SingleInstance Force
#Persistent  
#NoEnv
ListLines Off  
SetBatchLines -1 
 
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, % "ahk_id" hShellTray
DllCall("LoadLibrary","Str","oleacc","Ptr") 
SetTimer, Reload, 1800000
 
MouseGet:
    MouseGetPos, ,  , , hCtrl, 2 
    If (hCtrl != hTaskbar)
        prID := 0
    Else If ((ID := AccChildPos(mX, mY, active)) && ID != prID && (prID := ID) && !active)
    {     
        BlockInput On 
        WinGetPos, wX, wY,,, ahk_id %hTaskbar%
        poi := (mX - wX) & 0xFFFF | ((mY - wY) & 0xFFFF) << 16    
        PostMessage, 0x201, 0x8 | 0x1, poi,, ahk_id %hTaskbar% 
        Sleep 1
        PostMessage, 0x202, 0x8, poi,, ahk_id %hTaskbar%
        BlockInput Off
    }
    Else If !ID
        prID := 0
    SetTimer, MouseGet, -20
    Return
    
AccChildPos(byref mX, byref mY, byref active)   { 
    If DllCall("oleacc\AccessibleObjectFromPoint"
        , "Int64", 0*DllCall("GetCursorPos","Int64*",pt)+pt, "Ptr*", pacc
        , "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild) != 0  
        Return
    If !(Child := NumGet(varChild,8,"UInt"))
        Return
    Acc := ComObjEnwrap(9, pacc, 1)
    Acc.accLocation(ComObj(0x4003,&x:=0), ComObj(0x4003,&y:=0), 0, 0, Child) 
    mX := pt & 0xFFFF, mY := pt >> 32
    active := Acc.accState(Child) = 1073741960 ? 1 : 0
    Return NumGet(x,0,"int") "x" NumGet(y,0,"int")
}

Reload:
    Reload

Кстати ещё можно определять, одно или несколько окон висит на кнопке, так что вариантов много. Например если одно из нескольких окон кнопки уже активно, то посылать ктрл+клик для активации следующего окна (код ниже), или просто клик для вывода списка окон этой кнопки.


#SingleInstance Force
#Persistent  
#NoEnv
ListLines Off  
SetBatchLines -1 
 
hShellTray := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer.exe") 
ControlGet, hTaskbar, HWND,, MSTaskListWClass1, % "ahk_id" hShellTray
DllCall("LoadLibrary","Str","oleacc","Ptr") 
SetTimer, Reload, 1800000
 
MouseGet:
    MouseGetPos, ,  , , hCtrl, 2 
    If (hCtrl != hTaskbar)
        prID := 0
    Else If ((ID := AccChildPos(mX, mY, active, several)) && ID != prID && (prID := ID)) && (!active || (active && several))
    {     
        BlockInput On 
        WinGetPos, wX, wY,,, ahk_id %hTaskbar%
        poi := (mX - wX) & 0xFFFF | ((mY - wY) & 0xFFFF) << 16     
        PostMessage, 0x201, 0x8 | 0x1, poi,, ahk_id %hTaskbar% 
        Sleep 1
        PostMessage, 0x202, 0x8, poi,, ahk_id %hTaskbar%
        BlockInput Off
    }
    Else If !ID
        prID := 0
    SetTimer, MouseGet, -20
    Return
    
AccChildPos(byref mX, byref mY, byref active, byref several)   { 
    If DllCall("oleacc\AccessibleObjectFromPoint"
        , "Int64", 0*DllCall("GetCursorPos","Int64*",pt)+pt, "Ptr*", pacc
        , "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild) != 0  
        Return
    If !(Child := NumGet(varChild,8,"UInt"))
        Return
    Acc := ComObjEnwrap(9, pacc, 1)
    Acc.accLocation(ComObj(0x4003,&x:=0), ComObj(0x4003,&y:=0), 0, 0, Child) 
    mX := pt & 0xFFFF, mY := pt >> 32
    active := Acc.accState(Child) = 1073741960 ? 1 : 0
    several := Acc.accRole(Child) = 57 ? 1 : 0 
    Return NumGet(x,0,"int") "x" NumGet(y,0,"int")
}

Reload:
    Reload