#SingleInstance Force

WinTitle := "ahk_class MPC-BE ahk_exe mpc-be64.exe"  ; класс и процесс окна
wx := 5  ; x - координата показа osd
wy := 857  ; y - координата показа osd
TextColor := "FFFF00"
TextSize := 14
FontName := "Verdana"
FontStyle := "norm"
Quality := 0
Global tWin, hOSD
Gui, +AlwaysOnTop +ToolWindow -Caption -DPIScale +LastFound +E0x00000020 +HWNDhOSD
Gui, Color, EEAA99
WinSet, TransColor, EEAA99 220
Gui, Font, % "s" . TextSize . " q" . Quality . " " . FontStyle, % FontName
OnExit, Exit
DllCall("RegisterShellHookWindow", "UInt", A_ScriptHwnd)
OnMessage(DllCall("RegisterWindowMessage", "str", "SHELLHOOK"), "ShellProc")
SetWinEventHook(0x800B, 0x800B, 0, RegisterCallback("WinEventHook", "F"),0,0,0)    ;    EVENT_OBJECT_LOCATIONCHANGE
Loop  {
    WinWait, % WinTitle
    tWin := WinExist(WinTitle)
    GoSub isWindowFullScreen
    SoundSet 25
    WinWaitClose, % WinTitle 
    tWin := HideOSD := 0, GuiHide()
    SoundSet 10
}

#If tWin
^Space:: ((HideOSD := !HideOSD) ? GuiHide() : OSD())

OSD()  {
    Global
    if FS || HideOSD
        Return
    WinGetTitle, Title, ahk_id %tWin%
    Title := RegExReplace(Title, "( - )?MPC-BE x64.*")
    DllCall("DestroyWindow", "Ptr", hText)
    Gui, Add, Text, % "Center hwndhText c" TextColor " x" 0 " y" 0, % Title
    Gui, Show, NA AutoSize x%wx% y%wy%
    SetTimer OnTopTaskBar, 70
}

GuiHide()  {
    Gui, Show, Hide
    SetTimer OnTopTaskBar, Off
}

isWindowFullScreen:
    WinGet style, Style, ahk_id %tWin%
    WinGetPos, , , winW, winH, ahk_id %tWin%
    ; 0x800000 is WS_BORDER. 0x20000000 is WS_MINIMIZE. no border and not minimized
    FS := (!(style & 0x20800000) && winH = A_ScreenHeight && winW = A_ScreenWidth)
    (FS ? GuiHide() : OSD())
    Return

OnTopTaskBar: 
    Gui, +AlwaysOnTop
    Return

Exit:
    DllCall("DeregisterShellHookWindow", "UInt", A_ScriptHwnd)
    ExitApp

ShellProc(nCode, wParam)  {
    Critical
    If (nCode = 6 && wParam = tWin) ; HSHELL_REDRAW
        OSD()
}

WinEventHook(hWinEventHook, event, hwnd, idObject, idChild, dwEventThread, dwmsEventTime)   {
    if (tWin && hwnd = tWin)
        SetTimer isWindowFullScreen, -100
}

SetWinEventHook(eventMin, eventMax, hmodWinEventProc, lpfnWinEventProc, idProcess, idThread, dwFlags) {
    Return DllCall("SetWinEventHook" , "UInt", eventMin, "UInt", eventMax, "Ptr", hmodWinEventProc
            , "Ptr", lpfnWinEventProc, "UInt", idProcess, "UInt", idThread, "UInt", dwFlags, "Ptr")
}