Серый форум — Клики по очереди

Re: Клики по очереди

null@example.com (becauseim) — Wed, 18 Jan 2017 00:47:03 +0000

serzh82saratov, подскажите, пожалуйста, как в Вашем сценарии добавить к поиску ряд изображений вместо одного?

Re: Клики по очереди

null@example.com (serzh82saratov) — Sun, 06 Jul 2014 20:06:48 +0000

http://ahkscript.org/download/ahk-install.exe

Re: Клики по очереди

null@example.com (ignor31) — Sun, 06 Jul 2014 19:18:47 +0000

Последний код ругается на

For k, v in SeveralSearch(0, 0, 1366, 768, "*49 D:\Search.png")

и предпоследний тоже ... не нонятна=(

Re: Клики по очереди

null@example.com (serzh82saratov) — Sun, 06 Jul 2014 08:35:04 +0000

Вы уверены что оно будет в принципе находить все такие зелёные пятна, обратите внимание что они все неоднородны.

Вообщем с такой картинкой, на вашей находит.

+ code


#SingleInstance Force
#Persistent
#NoEnv
ListLines Off
SetBatchLines -1
CoordMode, Pixel
CoordMode, Mouse

Gui -DPIScale -Caption +HWNDhGui
Gui Margin, 0, 0
Gui Add, Picture, vPicture, Новый точечный рисунок.png
Gui Show, x100 y100 w1300 h725

1:: 
	For k, v in SeveralSearch(100, 100, 1300, 725, "*49 tz.bmp")
		Click % v[1]+10 " " v[2]+5
	Return

SeveralSearch(ix1, iy1, w, h, file)  {
	StartTime := A_TickCount
	x1 := ix1, y1 := iy1, x2 := ix1 + w - 1, y2 := iy1 + h - 1
	prY := y2, ErrorCount := 0, Coords := []
	Loop
	{
		ImageSearch, mX, mY, x1, y1, x2, y2, %file%
		If (ErrorLevel && ++ErrorCount > 1)
			Break
		If (mY = "" || mY > prY)
			x1 := ix1, y1 += 1, prY := y2
		Else
			x1 := mX + 1, ErrorCount := 0, y1 := mY, prY := mY, Coords.Push([mX, mY])
	}
	MsgBox % "Найдено: " coords.MaxIndex()
        . "`nЗа: " A_TickCount - StartTime "msec"
	Return Coords
}
 
Esc::
	ExitApp

Re: Клики по очереди

null@example.com (serzh82saratov) — Sat, 05 Jul 2014 14:44:26 +0000

не вижу другого способа, кроме как "прикрывать" найденные картинки для поиска следующей.

Хотя нет, появилась такая идея:


#SingleInstance Force
#Persistent
#NoEnv
ListLines Off
SetBatchLines -1
CoordMode, Pixel
CoordMode, Mouse

Gui -DPIScale -Caption +HWNDhGui
Gui Margin, 0, 0
Gui Add, Picture, vPicture, Новый точечный рисунок.png
Gui Show, x100 y100 w1300 h725

1:: 
	For k, v in SeveralSearch(100, 100, 1300, 725, "tz.bmp")
		Click % v[1]+10 " " v[2]+5
	Return

SeveralSearch(ix1, iy1, w, h, file)  {
	x1 := ix1, y1 := iy1, x2 := ix1 + w - 1, y2 := iy1 + h - 1
	prY := y2, ErrorCount := 0, Coords := []
	Loop
	{
		ImageSearch, mX, mY, x1, y1, x2, y2, %file%
		If (ErrorLevel && ++ErrorCount > 1)
			Break
		If (mY = "" || mY > prY)
			x1 := ix1, y1 += 1, prY := y2
		Else
			x1 := mX + 1, ErrorCount := 0, y1 := mY, prY := mY, Coords.Push([mX, mY])
	}
	Return Coords
}
 
Esc::
	ExitApp

Картинки с предыдущего поста.

Re: Клики по очереди

null@example.com (serzh82saratov) — Sat, 05 Jul 2014 08:29:14 +0000

Если представить что картинки всё же одинаковые, то Я например, в такой казалось бы тривиальной задаче, не вижу другого способа, кроме как "прикрывать" найденные картинки для поиска следующей.
Необходимые для работы кода картинки, в аттаче.


Gui -DPIScale -Caption +HWNDhGui
Gui Margin, 0, 0
Gui Add, Picture, vPicture, C:\Users\sergey\Desktop\Новый точечный рисунок.bmp
Gui Show, x0 y0

1::
    Gui 2: -Caption +AlwaysOnTop +E0x08000000 +E0x20 +Lastfound -DPIScale 
    DllCall("Dwmapi\DwmIsCompositionEnabled", "UInt*", isEnabled)
    If isEnabled
    {
        Gui 2: Color, 000000
        WinSet, TransColor, 000000 250
    }
    Gui 2: Show, NA x0 y0 w%A_ScreenWidth% h%A_ScreenHeight%
    coords := [], prY := y1 := 0 
    Loop
    {
        ImageSearch, mX, mY, 0, y1, A_ScreenWidth, A_ScreenHeight, C:\Users\sergey\Desktop\tz.bmp
        If ErrorLevel
            Break
        Gui 2: Add, Progress, % "x" mX " y" mY " h" 11 " w" 20 " BackgroundD27429F"
        coords[A_Index] := [mX, mY], y1 := mY > prY ? mY : y1, prY := mY 
        Sleep -1 
    } 
    Gui 2: Destroy 
    For k, v in coords
        Click % v[1]+10 " " v[2]+5
    Return

АП:
На Win 7 работает только с включенным Аеро, пока сам не знаю почему так.

АП:
С выключенным Аеро работает, если, как ни странно, удалить эти строки

    Gui 2: Color, 000000
    WinSet, TransColor, 000000 250

АП:
Поправил код, чтобы учитывалось Аеро.

АП:

"прикрывать" найденные картинки

Но лучше наверное, такие "нашлёпки" делать с помощью GDI.

Re: Клики по очереди

null@example.com (serzh82saratov) — Sat, 05 Jul 2014 04:48:27 +0000

ignor31 пишет:

Дело в том что после клика объект не пропадает..

Malcev пишет:

Во втором посте уже осуществлена.

Сомневаюсь что этот код как то может решить вопрос.

x::
ErrorLevel = 0
n = 1
while (!ErrorLevel)
{
   PixelSearch, Px%n%, Py%n%, 0, 0, %A_ScreenWidth%, %A_ScreenHeight%, 0x01CD01, 0, fast
   n++
}
while (A_index < n)
   Click, % Px%A_index% ", " Py%A_index%
return

ignor31 пишет:

Написал код используя ImageSearch

Вы уверены что оно будет в принципе находить все такие зелёные пятна, обратите внимание что они все неоднородны.

Re: Клики по очереди

null@example.com (Malcev) — Fri, 04 Jul 2014 22:49:18 +0000

Значит что-то неправильно делаете.

Re: Клики по очереди

null@example.com (ignor31) — Fri, 04 Jul 2014 17:21:18 +0000

Malcev пишет:

Во втором посте уже осуществлена.

Возможно, но не 2ой пост не тот же код с ImageSearch не дают результата..

Re: Клики по очереди

null@example.com (Malcev) — Fri, 04 Jul 2014 08:13:33 +0000

пока писал это , пришла в голову мысль.. Сканирования экрана на наличие искомого изображения , запись кординат далее клики по ним. Помогите Осуществить

Во втором посте уже осуществлена.

Re: Клики по очереди

null@example.com (ignor31) — Fri, 04 Jul 2014 02:22:49 +0000

Доброго времени суток еще раз.
Написал код используя ImageSearch, но мне не как не приходит в голову как написать последовательность кликов по результатам. Дело в том что после клика объект не пропадает.. пока писал это , пришла в голову мысль.. Сканирования экрана на наличие искомого изображения , запись кординат далее клики по ним. Помогите Осуществить

Re: Клики по очереди

null@example.com (Malcev) — Sat, 28 Jun 2014 11:07:07 +0000

Возможно, находит слишком много совпадений.
Посмотрел на картинку - используйте ImageSearch.

Re: Клики по очереди

null@example.com (ignor31) — Fri, 27 Jun 2014 21:15:07 +0000

Malcev .
Ваш код не помог .. делает тоже самое только еще и зависает... может я вас не правильно понял и должен был что-то дописать .. но код в таком виде не робит. прошу помощи...

Re: Клики по очереди

null@example.com (Malcev) — Fri, 27 Jun 2014 07:02:44 +0000

Используйте цикл.

x::
ErrorLevel = 0
n = 1
while (!ErrorLevel)
{
   PixelSearch, Px%n%, Py%n%, 0, 0, %A_ScreenWidth%, %A_ScreenHeight%, 0x01CD01, 0, fast
   n++
}
while (A_index < n)
   Click, % Px%A_index% ", " Py%A_index%
return

Клики по очереди

null@example.com (ignor31) — Fri, 27 Jun 2014 01:36:16 +0000

Доброго времени суток, подскажите пожалуйста использую код




x::
        {
        PixelSearch, Px, Py, 0, 0, %A_ScreenWidth%, %A_ScreenHeight%, 0x01CD01, 0, fast
        Click, %Px%, %Py%
        
        }
return

все работает . но на экране несколько пикселей данного цвета, помогите сделать так что бы после клика по первому найденному пикселю кликал по остальным по очереди.

ps: делать надо клики по зеленым лужам на скриншоте .